;#############################################################################
;USERLIBS:
;=========

;.lib "user32.dll"
;api_CreatePopupMenu%():"CreatePopupMenu"
;api_DestroyMenu(h):"DestroyMenu"

;api_InsertMenuItem%(hMenu,uItem,fByPosition, lpmii*):"InsertMenuItemA"
;api_DeleteMenu(hMenu,uPosition,uFlags):"DeleteMenu"

;api_TrackPopupMenuEx%(hMenu,wFlags,x,y,HWnd,lptpm):"TrackPopupMenuEx"

;api_GetMenuItemInfo%(hMenu,uItem,fByPosition,lpmii*):"GetMenuItemInfoA"
;api_SetMenuItemInfo%(hMenu,uItem,fByPosition,lpmii*):"SetMenuItemInfoA"
; GetAsyncKeyState%(vKey%)

;-----------------------------------------------------------------------------

;.lib "kernel32.dll"
;ptr_helper__%(a*,b%,c%):"MulDiv"

;#############################################################################

Local win=CreateWindow("BOX",GadgetWidth(Desktop())/2-150,GadgetHeight(Desktop())/2-120,300,240,0,33)
Local font=LoadFont("Arial",14,1)
Local box=CreateListBox(3,3,294,284,win)
SetGadgetFont(box,font)
FreeFont(font)

;[Block - Items]
AddGadgetItem(box,"Eintrag !")
AddGadgetItem(box,"Eintrag ?")
AddGadgetItem(box,"Eintrag .")
;[End Block]


Const VK_LEFTMOUSE = $01 ; Left physical mouse button
Const VK_RIGHTMOUSE = $02 ; Right physical mouse button



Untermenu = PM_Create()
PM_AddItem(Untermenu,"Auswahl Nr.1",11,$8,0,1)
PM_AddItem(Untermenu,"Auswahl Nr.2",12, 0,0,1)
PM_AddItem(Untermenu,"Auswahl Nr.3",13, 0,0,1)

HauptMenu=PM_Create()
PM_AddItem(HauptMenu,"UnterMenü?",1,$8)
PM_AddItem(HauptMenu,"",4)
PM_AddItem(HauptMenu,"Untermenü",2,$1000,Untermenu)
PM_AddItem(HauptMenu,"Ende",3)
PM_AddItem(HauptMenu,"",4)
PM_AddItem(HauptMenu,"Lösch mich!",5)
PM_AddItem(HauptMenu,"Counter: 0",6)



Repeat
Local bef_e=SelectedGadgetItem(box)

event=0
If  GetAsyncKeyState%( VK_RIGHTMOUSE ) rightmouse=1


   Select WaitEvent()
      Case $803
         Ende = 1
        Case $401
      If rightmouse=1
         rightmouse=0
         event = PM_Show(Hauptmenu,MouseX(),MouseY(),win)
         Select event
            Case 11,12,13
               PM_UncheckItem(Untermenu,11)
               PM_UncheckItem(Untermenu,12)
               PM_UncheckItem(Untermenu,13)
               PM_CheckItem(Untermenu,event)
            Case 3
               Ende = 1
            Case 1
               If PM_GetChecked(Hauptmenu,1) Then
                     PM_UncheckItem(Hauptmenu,1)
                     PM_DisableItem(Hauptmenu,2)
                  Else
                        PM_CheckItem(Hauptmenu,1)
                        PM_EnableItem(Hauptmenu,2)
                  End If
               Case 5
                  PM_DeleteItem(HauptMenu,5)
              Case 6
                 t$ = PM_GetText(HauptMenu,6)
                  t$ = Mid(t,Instr(t," "))
                  PM_SetText(Hauptmenu,6,"Counter: "+(Int(t$)+1))
         End Select
      EndIf
      Select EventSource()
         Case box
               If SelectedGadgetItem(box)=bef_e
                  inhalt$ = GadgetItemText$ (box,bef_e)
                  inhalt_len = Len(inhalt$)
                  Notify(GadgetItemText$(box,SelectedGadgetItem(box))+" wurde doppelt angeklickt!"+Chr(13)+"Der Text hat ne länge von "+inhalt_len+" zeichen!")
               EndIf
         End Select
      End Select
Until (ende = 1)

PM_Delete(Hauptmenu)
PM_Delete(Untermenu)

End
























Function PM_Create()
   Return api_CreatePopupMenu()
End Function
;Erstellt ein neues Popupmenu, und gibt dessen handle zurück.



Function PM_Delete(h)
   api_DestroyMenu(h)
End Function
;Gibt den Speicher eines Menüs frei.
;h = Handle des Popupmenus.



Function PM_AddItem(h,t$,Id,s=$0,subM=0,r=0)
   b2 = CreateBank(Len(t)+1)
      For x = 1 To Len(t)
         PokeByte b2,x-1,Asc(Mid(t,x,1))
      Next
      PokeByte b2,x-1,0

     
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$3B+((subM>0)*$4)
      PokeInt b1,8,$800*(t="")+(r*$200)
      PokeInt b1,12,s
      PokeInt b1,16,ID
   
      PokeInt b1,20,subM
      PokeInt b1,24,0
      PokeInt b1,28,0
   
      PokeInt b1,32,0
      PokeInt b1,36,api_MulDiv%(b2,1,1)
      PokeInt b1,40,Len(t)
     
   api_InsertMenuItem(h,0,0,b1)
   
   FreeBank b1
   FreeBank b2
End Function
;Fügt ein Eintrag am Ende eines Popupfensters hinzu.
;h  = Handle des PopupMenus
;t  = Text der angezeigt werden soll oder "" für eine Trennlinie  (& vor Buchstaben für Shortcut)
;ID = Kennnummer, die von ShowPopupMenu zurückgegeben wird....
;s=Styles:   $8      Häckchen
;         $1000   Fett
;         $3      Ausgeschaltet (grau)
;         $80      Highlight (ausgewählt, blauer Hintergrund)
;         Flags können kombinert werden (durch Adition)
;subM = Handle des SubMenus, dass erscheinen soll, wenn man auf diesen Item kommt
;r = Punkte statt Häckchen verwenden (für nur eine Auswahl)



Function PM_DeleteItem(h,i)
   api_DeleteMenu(h,i,0)
End Function
;Löscht einen Eintrag aus einem Menu. Wenn das zu löschende Menü ein Untermenü hat, wird auch dessen
;Speciher freigegeben.
;h = Handle des Menüs, in dem sich der Eintrag befindet.
;i = Kennnummer des Eintrags.



Function PM_Show(h,x,y,w)
   Return api_TrackPopupMenuEx(h,$100,x,y,QueryObject(w,1),0)
End Function
;Zeigt das Popup-Menu an.
;h = Handle des PopupMenus
;x,y = Position des Menus zur linken, oberen Bildschirmecke
;w = Handle des Fensters, das Parent für das Menu ist









Function PM_GetEnabled(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1

   api_GetMenuItemInfo(h,i,0,b1)

   t = Not(PeekInt(b1,12) And $3)/3
   
   FreeBank b1

   Return t
End Function
;Gibt zurück, ob ein Item ausgewählt werden kann.
;h = Handle des Menüs
;i = Kennnummer des Eintrags



Function PM_GetChecked(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1

   api_GetMenuItemInfo(h,i,0,b1)

   t = (PeekInt(b1,12) And $8)/8
   
   FreeBank b1

   Return t
End Function
;Gibt zurück, ob vor einem Menüeintrag ein Haken ist.
;h = Handle des Menüs
;i = Kennnummer des Eintrags



Function PM_GetText$(h,i)
   b2 = CreateBank(50)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$10
      PokeInt b1,36,api_MulDiv%(b2,1,1)
      PokeInt b1,40,50

   api_GetMenuItemInfo(h,i,0,b1)

   For x = 0 To 49
      If PeekInt(b2,x)=0 Then Exit
      t$ = t + Chr(PeekByte(b2,x))
   Next

   FreeBank b1
   FreeBank b2

   Return t
End Function
;Gibt den Text eines Menüeintrags zurück.
;h = Handle des Menüs
;i = Kennnummer des Eintrags








Function PM_SetText(h,i,t$)
   b2 = CreateBank(Len(t)+1)
      For x = 1 To Len(t)
         PokeByte b2,x-1,Asc(Mid(t,x,1))
      Next
      PokeByte b2,x-1,0
     
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$10
      PokeInt b1,36,api_MulDiv%(b2,1,1)
      PokeInt b1,40,Len(t)+1

   api_SetMenuItemInfo(h,i,0,b1)

   FreeBank b1
   FreeBank b2
End Function
;Ändert den Text eines Menuitems.
;h = Handle des PopupMenus
;i = Kennnummer des Items
;t = neuer Text


Function PM_EnableItem(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1
   api_GetMenuItemInfo(h,i,0,b1)
   PokeByte b1,12,(PeekInt(b1,12) And $fffffffc)
   api_SetMenuItemInfo(h,i,0,b1)
   FreeBank b1
End Function
;Macht, dass ein Menuitem wieder angewählt werden kann
;h = Handle des PopupMenus
;i = Kennnummer des Items



Function PM_DisableItem(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1
   api_GetMenuItemInfo(h,i,0,b1)
   PokeByte b1,12,(PeekInt(b1,12) And $fffffffc)+$3
   api_SetMenuItemInfo(h,i,0,b1)
   FreeBank b1
End Function
;Macht, dass ein Menuitem nicht angewählt werden kann
;h = Handle des PopupMenus
;i = Kennnummer des Items



Function PM_CheckItem(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1
   api_GetMenuItemInfo(h,i,0,b1)
   PokeByte b1,12,(PeekInt(b1,12) And $fffffff7)+$8
   api_SetMenuItemInfo(h,i,0,b1)
   FreeBank b1
End Function
;Häckelt ein MenuItem "an".
;h = Handle des PopupMenus
;i = Kennnummer des Items



Function PM_UncheckItem(h,i)
   b1 = CreateBank(44)
      PokeInt b1,0,44
      PokeInt b1,4,$1
   api_GetMenuItemInfo(h,i,0,b1)
   PokeByte b1,12,(PeekInt(b1,12) And $fffffff7)
   api_SetMenuItemInfo(h,i,0,b1)
   FreeBank b1
End Function
;Entfernt das Häckchen vor einem MenuItem.
;h = Handle des PopupMenus
;i = Kennnummer des Items

Untermenu = PM_Create()
PM_AddItem(Untermenu,"Auswahl Nr.1",11,$8,0,1)
PM_AddItem(Untermenu,"Auswahl Nr.2",12, 0,0,1)
PM_AddItem(Untermenu,"Auswahl Nr.3",13, 0,0,1)


HauptMenu=PM_Create()
PM_AddItem(HauptMenu,"UnterMenü?",1,$8)
PM_AddItem(HauptMenu,"",4)
PM_AddItem(HauptMenu,"Untermenü",2,$1000,Untermenu)
PM_AddItem(HauptMenu,"Ende",3)
PM_AddItem(HauptMenu,"",4)
PM_AddItem(HauptMenu,"Lösch mich!",5)
PM_AddItem(HauptMenu,"Counter: 0",6)

;In der Schleife :
If GetAsyncKeyState%( VK_RIGHTMOUSE ) Then rightmouse=1
   ev = WaitEvent( 32 )
   If rightmouse = 1 Then
      rightmouse = 0
      get = PM_Show(Hauptmenu, MouseX(), MouseY(), MainWindow)
      DebugLog get+","+MouseX( )+","+MouseY()
   EndIf