Function ImgRectCollideFast(image,xpos1, ypos1, xpos2, ypos2, width2, height2, mask=0)

   Local startx, starty, endx, endy, ix, iy, x[3], y[3]

   Local width1  = ImageWidth(image)
   Local height1 = ImageHeight(image)

   xpos1   = xpos1 - ImageXHandle(image)
   ypos1   = ypos1 - ImageYHandle(image)

   startx = xpos2 - xpos1
   starty = ypos2 - ypos1
   endx   = startx + width2
   endy   = starty + height2

   If startx < 0       Then startx = 0
   If starty < 0       Then starty = 0
   If endx   > width1  Then endx   = width1
   If endy   > height1 Then endy   = height1

   endx = endx - 1
   endy = endy - 1

   If startx > endx Or starty > endy Then Return 0

   x[0] = startx
   y[0] = starty
   x[1] = (startx + endx) Shr 1
   y[1] = (starty + endy) Shr 1
   x[2] = endx
   y[2] = endy

   LockBuffer ImageBuffer(image)
   For ix = 0 To 2
      For iy = 0 To 2   
         If mask <> (ReadPixelFast(x[ix], y[iy], ImageBuffer(image)) And $00FFFFFF) Then
            UnlockBuffer ImageBuffer(image)
            Return 1
         EndIf
      Next
   Next
   UnlockBuffer ImageBuffer(image)

End Function