; ###### GUIExt Include
; #### Autor: Viken Emesh aka Hazumu-kun
; #### e-Mail: vikenemesh@live.de
; #### Homepage: http://vikenemesh.bplaced.net
; #### Beschreibung:
; ####		Fügt BlitzPlus nützliche GUI Funktionen hinzu.
; ******

;Decls für die Funktionen (als winapi.decls in das userlib Verzeichnis speichern oder an vorhandene Dateien anhängen):
; .lib "user32.dll"
; api_GetForegroundWindow% () : "GetForegroundWindow"
; api_GetWindowLong% (hwnd%, nIndex%) : "GetWindowLongA"
; api_SetWindowLong% (hwnd%, nIndex%, dwNewLong%) : "SetWindowLongA"
; api_ShowWindow% (hwnd%, nCmdShow%) : "ShowWindow"
; api_GetActiveWindow% () : "GetActiveWindow"
; api_SetClassLong% (hwnd%, nIndex%, dwNewLong%) : "SetClassLongA"
;
; .lib "Shell32.dll"
; LoadIcon%(hWND%,File$,Index%) : "ExtractIconA"

; #### guiext.lib.bb Variablen/Konstanten
Global guiext_desktop= Desktop()

Const SW_HIDE=		  0
Const SW_SHOWNORMAL=  1
Const GWL_STYLE= 	-16
; ****

; #### Testcode
Global win= CreateWindow ("Groupbox Text",50,50,400,300,guiext_desktop,33)

; Erst die GroupBox erstellen
Global gb= guiext_CreateGroupBox ("Gruppe",5,5,390,290,win)
; Dann das Panel
Global gb_pane= guiext_CreateGroupboxPanel (gb, win)
; NUR DEM PANEL werden Childs hinzugefügt
Global but= CreateButton ("Test",15,25,360,250,gb_pane,0)

guiext_AddMinimizeButton (win)
guiext_CenterWindow (win)

While Not KeyHit(1)
	Select WaitEvent()
		Case $803
			End
		Case $401
			Notify "Funktioniert!"
	End Select
Wend
; ****

; #### guiext.lib.bb Funktionen
Function guiext_CenterWindow (fwinhndl)
	Local fwinh, fwinw, fdesk, fdeskw, fdeskh
	
	fwinw= ClientWidth (fwinhndl)
	fwinh= ClientHeight (fwinhndl)
	fdesk= Desktop()
	fdeskw= ClientWidth(fdesk)
	fdeskh= ClientHeight(fdesk)
	SetGadgetShape fwinhndl,(fdeskw-fwinw)/2,(fdeskh-fwinh)/2,fwinw,fwinh
End Function

Function guiext_DeskWidth ()
	Return ClientWidth(guiext_desktop)
End Function

Function guiext_DeskHeight ()
	Return ClientHeight(guiext_desktop)
End Function

Function guiext_AddMinimizeButton (window=0)
	;Fügt einem Fenster den Minimieren-Knopf hinzu ohne den Maximieren-Knopf
	;oder die Skalierung eines Fensters zu aktivieren.
	Local window_hwnd
	Local window_oldstyle
	
	If window=0 Then
		window_hwnd= api_GetForegroundWindow()
	Else
		window_hwnd= QueryObject(window,1)
	EndIf
	
	window_oldstyle= api_GetWindowLong (window_hwnd,(-16))
	
	api_SetWindowLong (window_hwnd, -16, window_oldstyle Or $00020000)
	
	If window Then
		HideGadget window
		ShowGadget window
	Else
		api_ShowWindow(window_hwnd,SW_HIDE)
		api_ShowWindow(window_hwnd,SW_SHOWNORMAL)
	EndIf
End Function

Function guiext_CreateGroupBox (name$, x, y, width, height, parent)
	;Erstellt eine Groupbox
	Local groupbox, hwnd
	
	groupbox = CreateButton (name$, x, y, width, height, parent)
	hwnd = QueryObject (groupbox, 1)
	api_SetWindowLong (hwnd, GWL_STYLE, api_GetWindowLong(hwnd, GWL_STYLE)+7)
	
	Return groupbox
End Function

Function guiext_CreateGroupboxPanel (groupbox, parent)
	;Erstellt ein Panel für eine Groupbox um Childs hinzuzufügen
	Return CreatePanel (GadgetX(groupbox),GadgetY(groupbox),GadgetWidth(groupbox),GadgetHeight(groupbox),parent)
End Function

Function guiext_setAppIcon (icon_file$,window=0)
	;Läd eine 16x16 *.ico Datei und fügt das Icon in die Titelleiste des Fensters ein.
	Local hwnd,icon
	
	If window Then
		hwnd= QueryObject (window,1)
	Else
		hwnd = api_GetActiveWindow()
	EndIf
	icon = LoadIcon(hwnd,icon_file$,0)
	api_SetClassLong hwnd,-14,icon
End Function
; ****

Global PlayerGrpBox = guiext_CreateGroupBox( "Player", 390, 14, 370, 190, ServerWindow ) 
Global ServerGrpBox = guiext_CreateGroupBox( "Server", 390, 220, 370, 197, ServerWindow ) 
Global AccountGrpBox = guiext_CreateGroupBox( "Accounts", 10, 20, 370, 390, ServerWindow ) 

Global PlayerGrpBox_Panel= guiext_CreateGroupboxPanel (PlayerGrpBox, ServerWindow)
Global ServerGrpBox_Panel= guiext_CreateGroupboxPanel (ServerGrpBox, ServerWindow)
Global AccountGrpBox_Panel= guiext_CreateGroupboxPanel (AccountGrpBox, ServerWindow)