;========================================
; Fensterlose Applikation für [B3D, B+]; Freeware '2006 by East-Power-Soft

; Diese Funktionen "verstecken" das BlitzBasic Fenster (Titelleiste und Rahmen) und zeigen nur dessen Inhalt an
; Die Fensterposition kann verändert werden.

; Die nachfolgenden Zeilen (ohne REM) in eine decls Datei kopieren und im Userlibs Ordner von BB speichern:

;.lib "gdi32.dll"
;dll_CreateRectRgn% (X1%, Y1%, X2%, Y2%) : "CreateRectRgn"
;dll_DeleteObject% (hObject%) : "DeleteObject"

;.lib "user32.dll"
;dll_GetSystemMetrics% (nIndex%) : "GetSystemMetrics"
;dll_GetWindowRect% (hwnd%, lpRect*) : "GetWindowRect"
;dll_GetDesktopWindow% () : "GetDesktopWindow"
;dll_SetWindowPos% (hwnd%, hWndInsertAfter%, x%, y%, cx%, cy%, wFlags%) : "SetWindowPos"
;dll_GetActiveWindow% () : "GetActiveWindow"
;dll_SetWindowRgn% (hWnd%, hRgn%, bRedraw%) : "SetWindowRgn"
;========================================

Graphics 400,240,0,2

gw = GraphicsWidth()
gh = GraphicsHeight()
dw = DesktopWidth()
dh = DesktopHeight()

s$ = "......Fensterlose Applikation....."


SetBuffer BackBuffer()
Window_Hide()
Repeat

   If t<MilliSecs() Then
      t=MilliSecs()+30

      x=(dw-gw)/2 + 200*Cos(i#)
      y=(dh-gh)/2 + 200*Sin(i#)
      i#=(i#+0.5) Mod 360
      
      If p<Len(s$)-1 Then p=p+1 Else p=1

      Color 0,0,$FF0000:Rect 0,0,gw,gh,1
      Color 0,0,$FFFF00:Rect 0,0,gw,gh,0
      Color 0,0,$000000:Text gw/2,gh/2,Left$(s$,p),1,1

   End If
   
   Window_Setpos x,y

   Flip
Until KeyHit(1)



Function DesktopWidth()
;========================================
; Ermittle Windows Desktopbreite
;========================================
   Local struct_rect% = CreateBank(16)

   dll_GetWindowRect(dll_GetDesktopWindow(),struct_rect)
   Local res = PeekInt(struct_rect,8)
   FreeBank struct_rect

   Return res
End Function



Function DesktopHeight()
;========================================
; Ermittle Windows Desktophöhe
;========================================
   Local struct_rect% = CreateBank(16)

   dll_GetWindowRect(dll_GetDesktopWindow(),struct_rect)
   Local res = PeekInt(struct_rect,12)
   FreeBank struct_rect

   Return res
End Function



Function Window_Hide()
;========================================
; Verstecke BB Fenster
;========================================

   Local ww% = GraphicsWidth()
   Local wh% = GraphicsHeight()

   Local xoff% = dll_GetSystemMetrics(7)
   Local yoff% = dll_GetSystemMetrics(8) + dll_GetSystemMetrics(4)

   Local hRgn% = dll_CreateRectRgn(xoff, yoff, ww+xoff, wh+yoff)

   dll_SetWindowRgn(dll_GetActiveWindow(), hRgn, True)
   dll_DeleteObject(hRgn)

End Function



Function Window_SetPos(x%, y%)
;========================================
; Setze BB Fensterposition
;========================================

   Local xoff% = dll_GetSystemMetrics(7)
   Local yoff% = dll_GetSystemMetrics(8) + dll_GetSystemMetrics(4)

   dll_SetWindowPos(dll_GetActiveWindow(),0,x-xoff,y-yoff,0,0,5)

End Function