Graphics3D 800,600,32,2

Const partikelanz_max=1500         ;maximale Partikelanzahl im Frame
Const rauch_an=1               ;1=an 0=aus
Const feuerdichte=20            ;he höher um so mehr Feuerpartikel
Const rauchdichte=5               ;je höher um so mehr Rauchpartikel

SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global camera=CreateCamera()
PositionEntity camera,00,50,-250
Global firepartikel=CreateSprite()
cube=CreateCube()
PositionEntity cube,20,0,0
ScaleEntity cube,5,5,5

Global partikelanz=0

Type fire
Field partikel            ;Das Kopierte Entity
Field grob               ;Die Grobe Richtung des Partikels
Field r,g               ;Rot und Gelb Anteil
Field alpha#,alphablend#   ;Alpha und die Alphaänderung
Field speed#            ;Aufstiegsgesschwindigkeit
End Type
Type smoke
Field partikel
Field grob
Field r,g,b
Field alpha#,alphablend#
Field speed#
End Type

timer=CreateTimer(60)

While Not KeyHit(1)
   createfire()
   updatefire()
   updatesmoke()

   PointEntity camera,firepartikel         ;soll nur etwas um das feuer fahren
   MoveEntity camera,1,0,0
   
   WaitTimer(timer)

   UpdateWorld
   RenderWorld
   Text 10,10,partikelanz
   Flip 0

Wend


Function createfire()

If partikelanz<partikelanz_max
   For newfire=1 To feuerdichte
      f.fire=New fire
         f\partikel=CopyEntity(firepartikel)
         f\grob=Rnd(-1,1)
         f\r=255
         f\g=255
         f\alpha#=Rnd(0.2,0.4)
         f\alphablend#=Rnd(0.01,0.05)
         f\speed#=Rnd(0.1,1.6)
         partikelanz=partikelanz+1
         EntityFX f\partikel,17
   Next
End If
End Function
Function createsmoke(entity)

If partikelanz<partikelanz_max
   For newsmoke=1 To rauchdichte
      s.smoke=New smoke
         s\partikel=CopyEntity(entity)

         s\grob=Rnd(-1,1)
         graylevel=Rnd(30,90)
         s\r=graylevel
         s\g=graylevel
         s\b=graylevel
         s\alpha#=Rnd(0.2,0.4)
         s\alphablend#=Rnd(0.01,0.05)
         s\speed#=Rnd(0.1,1)
         partikelanz=partikelanz+1
         EntityFX s\partikel,17
   Next
End If
End Function
Function updatesmoke()
   For s.smoke=Each smoke
      ausweichen=Rnd(40)
      EntityAlpha s\partikel,s\alpha#
      s\alpha#=s\alpha+s\alphablend#
      If s\alpha#>0.8 Then s\alphablend#=Rnd(-0.05,-0.03)
      MoveEntity s\partikel,Rnd(-1.5,1.5)+0.2*s\grob,s\speed#,Rnd(-1.5,1.5)+0.2*s\grob
      EntityColor s\partikel,s\r,s\g,s\b   
      If s\alpha#<=0 Then
         partikelanz=partikelanz-1
         FreeEntity s\partikel
         Delete s
      End If         
   Next
         
End Function
Function updatefire()
   For f.fire=Each fire
      ausweichen=Rnd(40)

      EntityAlpha f\partikel,f\alpha#
      f\alpha#=f\alpha#+f\alphablend#
      If f\alpha#>0.8 Then f\alphablend#=Rnd(-0.15,-0.1)
      MoveEntity f\partikel,Rnd(-1.5,1.5)+0.2*f\grob,f\speed#,Rnd(-1.5,1.5)+0.2*f\grob
      EntityColor f\partikel,f\r,f\g,0
      If f\r > 50 Then f\r = f\r - 5
      f\g = f\g - Rnd(10,20)
      If f\alpha#<=0 Or f\r<20 Then
         partikelanz=partikelanz-1
         If f\speed#>1.5 And partikelanz<partikelanz_max-200 And rauch_an=1Then
            createsmoke(f\partikel)
         End If
         FreeEntity f\partikel
         Delete f
      End If
   Next
End Function