Type TDirEnum

	Field _dir:Int
	Field _path:String
	Field _stripParent:Int
	Field _fileTmp:TFile
	Field _filter:Byte

	Method HasNext:Int()
		Local name:String = NextFile(_dir)

		If _stripParent
			While name = "." Or name = ".."
				name = NextFile(_dir)
			Wend
		End If

		While Not (FileType(_path + "/" + name) & _filter) And name <> ""
			name = NextFile(_dir)
		Wend

		_fileTmp = TFile.Open(_path + "/" + name)
		Return (name <> "")
	End Method

	Method NextObject:Object()
		Return _fileTmp
	End Method

	Method Delete()
		CloseDir(_dir)
	End Method

End Type

Type TFile
	Field _name:String
	Field _path:String
	Field _fullPath:String
	Field _type:Int
	Field _stripParent:Int
	Field _filter:Byte

	Function Open:TFile(path:String)
		Local dir:TFile = New TFile

		?Win32
			If path.EndsWith("\\") path = path[..path.length - 1]
		?Linux
			If path.EndsWith("/") path = path[..path.length - 1]
		?MacOs
			If path.EndsWith("/") path = path[..path.length - 1]
		?

		dir._type = FileType(path)
		dir._name = StripDir(path)
		dir._path = ExtractDir(path)
		dir._fullPath = path
		dir._filter = FILETYPE_FILE|FILETYPE_DIR
		Return dir
	End Function

	Method Name:String()
		Return _name
	End Method

	Method Path:String()
		Return _fullPath
	End Method

	Method ParentDirectory:String()
		Return _path
	End Method

	Method Typ:Int()
		Return _type
	End Method

	Method Mode:Int()
		Return FileMode(_fullPath)
	End Method

	Method Size:Int()
		Return FileSize(_fullPath)
	End Method

	Method Time:Int()
		Return FileTime(_fullPath)
	End Method

	Method ObjectEnumerator:TDirEnum()
		If _type <> FILETYPE_DIR Return Null
	
		Local enum:TDirEnum = New TDirEnum
		enum._dir = ReadDir(_fullPath)
		enum._path = _fullPath
		enum._stripParent = _stripParent
		enum._filter = _filter
		Return enum
	End Method

	Method stripParent()
		_stripParent = True
	End Method

	Method Filter(f:Byte)
		_filter = f
	End Method

	Method Extension:String()
		Return ExtractExt(_name)
	End Method

	Method Rename(newName:String)
		RenameFile(_fullPath, _path + "/" + newName)
		_fullPath = _path + "/" + newName
		_name = newName
	End Method

	Method SetMode(mode:Byte)
		SetFileMode(_fullPath, mode)
	End Method

	Method Write:TStream()
		If _type <> FILETYPE_FILE Return Null

		Return WriteFile(_fullPath)
	End Method

	Method Read:TStream()
		If _type <> FILETYPE_FILE Return Null

		Return ReadFile(_fullPath)
	End Method

	Method Content:String[]()
		If _type <> FILETYPE_DIR Return Null

		Return LoadDir(_fullPath)
	End Method

End Type

Local md:TFile = TFile.Open("C:\Users\Fabian\Downloads")
md.stripParent()
printDir(md)

Function printDir(d:TFile)
	For Local file:TFile = EachIn d
		If file.Time() >= 1253636100 Print "File: " + file.Path()

		If file.Typ() = FILETYPE_DIR
			Local dir:TFile = TFile.open(file.path())
			dir.stripParent()
			printDir(dir)
		End If

	Next
End Function