Graphics 1024,768,0,2
SetBuffer BackBuffer()

Const STATE_MENU = 0
Const STATE_PLAY = 1

.scancodes1
Data "ESC",1,2,3,4,5,6,7,8,9,0,"?","`","Backspace"
Data "Tab","q","w","e","r","t","z","u","i","o","p","ü","+","Return"
Data "Strg Left","a","s","d","f","g","h","j","k","l","ö","ä","^","Shift Left","#"
Data "y","x","c","v","b","n","m",",",".","-","Shift Right","*"
Data "Alt Left","Space","Capslock","F1","F2","F3","F4","F5","F6","F7","F8","F9","F10"
Data "NumLock","Roll","7 (NumBlock)","8 (NumBlock)","9 (NumBlock)","# (NumBlock)","4 (NumBlock)"
Data "5 (NumBlock)","6 (NumBlock)","+ (NumBlock)","1 (NumBlock)","2 (NumBlock)","3 (NumBlock)","0 (NumBlock)",", (NumBlock)","<"
Restore scancodes1
Dim scancodes$(212)
For i=1 To 83
   Read scancodes$(i)
Next

.scancodes2
Data 86,"<"
Data 87,"F11"
Data 88,"F12"
Data 153,"Next Track (Media)"
Data 156,"Return (NumBlock)"
Data 157,"Ctrl Right"
Data 160,"Mute (Media)"
Data 162,"Play/Pause (Media)"
Data 164,"Stop (Media)"
Data 174,"Volume - (Media)"
Data 176,"Volume + (Media)"
Data 178,"Home (Internet)"
Data 181,"/ (NumBlock)"
Data 183,"Print"
Data 184,"Alt Right"
Data 197,"Pause"
Data 199,"Pos1"
Data 200,"Cursor Up"
Data 201,"PgUp"
Data 203,"Cursor Left"
Data 205,"Cursor Right"
Data 207,"End"
Data 208,"Cursor Down"
Data 209,"PgDown"
Data 210,"Insert"
Data 211,"Del"
Restore scancodes2
Local index = 0
For i=1 To 26
   Read index
   Read scancodes$(index)
Next

Global timer = CreateTimer(50)

Global last_key = False

Global control_key1 = 203
Global control_key2 = 205
Global control_key1_txt$ = scancodes$(control_key1)
Global control_key2_txt$ = scancodes$(control_key2)
Global control_key1_hit, control_key2_hit
Global control_mx, control_my, control_mhit

Global program_state = STATE_MENU
Global game_start_time = 0

Global game_progress# = 0
Global game_difficulty# = 0.1
Global game_won_time = 0
Global game_pressed_keys = 0

Repeat
   updateControls()
   
   If program_state = STATE_MENU Then
      
      If Button(10,10,"Start game",200) Then
         program_state = STATE_PLAY
         game_start_time = MilliSecs()
         game_progress = 0
         game_won_time = 0
         game_pressed_keys = 0
         Delay 1
      EndIf
      
      If Button(10,40,"Set up keys",200) Then
         control_key1 = getControlKey("Hit the first key on your keyboard")
         control_key2 = getControlKey("Hit the second key on your keyboard")
         control_key1_txt$ = scancodes$(control_key1)
         control_key2_txt$ = scancodes$(control_key2)
      EndIf
      Text 240,40,"Currently: ["+control_key1_txt$+"] and ["+control_key2_txt$+"]"
      
      If Button(10,70,"-",20) Then
         game_difficulty# = game_difficulty# - 0.02
         If game_difficulty# < 0.005 Then game_difficulty# = 0
      EndIf
      Text 40,70,"Difficulty: "+((game_difficulty#) * 500) + "%"
      If Button(190,70,"+",20) Then
         game_difficulty# = game_difficulty# + 0.02
         If game_difficulty# > 0.2 Then game_difficulty# = 0.2
      EndIf
      
      If Button(10,100,"Quit game",200) Then
         Exit
      EndIf
      
   ElseIf program_state = STATE_PLAY Then
      
      If control_key1_hit Then
         game_pressed_keys = game_pressed_keys + 1
         If last_key Then
            last_key = False
            game_progress# = game_progress + 1
         EndIf
      EndIf
      If control_key2_hit Then
         game_pressed_keys = game_pressed_keys + 1
         If Not last_key Then
            last_key = True
            game_progress# = game_progress + 1
         EndIf
      EndIf
      
      If game_progress >= 100 Then
         If game_won_time = 0 Then
            game_won_time = MilliSecs()
         EndIf
         Text 10,70,"You mastered this game in "+((game_won_time - game_start_time) / 1000.0)+"sec!"
      Else
         game_progress = game_progress - game_difficulty#
         If game_progress < 0 Then game_progress = 0
      EndIf
      
      Text 10,10,"Hit the Keys ["+control_key1_txt$+"] and ["+control_key2_txt$+"] alternating"
      Text 10,30,(MilliSecs() - game_start_time) / 1000.0
      Text 10,50,Int(game_progress)+" / 100 Points"
      Text 10,90,"APM: "+Int(game_pressed_keys / ( (MilliSecs() - game_start_time) / 60000.0))
      
      If KeyHit(1) Then
         program_state = STATE_MENU
      EndIf
   EndIf
   
   
   Flip 0:Cls
   WaitTimer timer
Forever

End

Function Button(x,y,txt$="",w=150,h=20)
   Color 180,180,180
   Rect x,y,w,h,0
   Color 255,255,255
   If control_mx > x And control_mx < x + w And control_my > y And control_my < y + h Then
      Rect x,y,w,h,0
      If control_mhit Then
         Return True
      EndIf
   EndIf
   Text x + w/2, y + h/2, txt$, 1, 1
   Return False
End Function

Function updateControls()
   control_mx = MouseX()
   control_my = MouseY()
   control_mhit = MouseHit(1)
   control_key1_hit = KeyHit(control_key1)
   control_key2_hit = KeyHit(control_key2)
End Function

Function getControlKey(prompt$)
   Cls
   Text 10,10,prompt$
   Flip 0
   FlushKeys()
   Repeat
      For i=2 To 212
         If KeyHit(i) Then
            Return i
         EndIf
      Next
      Delay 10
   Forever
   FlushMouse()
End Function