Cracktros/ Intros/ Demos mit SinusEffekten

Übersicht BlitzBasic Allgemein

Neue Antwort erstellen

Flush

Betreff: Cracktros/ Intros/ Demos mit SinusEffekten

BeitragSa, Jan 07, 2017 16:55
Antworten mit Zitat
Benutzer-Profile anzeigen
High,

ich bin grad dabei mit Sinus, Tangens und Co. zu experimentieren Cool .
Ich wollte mal fragen ob Ihr mir vielleicht ein paar Cracktros/ Intros/ Demos mit SinusEffekten nennen könnt. Ich meine ein paar Sachen die über den SinusScroll hinausgehen. Ich glaube mit Sinus und Co. werden/ wurden auch ein paar einfachere Bitmap Disturtions (wie z.b. Wobbler-Logo)durchgeführt!?
Mir ist alles willkommen (2D und 3D Sachen!) YouTube etc., Tutorials, CodeSnippets (bei den Sourcen kann ich BlitzBasics, PureBasic, FreeBasic, C/C++, Java, JavaScript) Wink .

Ich habe da leider nur eine magere Ausbeute.

https://www.youtube.com/watch?v=ZL1_ccli9kE
http://www.awsm.de/js-cracktros/awsm/
http://www.awsm.de/fullofsinus/



Vielen Dank Leute und "Happy New Year",
Flush

hectic

Sieger des IS Talentwettbewerb 2006

BeitragSa, Jan 07, 2017 17:14
Antworten mit Zitat
Benutzer-Profile anzeigen
Eine uralte Spielerei von mir:

Code: [AUSKLAPPEN]
Graphics 400,400,0,2
SetBuffer BackBuffer()

qq#=0
za#=0
x1#=0
y1#=0
x2#=0
y2#=0


While Not KeyHit(1)
   za=za+1
   
   LockBuffer BackBuffer()
   
   For qq=0 To 9999
      x1=Sin(qq/3)/4
      y1=Cos(qq/2)/8
      x2=Sin(qq*x1+za)*(qq+x1)/60
      y2=Cos(qq*y1)*(qq+y1)/60
      WritePixelFast 200+x2,200+y2,14737632
   Next
   
   UnlockBuffer BackBuffer()
   
   Flip
   Cls
Wend
End
Download der Draw3D2 V.1.1 für schnelle Echtzeiteffekte über Blitz3D

Flush

BeitragSa, Jan 07, 2017 17:24
Antworten mit Zitat
Benutzer-Profile anzeigen
@hectic
Sieht klasse aus.
Was ist das für eine Math. bzw Phys Formel?.
Sinus und Cos isr klar Laughing aber gibt es da in der Mathe bz. Physik besonders geeignete Gebiete?

Gruß;
Flush

hectic

Sieger des IS Talentwettbewerb 2006

BeitragSa, Jan 07, 2017 20:13
Antworten mit Zitat
Benutzer-Profile anzeigen
Es ist eine uralte Spielerei die ich noch mit PowerBasic gemacht hatte. Ich experimentierte selbst mit Sin und Cos rum, um daraus zu lernen. Letztendlich fand ich es interessant, dass man mit so wenig Code so einen Effekt erstellen kann.
Download der Draw3D2 V.1.1 für schnelle Echtzeiteffekte über Blitz3D

Flush

BeitragSo, Jan 08, 2017 15:24
Antworten mit Zitat
Benutzer-Profile anzeigen
@hectic
Stimmt, die Faszination mit wenig Quellcode schöne und sehr schöne (teils 3D)
Sachen zu machen, macht sich auch bei mir breit Exclamation
Mit Sources, Snippets und/ oder Tutorials egal in welcher Sprache sieht's nicht gut aus Crying or Very sad

Was ich finde poste ich hier, falls Interesse besteht.


Hier noch ein paar Links zum Sinus-Content:

CoppeRrulez Again:
https://www.youtube.com/watch?v=0_K81sZA3xc
The Angels Copper Master:
https://www.youtube.com/watch?v=h3FLdtkToBU
RamJam Copper Slave:
https://www.youtube.com/watch?v=iJA3xtrOtpI
Agile Breach 2 2.1
https://www.youtube.com/watch?v=sHAO-NcIKec
Jism & Fast Legends:
http://www.flashtro.com/index....mp;id=4318
Vision Cool Sinus:
https://www.youtube.com/watch?v=GQm9JZ5gx-o
Australian Crackers United ACU:
https://www.youtube.com/watch?v=ZL1_ccli9kE


Best regards,
Flush

Flush

BeitragMo, Jan 09, 2017 19:06
Antworten mit Zitat
Benutzer-Profile anzeigen
Hat sonst keiner mehr was Sad

Gruß,
Flush

hectic

Sieger des IS Talentwettbewerb 2006

BeitragDi, Jan 10, 2017 16:08
Antworten mit Zitat
Benutzer-Profile anzeigen
Ich hab nochmal in meinen alten Code nachgeschaut:


Raycaster - Mit der rechten Maustaste geht man vorwärts. Sin und Cos spielen hierbei die Rolle, abhängig der Blickrichtung des Spielers das Data-Feld auf Kollision abzutasten. Code: [AUSKLAPPEN]
Graphics 400,400,0,2
SetBuffer BackBuffer()
Origin 200,200
HidePointer

Dim xy(9,9) ;Spielfeld
xp#=1 ;Spieler-X-Position
yp#=1 ;Spieler-Y-Position
ws#=90 ;SPieler-Sollwinkel
wi#=90 ;Spieler-Istwinkel
hs#=0 ;Spieler-Sollhöhe
hi#=0 ;Spieler-Isthöhe
x#=0 ;Schleifenvariable
y#=0 ;Schleifenvariable
e#=0 ;Strahlentfernung zur Wand
w%=6 ;Winkeleinfang (tele/weit)
f%=0 ;Funktionsvariable

For y=0 To 9
 For x=0 To 9
  Read xy(x,y)
 Next
Next

Data 1,1,1,1,1,1,1,1,1,1
Data 1,0,1,0,0,0,0,0,0,1
Data 1,0,1,0,1,0,1,0,0,1
Data 1,0,0,0,1,0,0,0,0,1
Data 1,0,1,1,1,0,1,0,0,1
Data 1,0,1,0,0,0,0,0,0,1
Data 1,0,1,0,0,0,0,0,0,1
Data 1,0,1,1,1,1,1,1,0,1
Data 1,0,0,0,0,0,0,0,0,1
Data 1,1,1,1,1,1,1,1,1,1

;Hauptschleife
While Not KeyHit(1)

 ;Kopfbewegung
 ws=(ws+MouseXSpeed())/1.4
 hs=(hs+MouseYSpeed())/1.4
 wi=wi+ws/3/w
 hi=hi-hs/5
 MoveMouse 200,200
 If hi<-160 Then hi=-160
 If hi>160 Then hi=160

 ;Körperbewegung
 If KeyDown(203) Then wi=wi-16/w
 If KeyDown(205) Then wi=wi+16/w
 If KeyDown(200) Then If xy(xp+Cos(wi)/24,yp+Sin(wi)/24)=0 Then xp=xp+Cos(wi)/24:yp=yp+Sin(wi)/24
 If KeyDown(208) Then If xy(xp-Cos(wi)/24,yp-Sin(wi)/24)=0 Then xp=xp-Cos(wi)/24:yp=yp-Sin(wi)/24
 If MouseDown(2) Then If xy(xp+Cos(wi)/24,yp+Sin(wi)/24)=0 Then xp=xp+Cos(wi)/24:yp=yp+Sin(wi)/24
 If KeyHit(2) Then w=w-1:If w<1 Then w=1
 If KeyHit(3) Then w=w+1:If w>8 Then w=8

 ;Raycaster
 For x=-200 To 200 Step 2
  f=0
  For e=0 To 9 Step .02
   If f=0 Then
    If xy(xp+Cos(wi+x/w)*e,yp+Sin(wi+x/w)*e)=1 Then
     Color 255-e*24,255-e*24,255-e*24
     Rect x,hi-200/e,2,400/e
     f=1
    End If
   End If
  Next
 Next

 ;Map zeichnen
 Color 0,0,0
 Rect -200,-200,80,80,1
 Color 240,240,240
 For y=0 To 9
  For x=0 To 9
   If xy(x,y)=1 Then Rect x*8-200,y*8-200,8,8,1
  Next
 Next
 Rect xp*8-197.5,yp*8-197.5,3,3,1
 Line xp*8-196.5,yp*8-196.5,xp*8-196.5+Cos(wi)*4,yp*8-196.5+Sin(wi)*4

 Flip
 Cls
Wend
End

Mausverfolger - In Abhängigkeit Gegner zur Mausposition, dreht dieser sich immer über den kürzeren Kreis zur Maus hin. Code: [AUSKLAPPEN]
Graphics 400,400,0,2
SetBuffer BackBuffer()

Local Timer%=CreateTimer(100)
Local MX%=0        ;Maus-X-Position
Local MY%=0        ;Maus-Y-Position
Local XP#=100      ;Gegner-X-Position
Local YP#=100      ;Gegner-Y-Position
Local RW#=90       ;Gegner-Ist-Rotationswinkel
Local RR#=0        ;Gegner-Soll-Rotationswinkel

While Not KeyHit(1)
   MX=MouseX()
   MY=MouseY()
   
   RR=ATan2(MY-YP,MX-XP)
   RW=RW+Sgn(Sin(RR-RW))
   
   If Sqr((MX-XP)^2+(MY-YP)^2)>40 Then
      XP=XP+Cos(RW)/2
      YP=YP+Sin(RW)/2
   End If
   
   Color 255,0,0
   Line XP,YP,XP+Cos(RW)*10,YP+Sin(RW)*10
   Color 255,255,255
   Rect MX-4,MY-4,9,9,0
   Oval XP-4,YP-4,9,9,0
   
   WaitTimer Timer
   Flip 0
   Cls
Wend
End

Max-Wnk-Speed - Möchte man vermeiden das sich die Spielfigur diagonal schneller bewegt als horizontal oder vertikal, so kann man dafür folgendes Verwenden. Code: [AUSKLAPPEN]
Graphics 200,200,0,2
SetBuffer BackBuffer()

Local Timer=CreateTimer(58)
Local XP#,YP#
Local XS#,YS#
Local WK#,LN#

While Not KeyHit(1)
   
   If KeyDown(203) Then XS=XS-0.1
   If KeyDown(205) Then XS=XS+0.1
   If KeyDown(200) Then YS=YS-0.1
   If KeyDown(208) Then YS=YS+0.1
   
   WK=ATan2(YS,XS)
   LN=Sqr(XS*XS+YS*YS)*0.93
   If LN>1 Then LN=1
   
   XS=Cos(WK)*LN
   YS=Sin(WK)*LN
   
   XP=XP+XS*5
   YP=YP+YS*5
   
   Oval 25,25,150,150,0
   Line 100,100,100+XS*80,100+YS*80
   
   If XP>200 Then XP=XP-200
   If YP>200 Then YP=YP-200
   If XP<0 Then XP=XP+200
   If YP<0 Then YP=YP+200
   
   Rect XP-4,YP-4,9,9,1
   
   WaitTimer Timer
   Flip 0
   Cls
Wend
End

Weitere Spielerei - Habe so eine Animation vor wenigen Tagen als Gif-Animation gesehen. Also musste ich es mal eben selbst nachprogrammieren. Code: [AUSKLAPPEN]
Graphics 840,840,0,2
SetBuffer BackBuffer()
Local timer%=CreateTimer(58)
Local w#
Local count%
Local loop%
Const half#=0.707107
Origin 410,410

While Not KeyHit(1)
   
   Color 63,63,63
   Oval -390,-390,800,800,0
   Line 10,-390,10,+410
   Line -272,-272,+292,+292
   Line -390,10,+410,10
   Line -272,+292,+292,-272
   Color 192,192,192
   
   count=count+1
   
   For loop=0 To 3
      
      w=Cos(loop*45+count)*400
      
      If loop=0 Then Oval 0,w,20,20,1
      If loop=1 Then Oval w*half,w*half,20,20,1
      If loop=2 Then Oval w,0,20,20,1
      If loop=3 Then Oval w*half,-w*half,20,20,1
   Next
   
   Flip 0
   Cls
Wend
End
Download der Draw3D2 V.1.1 für schnelle Echtzeiteffekte über Blitz3D

Flush

BeitragDi, Jan 10, 2017 19:14
Antworten mit Zitat
Benutzer-Profile anzeigen
@hectic
Wooowww, super Codes Exclamation Very Happy ,

vielen Dank hectic.
Die uralte Spielerei zu Anfang gefällt mir persönlich am allerbesten Cool !


Gruß,
Flush

Neue Antwort erstellen


Übersicht BlitzBasic Allgemein

Gehe zu:

Powered by phpBB © 2001 - 2006, phpBB Group