; ------------------------------------------
;            StereoCamera-Lib.bb
; ------------------------------------------
;             by AMULWARE (2007)
; ------------------------------------------


; der Type in dem alle Kameras gespeichert werden
Type TStereoCamera
   Field CamPivot ; ein Pivot, der genau zwischen den Augen sitzt und als Parent dient
   Field Cam_R    ; das rechte Auge
   Field Cam_L    ; das linke Auge
End Type


Function CreateStereoCamera(Parent = 0, EyeDist# = 1, Focus# = 50)
   ; Mit dieser Funktion wird eine neue Stereo-Kamera erstellt.
   ; Ein Parent kann über den gleichnamigen Parameter angegeben werden.
   ; Mit dem Parameter 'EyeDist' kann der Abstand zwischen den Augen angegeben werden.
   ; Mit 'Focus' kann die Entfernung angegeben werden, bei der der Schnittpunkt
   ; von den Kamera in Kamerarichtung ausgesannter Geraden liegen soll.
   
   SC.TStereoCamera = New TStereoCamera ; Typeeintrag erstellen
   
   SC\CamPivot = CreatePivot(Parent) ; Pivot(Punkt zwischen den Augen) erstellen
   
   D# = EyeDist# / 2
   Width = GraphicsWidth() / 2
   Height = GraphicsHeight()
   
   SC\Cam_R = CreateCamera(SC\CamPivot) ; rechtes Auge
   PositionEntity SC\Cam_R, D#, 0, 0
   CameraViewport SC\Cam_R, Width, 0, Width, Height
   
   SC\Cam_L = CreateCamera(SC\CamPivot) ; linkes Auge
   PositionEntity SC\Cam_L, -D#, 0, 0
   CameraViewport SC\Cam_L, 0, 0, Width, Height
   
   FocusPivot = CreatePivot(SC\CamPivot)
   PositionEntity FocusPivot, 0, 0, Focus
   PointEntity SC\Cam_R, FocusPivot
   PointEntity SC\Cam_L, FocusPivot
   FreeEntity FocusPivot
   
   Return SC\CamPivot ; Handle vom Pivot wird zurückgegeben.
End Function           ; Dieser kann so über dir Entitybefehle ganz normal Positioniert,gedreht und skaliert werden.

Function StereoCameraEyeDistance(Id, EyeDist#)
   ; Mit dieser Funktion kann der Abstand zwischen den Augen verändert werden.
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      D# = EyeDist# / 2
      PositionEntity SC\Cam_R, D#, 0, 0
      PositionEntity SC\Cam_L, -D#, 0, 0
   EndIf
End Function

Function StereoCameraFocus(Id, Focus#)
   ; Mit dieser Funktion kann der Fokus der Kameras verändert werden
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      FocusPivot = CreatePivot(SC\CamPivot)
      PositionEntity FocusPivot, 0, 0, Focus
      PointEntity SC\Cam_R, FocusPivot
      PointEntity SC\Cam_L, FocusPivot
      FreeEntity FocusPivot
   EndIf
End Function


; Die folgenden Funktionen machen genau das gleiche wie die original BB-Funktionen.
; Bei Fragen also einfach in der BB-Hilfe/OH nachschauen ;)

Function StereoCameraViewport(Id, X, Y, Width, Height)
   ; s. CameraViewport
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      Width = Width / 2
      CameraViewport SC\Cam_R, X + Width, Y, Width, Height
      CameraViewport SC\Cam_R, X, Y, Width, Height
   EndIf
End Function

Function StereoCameraClsMode(Id, Cls_Color, Cls_ZBuffer)
   ; s. CameraClsMode
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraClsMode SC\Cam_R, Cls_Color, Cls_ZBuffer
      CameraClsMode SC\Cam_L, Cls_Color, Cls_ZBuffer
   EndIf
End Function

Function StereoCameraClsColor(Id, Red, Green, Blue)
   ; s. CameraClsColor
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraClsColor SC\Cam_R, Red, Green, Blue
      CameraClsColor SC\Cam_L, Red, Green, Blue
   EndIf
End Function

Function StereoCameraRange(Id, Near#, Far#)
   ; s. CameraRange
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraRange SC\Cam_R, Near, Far
      CameraRange SC\Cam_L, Near, Far
   EndIf
End Function

Function StereoCameraFogMode(Id, Mode)
   ; s. CameraFogMode
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraFogMode SC\Cam_R, Mode
      CameraFogMode SC\Cam_L, Mode
   EndIf
End Function

Function StereoCameraFogRange(Id, Near#, Far#)
   ; s. CameraFogRange
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraFogRange SC\Cam_R, Near#, Far#
      CameraFogRange SC\Cam_L, Near#, Far#
   EndIf
End Function

Function StereoCameraFogColor(Id, Red, Green, Blue)
   ; s. CameraFogColor
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraFogColor SC\Cam_R, Red, Green, Blue
      CameraFogColor SC\Cam_L, Red, Green, Blue
   EndIf
End Function

Function StereoCameraZoom(Id, Zoom#)
   ; s. CameraZoom
   SC.TStereoCamera = StereoCameraFindType(Id)
   If SC <> Null
      CameraZoom SC\Cam_R, Zoom#
      CameraZoom SC\Cam_L, Zoom#
   EndIf
End Function

Function StereoCameraFindType.TStereoCamera(Id)
   ; Diese Funktion sucht den Typeeintrag zum Handle des Pivots und gibt ihn zurück
   For SC.TStereoCamera = Each TStereoCamera
      If SC\CamPivot = Id
         Return SC
      EndIf
   Next
   Return Null
End Function

Include "StereoCamera-Lib.bb"

Graphics3D 800, 600, 0, 2
SeedRnd MilliSecs()

Ego = CreateStereoCamera(0,0.5)      ; Erstellen der Kameras
StereoCameraClsColor Ego, 45, 45, 45 ; Hintergrundfarbe festlegen
StereoCameraFogColor Ego, 45, 45, 45 ; Nebelfarbe festlegen
StereoCameraFogMode Ego, 1           ; Nebel anschalten
StereoCameraFogRange Ego, 150, 250   ; Nebelentferung festlegen

For i = 0 To 99
   ; Erstellen von 100 Kegeln (sonst sieht man NIX)
   Mesh = CreateCone()      
   PositionEntity Mesh, Rnd(-150, 150), Rnd(-150, 150), Rnd(-150, 150)
   Size# = Rnd(2,10)
   ScaleEntity Mesh, Size, Size, Size
   RotateEntity Mesh, Rnd(360), Rnd(360), Rnd(360)
Next

For i = 0 To 3
   ; Erstellen von vier Lichtern (sieht besser aus als mit ohne Lichter)
   Light = CreateLight(2)
   PositionEntity Light, Rnd(-150, 150), Rnd(-150, 150), Rnd(-150, 150)
   LightColor Light, Rand(200), Rand(200), Rand(200)
   LightRange Light, 100
Next

AmbientLight 50,50,50

MoveMouse GraphicsWidth()/2, GraphicsHeight()/2
FlushMouse
HidePointer

SetBuffer BackBuffer()

Repeat
   ; Hauptschleife
   Ms = MilliSecs()
   Pitch_S# = Pitch_S# + MouseYSpeed() * 0.02 ; Drehung(mit Maus)
   Yaw_S# = Yaw_S# - MouseXSpeed() * 0.02
   MoveMouse GraphicsWidth()/2, GraphicsHeight()/2
   Pitch_S# = Pitch_S# * 0.95
   Yaw_S# = Yaw_S# * 0.95
   TurnEntity Ego, Pitch_S#, Yaw_S#, 0
   
   Speed# = Speed# + (MouseDown(1) - MouseDown(2)) * 0.05 ; Bewegung(mit den Maustasten)
   Speed# = Speed# * 0.99
   MoveEntity Ego, 0, 0, Speed#
   
   RenderWorld ; Rendern
   Flip 0
   Delay 16-MilliSecs()+Ms
Until KeyHit(1)