;Initialisiere Graphik im Fenstermodus
Graphics3D 640,480, 32, 2

;Erstelle (leere) Textur mit 64 x 64 Pixel - Alternative zum Laden einer Bilddatei
Global texture = CreateTexture(64, 64)

;Male ein Checker-Muster in die Textur
SetBuffer TextureBuffer(texture)
Rect 0, 0, 32, 32, 1
Rect 32, 32, 32, 32, 1
SetBuffer BackBuffer()

;Obligatorische Kamera
Global camera = CreateCamera()

;Obligatorisches Licht
Global light = CreateLight()

;Erstellt ein Mesh, welches die Vertexe usw. "beinhaltet"
Global mesh = CreateMesh()
PositionEntity mesh, 0, 0, 25   ;Mesh etwas von der Kamera weg positionieren, um die komplette Szene zu sehen
EntityTexture mesh, texture      ;Die geladene Textur dem Mesh zuweisen

;Erstellt eine Oberfläche für das Mesh, da das Mesh eigentlich nur ein Gerüst ohne Flächen ist
Global surface = CreateSurface(mesh)

;Variablen für Vertexe
Global v1, v2, v3, v4

;Erstelle Viereck 1
;==================
;4 Vertexe (=Eckpunkte) für ein "Quad" werden erstellt
;Hinweis: Ein UV-Koordinatensystem beginnt links oben mit jeweils 0 und endet rechts unten mit jeweils 1
;; U entspricht der horizontalen Achse (X) und V entspricht der vertikalen Achse (Y) im 3D-Koordinatensystem
;; Die UV-Koordinaten verstehen sich relativ zu den Pixeln der Bilddatei.
;Beispiel: Die UV-Koordinaten der Mitte des Bildes sind U = 0.5 und V = 0.5
v1 = AddVertex(surface, -8, -8, 0, 0, 1)   ;Die letzten beiden Parameter sind die U- und die V-Koordinate
v2 = AddVertex(surface, -8, 0, 0, 0, 0)
v3 = AddVertex(surface, 0, 0, 0, 1, 0)
v4 = AddVertex(surface, 0, -8, 0, 1, 1)
AddTriangle(surface, v1, v2, v3)   ;Drei Eckpunkte ergeben ein Dreieck
AddTriangle(surface, v1, v3, v4)   ;Ein weiteres Dreieck ergibt ein Viereck

;Erstelle Viereck 2
;==================
v1 = AddVertex(surface, 0, 0, 0, 0, 2)   ;Die UV-Map wird hier n-mal so groß
v2 = AddVertex(surface, 0, 16, 0, 0, 0)   ;mit n = Aktuelle Fläche / Fläche der 1:1 Aulösung
v3 = AddVertex(surface, 16, 16, 0, 2, 0)
v4 = AddVertex(surface, 16, 0, 0, 2, 2)
AddTriangle(surface, v1, v2, v3)
AddTriangle(surface, v1, v3, v4)

;FAZIT:
;======
;=> Das erste Viereck soll hier die "Normalauflösung" darstellen, das zweite Viereck ist doppelt so groß,
;; die Textur muss beim zweiten Viereck also gekachelt werden um nicht verzerrt zu sein.
;=> Die UV-Map des zweiten Vierecks muss also - relativ - doppelt so groß sein wie die Textur
;=> Die Textur wird auf der Fläche 2^2 = 4 mal gekachelt.

;Obligatorisches Aktualisieren der Normalen
UpdateNormals(mesh)

;Hintergrundfarbe für etwas besseren Kontrast
CameraClsColor camera, 50, 50, 150

;Szene rendern
RenderWorld
   
Text 10, 10, "Viereck 1:  8² - Textur 1:1"
Text 10, 30, "Viereck 2: 16² - Textur gekachelt"
Text 10, 450, "Beliebige Taste drücken um zu beenden."

WaitKey()

;Speicher der Textur wieder frei geben
FreeTexture texture

End