TGui.font_normal = LoadImageFont(gfx_dir+"\verdana.ttf", 12)
      Print (Not TGui.font_normal = Null)
      SetImageFont(TGui.font_normal)

'gui.bmx
Rem
Autor: Dustin Paasch
Information: GUI Modul für den Apace-Online-Shooter
Copyright: Copyright 2010 by Dustin Paasch
EndRem
SuperStrict

Global GUI_COLOR:Byte[] = [Byte(108),Byte(108),Byte(150)]
'Const GUI_COLOR:Byte[0]   = 128
'Const GUI_COLOR:Byte[1]   = 128
'Const GUI_COLOR:Byte[2]   = 170

Const WINDOW_CLOSE:Byte      = %00000001
Const WINDOW_MOVABLE:Byte   = %00000010

Const POINTER_NORMAL:Byte   = 0
Const POINTER_NO:Byte      = 1

Type TGui
   Global element_list:TList
   Global pressed_button:TGuiButton
   Global mx:Int, my:Int, mbuffer1:Byte, mbuffer2:Byte, pointer:Byte
   Global image_window:TImage, image_button:TImage, image_pointer:TImage
   Global font_normal:TImageFont
   
   Function Init(gfx_dir:String = "gui_gfx")
      TGui.element_list = New TList
      TGui.image_window = LoadImage(gfx_dir+"\window.png")
      TGui.image_button = LoadAnimImage(gfx_dir+"\button.png", 16, 16, 0, 3)
      TGui.image_pointer = LoadAnimImage(gfx_dir+"\mouse.png", 12, 14, 0, 4)
      TGui.font_normal = LoadImageFont(gfx_dir+"\verdana.ttf", 12)
      Print (Not TGui.font_normal = Null)
      SetImageFont(TGui.font_normal)
      SetBlend(ALPHABLEND)
      HideMouse()
   EndFunction
   
   Function Update()
      TGui.pressed_button = Null
      TGui.mbuffer2 = TGui.mbuffer1
      TGui.mbuffer1 = MouseDown(1)
      TGui.mx = MouseX()
      TGui.my = MouseY()
      TGui.pointer = POINTER_NORMAL
      For Local element:TGuiWindow = EachIn TGui.element_list
         element.Draw()
         element.Update()
      Next
      SetColor(255, 255, 255)
      DrawImage(TGui.image_pointer, TGui.mx, TGui.my, TGui.pointer)
   EndFunction
   
   Function PointerTouch:Byte(x:Int, y:Int, sx:Short, sy:Short)
      If TGui.mx>=x And TGui.mx<x+sx And TGui.my>=y And TGui.my<y+sy
         Return(True)
      EndIf
      Return(False)
   EndFunction
EndType

Type TGuiWindow
   Field x:Int, y:Int, sx:Short, sy:Short, title:String, sf_x:Float, sf_y:Float, list:TList, movable:Byte, close:TGuiButton
   
   Function Create:TGuiWindow(title:String, x:Int, y:Int, sx:Short, sy:Short, flags:Byte = WINDOW_CLOSE|WINDOW_MOVABLE)
      Local tmp:TGuiWindow = New TGuiWindow
      TGui.element_list.AddLast(tmp)
      tmp.list = New TList
      tmp.title = title
      tmp.x = x
      tmp.y = y
      tmp.sx = sx
      tmp.sy = sy
      tmp.sf_x = tmp.sx/128.0
      tmp.sf_y = tmp.sy/128.0
      tmp.movable = False
      If flags & WINDOW_MOVABLE = WINDOW_MOVABLE Then tmp.movable = True
      If flags & WINDOW_CLOSE = WINDOW_CLOSE Then tmp.close = TGuiButton.Create(tmp, "X", tmp.sx-18, 2, 16)
      Return(tmp)
   EndFunction
   
   Method Draw()
      SetColor(255, 255, 255)
      SetScale(Self.sf_x, Self.sf_y)
      DrawImage(TGui.image_window, Self.x, Self.y)
      SetScale(1.0, 1.0)
      DrawText(Self.title+" "+Self.movable, Self.x+2, Self.y+2)
   EndMethod
   
   Method Update()
      For Local element:TGuiButton = EachIn Self.list
         element.Draw()
         element.Update()
      Next
      If Self.close And TGui.pressed_button = Self.close Then Self.Free()
   EndMethod
   
   Method Free()
      TGui.element_list.Remove(Self)
   EndMethod
EndType

Type TGuiButton
   Field parent:TGuiWindow, x:Short, y:Short, length:Float, title:String, active:Byte, status:Byte
   
   Function Create:TGuiButton(parent:TGuiWindow, title:String, x:Short, y:Short, length:Short = 96, active:Byte = True)
      Local tmp:TGuiButton = New TGuiButton
      parent.list.AddLast(tmp)
      tmp.parent = parent
      tmp.x = x
      tmp.y = y
      tmp.title = title
      tmp.length = length/16.0
      tmp.active = active
      Return(tmp)
   EndFunction
   
   Method Draw()
      Local x:Int = Self.parent.x+Self.x, y:Int = Self.parent.y+Self.y, c:Byte = 127 + Self.active*128
      SetColor(c, c, c)
      SetScale(Self.length, 1.0)
      DrawImage(TGui.image_button, x, y, Self.status)      
      SetScale(1.0, 1.0)
      SetColor(GUI_COLOR[0], GUI_COLOR[1], GUI_COLOR[2])
      DrawRect(x, y-1, Self.length*16, 1)
      DrawRect(x-1, y, 1, 16)
      DrawRect(x+Self.length*16, y, 1, 16)
      DrawRect(x, y+16, Self.length*16, 1)
      SetColor(c, c, c)
      DrawText(Self.title, x+4, y)
   EndMethod
   
   Method Update()
      Self.status = 0
      If Self.active
         If TGui.PointerTouch(Self.parent.x+Self.x, Self.parent.y+Self.y, Self.length*16.0, 16)
            Self.status = 1
            If TGui.mbuffer2=True
               Self.status = 2
               If TGui.mbuffer1=False Then TGui.pressed_button = Self
            EndIf
         EndIf
      EndIf
   EndMethod
EndType



Graphics 640,480,16,50
SetGraphicsDriver( D3D9Max2DDriver() )

TGui.Init()
Local w:TGuiWindow = TGuiWindow.Create("Testfenster",10,10,600,400)
TGuiButton.Create(w, "Ok", 10, 180, 96, True)
TGuiButton.Create(w, "Nein Mann!", 300-106, 180, 96, True)
Local timer:TTimer = CreateTimer(50)

While Not AppTerminate()
   TGui.Update()
   Flip(0);Cls;WaitTimer(timer)
Wend