Graphics 800,600,32,2
SetBuffer(BackBuffer())

Global int_x#,int_y#
Global mx1# = 400
Global my1# = 300

Type colli
   Field x1#,y1#
   Field x2#,y2#
End Type

createLine(0,300,300,450)
createLine(300,450,600,400)
createLine(600,400,800,300)

timer = CreateTimer(25)
While Not KeyHit(1)
   WaitTimer(timer)
   Cls
   
   mx2# = MouseX()
   my2# = MouseY()
   
   Color(255,255,255)
   Line(mx1,my1,mx2,my2)

   For l.colli = Each colli
      Color(255,255,255)
      
      Line(l\x1,l\y1,l\x2,l\y2)
      ;--
            
      If LinesCross(l\x1#,l\y1#, l\x2#,l\y2#, 400,300, MouseX(),MouseY())
         
         ;delta Kollisionslinie errechnen
         dx# = l\x1 - l\x2
         dy# = l\y1 - l\y2
         
         ;die Magnitude(Vektorlänge)
         mag# = Sqr(dx^2 + dy^2)
         
         ;Vektor Normale (aufrecht auf der Colli-linie)
         nx# = dy / mag
         ny# = -dx / mag
         
         ; zeichnen der Normale
         Color(20,255,20)
         Line(int_x,int_y,int_x+nx*30,int_y+ny*30)
         ;--
         ;nun das ganze für den eintritts-vektor
         mdx# = int_x - mx1
         mdy# = int_y - my1
         
         mmag# = Sqr(mdx^2 + mdy^2)
         
         mnx# = mdx / mmag
         mny# = mdy / mmag
         
         ;--
         ;das Punktprodukt von eintritts-vektor und Liniennormale
         vdotN# = mdx * nx + mdy * ny
         
         ; hier wird die Reflektion errechnet
         NFx# = -2.0 * Nx# * VdotN#
         NFy# = -2.0 * Ny# * VdotN#
         Vx# = mdx# + NFx#
         Vy# = mdy# + NFy#
   
         ;neuen Vektor zeichnen
         Color(20,20,255)
         Line(int_x,int_y,int_x+vx,int_y+vy)
         
         ;hier nochmal den Kollisionspunkt zeichnen
         Color(255,20,20)
         Line(l\x1,l\y1,l\x2,l\y2)
         Oval(int_x-2,int_y-2,5,5)
      End If
   Next
      
   Flip()
Wend
End

Function createLine(x1#,y1#,x2#,y2)
   l.colli = New colli
   l\x1 = x1
   l\y1 = y1
   l\x2 = x2
   l\y2 = y2
End Function

Function LinesCross(x0#,y0#, x1#,y1#, x2#,y2#, x3#,y3# )   
   n# = (y0#-y2#)*(x3#-x2#) - (x0#-x2#)*(y3#-y2#)
   d# = (x1#-x0#)*(y3#-y2#) - (y1#-y0#)*(x3#-x2#)
   
   If Abs(d#) < 0.0001
      ; Lines are parallel!
      Return False
   Else
      ; Lines might cross!
      Sn# = (y0#-y2#)*(x1#-x0#) - (x0#-x2#)*(y1#-y0#)

      AB# = n# / d#
      If AB#>0.0 And AB#<1.0
         CD# = Sn# / d#
         If CD#>0.0 And CD#<1.0
            ; Intersection Point
            int_X# = x0# + AB#*(x1#-x0#)
            int_Y# = y0# + AB#*(y1#-y0#)
            Return True
         End If
      End If
   
      ; Lines didn't cross, because the intersection was beyond the end points of the lines
   EndIf

   ; Lines do not cross!
   Return False

End Function