SX = 100
SY = 100
FeldS = 10
AppTitle "Spiel des Lebens"
Dim World(SX,SY)
Dim Oldworld(SX,SY)

Local born[9]
Local keepallive[9]

keepallive[2]=1
keepallive[3]=1
born[3]=1

Graphics (SX+1)*FeldS,(SY+1)*FeldS,16,2
ClsColor 255,255,255
Color 0,0,0
Repeat
 Cls
  For X = 0 To SY
   Line X*FeldS,0,X*FeldS,(SY+1)*FeldS
  Next
  For Y = 0 To SY
   Line 0,Y*FeldS,(SX+1)*FeldS,Y*FeldS
  Next

 For X = 0 To Sx
  For Y = 0 To SY
   If RectsOverlap(X*FeldS,Y*FeldS,FeldS,feldS,MouseX(),MouseY(),1,1)
    Color 255,0,0
    Rect X*FeldS,Y*FeldS,FeldS+1,FeldS+1,0
    Color 0,0,0
    If MouseHit(1) Then world(X,Y) = World(X,Y) Xor 1
   End If
   If World(X,Y) = 1 Then Oval X*FeldS+2,Y*FeldS+2,feldS-4,FeldS-4
   OldWorld(X,Y) = World(X,Y)
  Next
 Next

 If KeyHit(57) Or KeyDown(28)
 allive = 0
 For X = 0 To SX
  For Y = 0 To SY
   Count = 0

   For DX = -1 To 1
    For DY = -1 To 1
     If DX Or DY <> 0
      NewX = X+DX
      NewY = Y+DY
      If NewX < 0 Then newX = SX
      If NewX > SX Then NewX = 0
      If NewY < 0 Then newY = SY
      If NewY > SY Then NewY = 0
      If oldworld(NewX,NewY) = 1 Then Count = Count + 1
     End If
    Next
   Next
   world(x,y) = 0

   If oldworld(x,y) = 1 Then
    If keepallive[count] Then world(x,y) = 1:allive = allive + 1
   Else
    If born[count] Then world(X,Y) = 1: allive = allive + 1
   EndIf
  Next
 Next
; Print allive
 End If

 If KeyHit(46)
  For X = 0 To SX
   For Y = 0 To SY
    World(X,Y) = 0
   Next
  Next
 End If
 If KeyHit(19)
  For X = 0 To SX
   For Y = 0 To SY
    If Rand(0,1) = 1 Then World(X,Y) = 1
   Next
  Next
 End If

 Flip
 
Until KeyHit(1)