'Snake Steuerung by Suco-X
'Viel Spass.


'Prinzip meiner Snake Steuerung
Rem

Das Prinzip ist einfacher als man denkt. Es gibt 3 Types.
TSnake, TSnakeHead und TSnakeBody.
In TSnake sind die Grunddaten drin die jeweils von TSnakeHead und TSnakeBody geerbt werden.
Jeder erstellt Snake Kopf bekommt seine Bodys zu beginn zugeteilt. Jeder dieser Bodys
hat einen Parent. Der Erste hat den SnakeKopf als Parent und die restlichen jeweils einen Body.
Die Steuerung des Snake Kopfes erfolgt ber Sin/Cos (normale 08/15 Steuerung).
Jeder Snake Body findet den Winkel von Sich selbst zu seinem Parent raus und setzt ihn so
Wenn der Radius zwischen einem Body und seinem parent zu Gro(>Objekt Radius) wird, bekommt die Speed Variable
einen Wert zugewiesen. So setzt sich angefangen vom Kopf bis zum Schwanz diese Realistisch wirkende
Schlange zusammen. Der Code kanns dir besser erklren.
Mfg Suco
end rem


Strict

Framework brl.basic



Import BRL.pngloader
Import BRL.glmax2d



Type TSnake

   Field x:Float, y:Float
   Field Radius:Float
   Field speed:Float
   Field Angle:Float
   Field Image:TIMage

   Method GetSpeed:Float()
      Return self.Speed
   End Method
   
   
   Method AddAngle(Value:Float)
      self.Angle:+Value
   End Method
   
   
   Method SetPosition(x:Float, y:Float)
      self.x = x
      self.y = y
   End Method
   
   Method GetX:Float()
      Return self.X
   End Method
   
   
   Method GetY:Float()
      Return self.Y
   End Method
   
   
   Method Set(Image:TIMage, Speed:Float, Radius:Float )
      self.Image = Image
      self.Speed = Speed
      self.Radius = Radius
   End Method
   
   
   Method SetImage(Image:TImage)
      self.Image = image
   End Method
   
   
   Method GetImage:TImage()
      Return self.Image
   End Method
   
   
End Type





TSnakeHead.hHeadList = New TList

Type TSnakeHead Extends TSnake

   Global hHeadList:TList
   
   
   Field hBodyList:TList
   Field hMaxBodys:Int = 10
   
   
   Method New()
      self.hHeadList.AddLast(Self)
   End Method


   Function GetInstance:TSnakeHead()
      Return New TSnakeHead
   End Function
   
   
   Function RenderAndUpdate()
      For Local TempObject:TSnakeHead = EachIn self.hHeadList
         TempObject.Update()
         TempObject.Render()
      Next
   End Function
   
   
   Method RenderAndUpdateBodys()
      For Local TempObject:TSnakeBody = EachIn self.hBodyList
         TempObject.Update()
         TempObject.Render()
      Next
   End Method
   
   
   Method SetData(x:Float, y:Float, Image:TImage, Speed:Float)
      self.SetPosition(x,y)
      self.Set(Image,Speed,Image.Width)
      self.CreateBodys()
   End Method
   
   
   Method AddBody()
      Local FirstBody:TSnakeBody
      
      FirstBody = TSnakeBody(self.hBodyList.Last())
      
      If FirstBody = Null
         Return
      EndIf
      
      Local NewBody:TSnakeBody = TSnakeBody.GetInstance()
      NewBody.hParent = FirstBody
      NewBody.SetData(FirstBody.GetX(),FirstBody.GetY(),FirstBody.image,FirstBody.speed)
      NewBody.IsLast = True
      FirstBody.IsLast = False
      self.hBodyList.AddLast(NewBody)
      
      self.hMaxBodys:+1
      
   End Method
   
   
   
   Method CreateBodys()
      self.hBodyList = Null
      self.hBodyList = New TList
      
      Local LastBody:TSnakeBody = Null
      Local TempBody:TSnakeBody = Null
      For Local i:Int = 0 Until self.hMaxBodys
      
         TempBody = TSnakeBody.GetInstance()
         TempBody.SetData(self.GetX(),self.GetY(),snakebody_img,0.0)
         
         If i = 0
            TempBody.hParent = Self
         Else
            TempBody.hParent = LastBody
         EndIf
         
   
         LastBody = TempBody
         
         self.hBodyList.AddLast(TempBody)
      Next
      TempBody.IsLast = True
      
      
   End Method
   
   
   Method Update()
      self.x:+Sin(self.Angle)*self.Speed
      self.y:-Cos(self.Angle)*self.Speed
      
      self.RenderAndUpdateBodys()
      
   End Method
   
   
   
   Method Render()
   
      ResetStates()
      SetBlend ALPHABLEND
      SetScale 1.4,1.4
      SetRotation self.Angle
      
      SetColor 30,30,30
      SetAlpha 0.6
      DrawImage self.Image,self.GetX()+10,self.GetY()
      
      SetColor 255,255,255
      SetAlpha 1.0
      DrawImage self.Image,self.GetX(),self.GetY()

   End Method
   

End Type




Type TSnakeBody Extends TSnake
   
   Field hParent:TSnake = Null
   Field OldSpeed:Float
   Field IsLast:Byte = False
   
   Function GetInstance:TSnakeBody()
      Return New TSnakeBody
   End Function
   
   
   Method SetData(x:Float, y:Float, Image:TImage, Speed:Float)
      self.SetPosition(x,y)
      self.Set(Image,Speed,Image.Width)
   End Method
   

   Method Update()
      
      If self.hParent
         Local TempAngle:Float = WInkel2D(self.GetX(),self.GetY(),self.hParent.GetX(),self.hParent.GetY())
         Local TempDistance:Float = Distance2D(self.GetX(),self.GetY(),self.hParent.GetX(),self.hParent.GetY())
         self.Speed = (TempDistance>self.Radius)*self.hParent.Speed
         self.Angle = TempAngle
      EndIf

      self.x:+Sin(self.Angle)*self.Speed
      self.y:-Cos(self.Angle)*self.Speed
            
   End Method
   
   
   Method Render()
      
      ResetStates()
      
      SetBlend ALPHABLEND
      SetRotation self.Angle
      
      SetColor 30,30,30
      SetAlpha 0.7
      DrawImage self.Image,self.GetX()+5,self.GetY()
      
      SetAlpha 1.0
      SetColor 255,255,255
      DrawImage self.Image,self.GetX(),self.GetY()
         
   End Method
   
End Type







Graphics 1024,768,32,60

AutoMidHandle True

Global snakehead_img = CreateImage(32,32)
Global snakebody_img = CreateImage(32,32)
Global tile_img      = CreateImage(32,32)



SetColor 0,255,0
DrawOval 0,0,32,32
SetColor 0,0,255
DrawOval 10,10,4,4
DrawOval 20,10,4,4

GrabImage(snakehead_img,0,0)




SetColor 0,150,0
DrawOval 0,0,32,32
GrabImage(snakebody_img,0,0)



SetColor 100,60,100
DrawRect 0,0,32,32
glPolygonMode(GL_BACK, GL_LINE)
SetColor 200,100,100
DrawRect 0,0,32,32
glPolygonMode(GL_BACK, GL_FILL)
GrabImage(tile_img,0,0)




Local Snake1:TSnakeHead = TSNakeHead.GetInstance()
Snake1.SetData(GraphicsWidth()/2,GraphicsHeight()/2,snakehead_img,2.5)




Repeat
Cls

   DrawText "PRESS RETURN TO START",GraphicsWidth()/2,GraphicsHeight()/2
   
   If KeyHit(KEY_RETURN)
      Exit
   EndIf
   

Flip
FlushMem()
Forever


Repeat
Cls


If KeyDown(KEY_LEFT)
   Snake1.AddAngle(-(Snake1.GetSpeed()*1.0))
ElseIf KeyDown(KEY_RIGHT)
   Snake1.AddAngle((Snake1.GetSpeed()*1.0))
EndIf







If Rand(0,200) = 1
   Snake1.AddBody()
EndIf





ResetStates()
TileImage tile_img,0,0

TSnakeHead.RenderAndUpdate()

Flip
FlushMem()
Until KeyHit(KEY_ESCAPE)

Function ResetStates()
   SetColor 255,255,255
   SetRotation 0.0
   SetScale 1.0,1.0
   SetAlpha 1.0
   SetBlend MASKBLEND
End Function

Function Distance2D:Float(x1:Float,y1:Float,x2:Float,y2:Float)
   Local Result:Float = 0.0
   result = Sqr(((x1-x2)*(x1-x2))+((y1-y2)*(y1-y2)))
   Return result
End Function       

Function Winkel2D(x1:Float,y1:Float,x2:Float,y2:Float)
   Return Float(ATan2(y1-y2,x1-x2)+270) Mod 360
End Function