;BSP REader by mk
;
;Quelle:
;http://www.geocities.com/cofrdrbob/bspformat.html
;-----------------------------------------------------------------------------------------------------

Global entity_count=0
   Type entity_keyvalue
      Field id
      Field key$,value$
   End Type
   
   Type entity_raw
      Field txt$
   End Type
   
   Type entity
      Field name$
      Field x#,y#,z#
   End Type

Global edge_count=0
   Dim edge_v(255999,1)
   Type edge_line
      Field x1#,x2#,y1#,y2#,z1#,z2#
   End Type

Global surfedge_count=0
   Dim surfedge_index(511999)

Global vertex_count=0
   Dim vertex_x#(65535)
   Dim vertex_y#(65535)
   Dim vertex_z#(65535)
   Dim vertex_id(65535)

Global face_count=0
   Dim face_planenum(65535)
   Dim face_side(65535)
   Dim face_onNode(65535)
   Dim face_firstedge(65535)
   Dim face_numedges(65535)
   Dim face_texinfo(65535)
   Dim face_dispinfo(65535)
   Dim face_surfaceFogVolumeID(65535)
   Dim face_styles(65535,3)
   Dim face_lightofs(65535)
   Dim face_area#(65535)
   Dim face_LightmapTextureMinsInLuxels(65535,1)
   Dim face_LightmapTextureSizeInLuxels(65535,1)
   Dim face_origFace(65535)
   Dim face_numPrims(65535)
   Dim face_firstPrimID(65535)
   Dim face_smoothingGroups(65535)



;Include "include/debug.bb"

Global bspfile_path$="c:\bsp.bsp"
;Global bspfile_path$="bsp2.bsp"

Global file,logfile

Print "Loading "+bspfile_path
file=OpenFile(bspfile_path)
If Not file Then
   RuntimeError(bspfile_path+" existiert nicht.")
EndIf

WriteFile(bspfile_path+".log")
logfile=OpenFile(bspfile_path+".log")


;dheader_t
debug("---------- HEADER ----------")
debug("")
debug("Identifier: VBSP")

If ReadByte(file)=86 And ReadByte(file)=66 And ReadByte(file)=83 And ReadByte(file)=80 Then
   debug("Mapfile OK")
Else
   debug("Mapfile Damaged")
   RuntimeError(bspfile_path+" is not a valid BSP File!")
EndIf
version=ReadInt(file)
debug("Version: "+version)
debug("")
debug("---------- LUMP DATA ----------")
debug("")

Dim lump_t_fileofs(63)
Dim lump_t_filelen(63)
Dim lump_t_version(63)
Dim lump_t_fourCC(63,3)


For i=0 To 63
lumpstart=FilePos(file)
r1=ReadInt(file)
r2=ReadInt(file)
r3=ReadInt(file)
r4=ReadByte(file)
r5=ReadByte(file)
r6=ReadByte(file)
r7=ReadByte(file)

debug("Lump Data   (Lump "+i+")")
debug("   "+r1+"   Datenanfang(Bytes)")
debug("   "+r2+"   Länge(Bytes)")
debug("   "+r3+"   Version")
debug("   "+r4+","+r5+","+r6+","+r7+" Indentifier")
debug("End of Lump")

lump_t_fileofs(i)=r1
lump_t_filelen(i)=r2
lump_t_version(i)=r3
lump_t_fourCC(i,0)=r4
lump_t_fourCC(i,1)=r5
lump_t_fourCC(i,2)=r6
lump_t_fourCC(i,3)=r7
Next

debug("")
mapRevision=ReadInt(file)
debug("Hammer Editor Anzahl Saves: "+mapRevision)
debug("")

For i=0 To 63
SeekFile(file,lump_t_fileofs(i))
Select i
   Case 0
   lump_entity()
   Case 3
   lump_vertex()
   Case 7
   lump_face()
   Case 12
   lump_edge()
   Case 13
   lump_surfedge()
End Select
Next

CloseFile file


Local cam_rot_pitch#,cam_rot_yaw#,cam_rot_roll#

Graphics3D 1024,768,0,2
SetBuffer BackBuffer()

font=LoadFont("Arial",14,0,0,0)
font_debug=LoadFont("Arial",15,1,0,0)
SetFont font_debug

Print "Initializing World"
cam=CreateCamera()
PositionEntity cam,0,10,-20
;plane=CreatePlane()

radius=CreateSphere(6)
EntityColor radius,0,128,255
EntityAlpha radius,0.125
ScaleEntity radius,32,32,32
EntityBlend radius,3
EntityFX radius,1
FlipMesh radius
EntityParent radius,cam

middle=CreateSphere(12)
EntityColor middle,255,0,0
PointEntity cam,middle
cam_rot_pitch=EntityPitch(cam)
cam_rot_yaw=EntityYaw(cam)
cam_rot_roll=EntityRoll(cam)
light=CreateLight(1)

map=CreateMesh()
surf=CreateSurface(map)

Print "Creating Map"
;Create map
For i=0 To vertex_count-1
   vertex_id(i)=AddVertex(surf,vertex_x(i),vertex_y(i),vertex_z(i)) ;vertices erstellen
Next

For i=0 To face_count-1 ;faces durchgehen
   For i2=face_firstedge(i) To face_firstedge(i)+face_numedges(i)-1 Step 1 ;Surfedges die zum face gehören
      i3=Abs(surfedge_index(i2))   ;i3 ist der positive surfedge index (gibt die zugehörige edge an)
      For i4=1 To edge_count-1   ;alle edges durchgehen
         If i4=i3 Then   ;wenn edge = surfedge index
            If Sgn(surfedge_index(i2))>0 Then
               AddTriangle(surf,vertex_id(edge_v(i4,0)),vertex_id(edge_v(i4,1)),vertex_id(edge_v(i4-1,0)))
            Else ;---> add triangle letztes vertex als test
               AddTriangle(surf,vertex_id(edge_v(i4-1,0)),vertex_id(edge_v(i4,1)),vertex_id(edge_v(i4,0)))
            EndIf
         EndIf
      Next
   Next
Next

UpdateNormals map

For i=0 To entity_count
   e2.entity = New entity
   For e.entity_keyvalue = Each entity_keyvalue
      ;debug("#"+e\id+" | "+e\key+" | "+e\value)
      If e\id=i Then
         Select e\key
         Case "classname"
         e2\name=e\value
         Case "origin_1"
         e2\x=Float(e\value)/10
         Case "origin_2"
         e2\z=Float(e\value)/10
         Case "origin_3"
         e2\y=Float(e\value)/10
         Case "rendercolor_1"
         ;e2\x=e\value
         Case "rendercolor_2"
         ;e2\z=e\value
         Case "rendercolor_3"
         ;e2\y=e\value
         End Select
      EndIf
   Next
   debug(e2\name+" | "+e2\x+" | "+e2\y+" | "+e2\z)
Next


For e2.entity = Each entity
   Select e2\name
   Case "info_node"
      c=CreateCube()
      PositionEntity c,e2\x,e2\y,e2\z
      ScaleEntity c,1.5,0.2,1.5
      EntityColor c,255,255,0
      EntityAlpha c,0.5
   Case "info_node_hint"
      c=CreateCube()
      PositionEntity c,e2\x,e2\y,e2\z
      ScaleEntity c,1.5,0.2,1.5
      EntityColor c,255,128,0
      EntityAlpha c,0.5
   Case "info_player_start"
      c=CreateCube()
      PositionEntity c,e2\x,e2\y,e2\z
      ScaleEntity c,3.2,6.4,3.2
      EntityColor c,0,255,0
      EntityAlpha c,0.5
   End Select
Next
c=0

For i=0 To edge_count-1
   v1_ok=0
   v2_ok=0
   For i2=0 To vertex_count-1
      If i2=edge_v(i,0) Then
         v1_x=vertex_x(i2)
         v1_y=vertex_y(i2)
         v1_z=vertex_z(i2)
         v1_ok=1
      EndIf
      If i2=edge_v(i,1) Then
         v2_x=vertex_x(i2)
         v2_y=vertex_y(i2)
         v2_z=vertex_z(i2)
         v2_ok=1
      EndIf
      If v1_ok And v2_ok Then
         Exit
      EndIf
   Next
   e3.edge_line = New edge_line
   e3\x1=v1_x
   e3\y1=v1_y
   e3\z1=v1_z
   e3\x2=v2_x
   e3\y2=v2_y
   e3\z2=v2_z
Next

timer=CreateTimer(60)

Repeat
WaitTimer timer
md=MouseDown(1)
mxs#=MouseXSpeed()
mys#=MouseYSpeed()

If md Then
   MoveMouse(400,300)
   cam_rot_pitch=cam_rot_pitch+mys/2
   cam_rot_yaw=cam_rot_yaw-mxs/2
   cam_rot_roll=0
   If cam_rot_pitch>90 Then cam_rot_pitch=90
   If cam_rot_pitch<-90 Then cam_rot_pitch=-90
   RotateEntity cam,cam_rot_pitch,cam_rot_yaw,cam_rot_roll
EndIf



RotateEntity cam,EntityPitch(cam)+MouseYSpeed(),EntityYaw(cam)-MouseXSpeed(),0



If KeyDown(17) Then MoveEntity cam,0,0,1
If KeyDown(31) Then MoveEntity cam,0,0,-1
If KeyDown(32) Then MoveEntity cam,1,0,0
If KeyDown(30) Then MoveEntity cam,-1,0,0

WireFrame KeyDown(57)


RenderWorld()


SetFont font
For e2.entity = Each entity
   abstand=Sqr((e2\x-EntityX(cam))^2+(e2\z-EntityZ(cam))^2)
   abstand2=Sqr((e2\x-EntityX(cam))^2+(e2\y-EntityY(cam))^2)
   abstand3=Sqr((e2\z-EntityZ(cam))^2+(e2\y-EntityY(cam))^2)
   abstand=(abstand+abstand2+abstand3)/3
   If abstand<32 Then
      CameraProject(cam,e2\x,e2\y,e2\z)
      If ProjectedZ() Then
      Color 255,128,0
         Text ProjectedX(),ProjectedY(),e2\name,1,1
      EndIf
   EndIf
Next

Color 0,255,0
LockBuffer BackBuffer()
For e3.edge_line = Each edge_line
CameraProject(cam,e3\x1,e3\y1,e3\z1)
x1=ProjectedX()
y1=ProjectedY()
z1=ProjectedZ()
CameraProject(cam,e3\x2,e3\y2,e3\z2)
x2=ProjectedX()
y2=ProjectedY()
z2=ProjectedZ()
If z1 And z2 Then
   Line x1,y1,x2,y2
EndIf
Next
UnlockBuffer BackBuffer()

Color 255,255,255
SetFont font_debug
Text 0,0,"Vertices: "+vertex_count
Text 0,15,"Edges: "+edge_count
Text 0,30,"SurfEdges: "+surfedge_count
Text 0,45,"Faces: "+face_count

; ==== FPS-Counter ====>>
   syszeit=MilliSecs()
   If syszeit>fpszeit+1000
      fps=fpsct : fpszeit=syszeit : fpsct=0
   Else
      fpsct=fpsct+1
   EndIf
; <<====

Text 200,0,"FPS: "+fps
Text 200,15,"Tris Rendered: "+TrisRendered()

Color 0,255,0
Text 350,0,"Edges"
Color 255,128,0
Text 350,15,"Entities"

Flip 0
Cls
Until KeyHit(1)
CloseFile logfile

;----------------- LUMP Funktonen ---------------------

Function lump_entity()
Local tempstr$
debug("---------- Entity Data (Lump 0) ----------")
   For i=0 To lump_t_filelen(0)
      byte=ReadByte(file)
      ;DebugLog byte+" | "+Chr(byte)
      If byte=10 Then
         WriteLine(logfile,tempstr)
         e.entity_raw = New entity_raw
         e\txt=tempstr
         tempstr=""
      Else
         tempstr=tempstr+Chr(byte)
      EndIf   
   Next
   
   debug("")
   entity_parse()
   debug("")
End Function

Function lump_vertex()
bf=FilePos(file)
debug("---------- Vertex Data (Lump 3) ----------")
   For i=0 To (lump_t_filelen(3)-1)/12
      vertex_x#(i)=ReadFloat(file)/10
      vertex_z#(i)=ReadFloat(file)/10
      vertex_y#(i)=ReadFloat(file)/10
      debug(i+". "+"X: "+vertex_x#(i)+" | Y: "+vertex_y#(i)+" | Z: "+vertex_z#(i))
   Next
   vertex_count=i
   debug("")
   DebugLog FilePos(file)-bf
End Function

Function lump_edge()
debug("---------- Edge Data (Lump 12) ----------")
   For i=0 To (lump_t_filelen(12)-1)/4

      edge_v(i,0)=ReadShort(file)
      edge_v(i,1)=ReadShort(file)
      debug("Edge "+i+":Vertex Index: "+edge_v(i,0)+" + "+edge_v(i,1))
   Next
   edge_count=i
   debug("")
End Function

Function lump_surfedge()
debug("---------- SurfEdge Data (Lump 13) ----------")
   For i=0 To (lump_t_filelen(13)-1)/4
      surfedge_index(i)=ReadInt(file)
      debug("SurfEdge "+i+":Index: "+surfedge_index(i))
   Next
   surfedge_count=i
   debug("")
End Function


Function lump_face()
debug("---------- Face Data (Lump 7) ----------")
   For i=0 To (lump_t_filelen(13)-1)/56
      face_planenum(i)=ReadShort(file)
      face_side(i)=ReadByte(file)
      face_onNode(i)=ReadByte(file)
      face_firstedge(i)=ReadInt(file)
      face_numedges(i)=ReadShort(file)
      face_texinfo(i)=ReadShort(file)
      face_dispinfo(i)=ReadShort(file)
      face_surfaceFogVolumeID(i)=ReadShort(file)
      face_styles(i,0)=ReadByte(file)
      face_styles(i,1)=ReadByte(file)
      face_styles(i,2)=ReadByte(file)
      face_styles(i,3)=ReadByte(file)
      face_lightofs(i)=ReadInt(file)
      face_area(i)=ReadFloat(file)
      face_LightmapTextureMinsInLuxels(i,0)=ReadInt(file)
      face_LightmapTextureMinsInLuxels(i,1)=ReadInt(file)
      face_LightmapTextureSizeInLuxels(i,0)=ReadInt(file)
      face_LightmapTextureSizeInLuxels(i,1)=ReadInt(file)
      face_origFace(i)=ReadInt(file)
      face_numPrims(i)=ReadShort(file)
      face_firstPrimID(i)=ReadShort(file)
      face_smoothingGroups(i)=ReadInt(file)
      
      debug("### Face: "+i+" ###")
      debug("Plane Nummer: "+face_planenum(i))
      debug("Faces opposite to plane: "+face_side(i))
      debug("1: on node | 0: On leaf: "+face_onNode(i))
      debug("Surfedge Index: "+face_firstedge(i))
      debug("Number of Surfedges: "+face_numedges(i))
      debug("Texinfo: "+face_texinfo(i))
      debug("Displ Info: "+face_dispinfo(i))
      debug("Fog: "+face_surfaceFogVolumeID(i))
      debug("Light Styles:"+face_styles(i,0)+" | "+face_styles(i,1)+" | "+face_styles(i,2)+" | "+face_styles(i,3))
      debug("Light offset: "+face_lightofs(i))
      debug("Face area: "+face_area(i))
      debug("Lightning info: "+face_LightmapTextureMinsInLuxels(i,0))
      debug("Lightning info: "+face_LightmapTextureMinsInLuxels(i,1))
      debug("Lightning info: "+face_LightmapTextureSizeInLuxels(i,0))
      debug("Lightning info: "+face_LightmapTextureSizeInLuxels(i,1))
      debug("Original Face: "+face_origFace(i))
      debug("Primitives: "+face_numPrims(i))
      debug("First Prim: "+face_firstPrimID(i))
      debug("SmoothingGroups: "+face_smoothingGroups(i))
   Next
   face_count=i
   debug("")
End Function



;------------------- Andere Funktionen -----------------


Function entity_parse()
Local brackets
Local key$,value$,temp$
Local nr1,nr2,nr3,nr4
Local v1$,v2$,v3$
Local cnt,i
   For e.entity_raw = Each entity_raw
      If e\txt="{" Then
         brackets=brackets+1
         entity_count=entity_count+1
      ElseIf e\txt="}" Then
         brackets=brackets-1
      Else
         If brackets=1 Then
            cnt=0
            ;keyvalue parser
            For i=1 To Len(e\txt)
               temp=Mid(e\txt,i,1)
               If temp=Chr(34) Then
               Select cnt
                  Case 0
                  nr1=i
                  Case 1
                  nr2=i
                  Case 2
                  nr3=i
                  Case 3
                  nr4=i
               End Select
               cnt=cnt+1
               EndIf
            Next
            key=Mid(e\txt,nr1+1,nr2-nr1-1)
            value=Mid(e\txt,nr3+1,nr4-nr3-1)
            If key="origin" Or key="rendercolor" Then
            cnt=0
               For i2=1 To Len(value)
                  temp=Mid(value,i2,1)
                  If temp=" " Then
                     Select cnt
                        Case 0
                        nr1=i2
                        Case 1
                        nr2=i2
                        Case 2
                        nr3=i2
                     End Select
                     cnt=cnt+1
                  EndIf
               Next
               v1=Mid(value,1,nr1-1)
               v2=Mid(value,nr1+1,nr2-nr1-1)
               v3=Mid(value,nr2+1,Len(value)-nr2)
               For i2=1 To 3
                  e2.entity_keyvalue = New entity_keyvalue
                  e2\id=entity_count
                  e2\key=key+"_"+i2
                  Select i2
                     Case 1
                        e2\value=v1
                     Case 2
                        e2\value=v2
                     Case 3
                        e2\value=v3
                  End Select
               Next
            Goto entity_parse_label1
            EndIf
            e2.entity_keyvalue = New entity_keyvalue
            e2\id=entity_count
            e2\key=key
            e2\value=value
         EndIf
      EndIf
      .entity_parse_label1
   Next
   Delete Each entity_raw
End Function




Function debug(txt$)
   WriteLine(logfile,txt)
End Function





;