• Es gelten die Regeln und zwar (wie ihr seht) im Sfx-Extra Modus!
  
• Erlaubte Sprachen sind: BlitzBasic3D, BlitzPlus, BlitzMax, Monkey.
  
• Ihr benötigt als Abgabe: Den Code, eine ausführbare Exe, die Sprachdateien, die BAT-Datei. Dazu könnt ihr eine Readme packen, oder einen ungecrunchten Quelltext.
  
• Das Schreiben von Dateien (z.B. Highscore) ist nicht erlaubt.
  
• Das Lesen von Dateien ist nicht nur erlaubt, sondern unumgänglich wegen der Sprachdateien .
  
• Ihr dürft auf Umgebungsvariablen lesend zugreifen.
  
• Jede Art von Skriptsprache ist nicht erlaubt.
  
• Es ist Aufgabe der Teilnehmer, den Veranstalter zu Unklarheiten bei den Regeln zu fragen. „Ich habe mein Programm vorgestellt und Niemand hat sich beschwert!!11!“ ist kein zulässiges Argument.
  
• Die Abstimmung wird dann bis zum nächsten Sonntag laufen. Der Teilnehmer, dessen Beitrag die meisten Stimmen auf sich vereint gewinnt, und darf den nächsten MiniBCC Ausrichten.
  

Strict
Framework brl.blitz
Import brl.audio
Import brl.oggloader
Import brl.directsoundaudio
Import brl.filesystem

Local s$, c, li, la, args$, i

Global one:TSound[], ten:TSound[], dig:TSound[], ext:TSound[], list:TSound[]

one = [ls("elf.ogg"), ls("zwoelf.ogg"), ls("drei.ogg"), ls("vier.ogg"), ls("fuenf.ogg"), ..
		ls("sech.ogg"), ls("sieb.ogg"), ls("acht.ogg"), ls("neun.ogg")]
ten = one[..]
ten[0] = ls("zehn.ogg")
ten[1] = ls("zwanzig.ogg")

dig = one[..]
dig[0] = ls("ein.ogg")
dig[1] = ls("zwei.ogg")
dig[5] = ls("sechs.ogg")
dig[6] = ls("sieben.ogg")

ext = [ls("eins.ogg"), ls("eine.ogg"), ls("und.ogg"), ls("million.ogg"), ..
		ls("tausend.ogg"), ls("hundert.ogg"), ls("zig.ogg"), ls("ssig.ogg")]
		
WriteStdout "Code by Thunder~nSound by Tagirijus~n~n"

For s = EachIn AppArgs[1..]
	args :+ s
Next
If FileType(args) = 1 Then file(args);End
args = args+"."

s=""
For i = 0 Until args.length

	c = args[i]
	If c >= Asc"0" And c <= Asc"9" Then 
		s :+ Chr c
	ElseIf s Then
		If li Then
			For Local i:Long = Long(la+1) To Long(s)
				WriteStdout "* "+String i+"~n"
				speak String i
			Next
			li = 0
		Else
			WriteStdout "* "+s+"~n"
			speak String Long s
			la = Int s
			If c = Asc"-" Then li = 1 
		EndIf
		s = ""
	EndIf

Next
End

Function file(s$)
	Local f:TStream = ReadFile(s), w:Short
	While Not Eof(f)
		w = ReadShort(f)
		WriteStdout w+", "
		speak String w
	Wend
	CloseFile f
EndFunction

Function speak(s$)
	Local a:TSound, ch:TChannel
	
	Delay 500
		
	If s.length<=3 Then
		speak_ s, 1
	ElseIf s.length <= 6 Then
		speak_ s[..s.length-3], 0
		list :+ [ext[4]]
		speak_ s[s.length-3..], 1
	ElseIf s.length <= 9 Then
		speak_ s[..s.length-6], 2
		list :+ [ext[3]]
		speak_ s[s.length-6..s.length-3], 0
		If s[s.length-6..s.length-3]<>"000" Then list :+ [ext[4]]
		speak_ s[s.length-3..], 1
	EndIf
	
	For a = EachIn list
		If a Then ch = a.Play()
		While ch.playing(); Delay 5; Wend
	Next
	list = Null	
EndFunction

Function ls:TSound(s:String)
	Return LoadSound(s)
EndFunction

Function n(x)
	Return x-Asc"1"
EndFunction

Function speak_(s$, e)

	If s.length = 3 Then
		If s[0] = Asc"0" Then
			If s[1] = Asc"0" Then s = s[2..] Else s = s[1..]
		Else
			list:+[dig[n(s[0])]]
			list:+[ext[5]]
			s = s[1..]
			e = 0
		EndIf
	EndIf
	
	If s.length = 2 Then
		
		Select s[0]
		Case Asc"0"
				
			If s[1] = Asc"1" Then list:+[ext[0]] ..
			ElseIf s[1] > Asc"1" Then list:+[dig[n(s[1])]]
				
		Case Asc"1"
			If s[1] > Asc"0" Then list :+ [one[n(s[1])]]
			If s[1] = Asc"0" Or s[1] > Asc"2" Then list :+ [ten[0]]
			
		Default
			
			If s[1] > Asc"0" Then list :+ [dig[n(s[1])], ext[2]]
			list :+ [ten[n(s[0])]]
			
			If s[0] = Asc"3" Then list :+ [ext[7]] ..
			ElseIf s[0] > Asc"3" Then list :+ [ext[6]]
			
		EndSelect
				
	Else
				
		Select e
		Case 1
			If s[0] = Asc"1" Then list:+[ext[0]] ..
			ElseIf s[0] > Asc"1" Then list:+[dig[n(s[0])]]
		Case 2
			If s[0] = Asc"1" Then list:+[ext[1]] ..
			ElseIf s[0] > Asc"1" Then list:+[dig[n(s[0])]]
		Default
			If s[0]<>Asc"0" Then list :+ [dig[n(s[0])]]
		EndSelect
		
	EndIf
	
EndFunction