Strict

Module pub.GameManager

ModuleInfo "Name:"
ModuleInfo "Version:"
ModuleInfo "Author:"

Import brl.system
Import brl.glmax2d


'Basisklasse für Gamestates
Type TGameState Abstract

   'Starten des Gamestates (laden etc.)
   Method Enter()
   End Method
   
   'Hauptschleife des Gamestates
   Method Process()
   End Method
   
   'Beenden des Gamestates (resourcen freigeben etc.)
   Method Leave()
   End Method
   
   'Zeichnen des Gamestates (kann in Process() aufgerufen werden)
   Method Draw()
   End Method

End Type



'Standard-Gamestate, wird beim Starten des Gamemanagers als Hinweis verwendet dass noch keine eigenen Gamestates erstellt wurden.
Type TMainGameState Extends TGameState Final

   Field _lines:TList

   Method Enter()
      _lines = New TList
      _lines.AddLast("Noch keine States erstellt / No states created")
      _lines.AddLast("Druecke ESC zum Beenden / Press ESC Key to quit")
      _lines.AddLast("")
      _lines.AddLast("Beispiel eines Gamestates / Example of a gamestate")
      _lines.AddLast("")
      _lines.AddLast("")
      _lines.AddLast("Type TMyGameState extends TGameState")
      _lines.AddLast("  Method Enter()")
      _lines.AddLast("    'Entering Gamestate")
      _lines.AddLast("  End Method")
      _lines.AddLast("")
      _lines.AddLast("  Method Process()")
      _lines.AddLast("    'Mainloop of this Gamestate")
      _lines.AddLast("    If KeyHit(KEY_ESCAPE) then GameManager.SetGameState(Null)")
      _lines.AddLast("    Draw()")
      _lines.AddLast("  End Method")
      _lines.AddLast("")
      _lines.AddLast("  Method Leave()")
      _lines.AddLast("    'End of Gamestate")
      _lines.AddLast("  End Method")
      _lines.AddLast("")
      _lines.AddLast("  Method Draw()")
      _lines.AddLast("    'Draw")
      _lines.AddLast("  End Method")
      _lines.AddLast("End Type")
      _lines.AddLast("")
      _lines.AddLast("")
      _lines.AddLast("Local MyState:TMyGameState = new TMyGameState")
      _lines.AddLast("")
      _lines.AddLast("GameManager.Run(MyState)")
   End Method
   
   Method Process()
      If KeyHit(KEY_ESCAPE) Then
         GameManager.SetGameState(Null)
         Return
      EndIf
   
      Draw()
   End Method
   
   Method Leave()
      _lines.Clear()
      _lines = Null
   End Method
   
   Method Draw()
      Local count = 0
      
      For Local line:String = EachIn _lines
         DrawText line, 10, count * 20 + 10
         count :+ 1
      Next
   End Method
   
End Type



'FPS Manager - für frameunabhängiges Programmieren
Type TFPSManager

   Field _fps
   Field _fps_counter
   Field _fps_timer
   Field _fps_value:Float
   Field _fps_begin
   
   Method New()
      _fps_begin = MilliSecs()
   End Method
   
   'Aktualisiert die FPS Daten
   Method Update()
      Local ms = MilliSecs()
   
      _fps_value = (ms - _fps_begin) / 1000.0
      _fps_begin = ms

      If ms >= _fps_timer
         _fps = _fps_counter * 5
         _fps_counter = 0
         _fps_timer = ms + 200 '1/5 einer Sekunde
      Else
         _fps_counter :+ 1
      EndIf
   End Method
   
   'Gibt die aktuellen FPS zurück
   Method FPS()
      Return _fps
   End Method
   
   'Multipliziert den FPS Faktor mit einer Geschwindigkeit in pixel/sek. und gibt das Ergebnis zurück.
   Method FPS_Val:Float(value:Float)
      Return _fps_value * value
   End Method

End Type


'Gamemanager
Type TGameManager

   Field _state:TGameState               'aktueller Gamestate der ausgeführt wird.
   Field _quit:Byte                        'gibt an ob das Spiel beendet ist.
   Field _fps:TFPSManager               'frameunabhängiges Programmieren und FPS
   

   'Start des Spiels mit übergabe einer GameState Instanz, wenn keine vorhanden wird TMainGameState als Hinweis benutzt.
   Method Run(State:TGameState = Null)
      If State = Null
         _state = New TMainGameState
      Else
         _state = State
      EndIf
      
      _state.Enter()
      _quit = False
      _fps = New TFPSManager         
      
      'Hauptschleife des Spiels   
      While Not _quit
         _fps.Update()
         Cls
            Update()
         Flip
         FlushMem
      Wend
      
      Terminate()
   End Method


   'Führt den aktuellen GameState aus, wenn keiner vorhanden wird _quit auf True gesetzt.   
   Method Update()
      If _state
         _state.Process()
      Else
         _quit = True
      EndIf
   End Method
   
   
   'Gibt vom aktuellen Gamestate verwendete Resourcen frei und setzt den Gamestate auf Null.
   Method Terminate()
      If _state
         _state.Leave()
         _state = Null
      EndIf
   End Method
   
   
   'Ändert den Gamestate. Auch Null möglich (wodurch das Spiel beendet wird).
   Method SetGameState(NewState:TGameState)
      
      If _state
         _state.Leave()
      EndIf
      
      _state = NewState

      If _state
         _state.Enter()
      EndIf

   End Method
   
   
   'Gibt die aktuellen FPS zurück
   Method FPS()
      Return _fps.FPS()
   End Method
   
   
   'Multipliziert den FPS Faktor mit einem Wert, wird für die frameunabhängige Programmierung benötigt.
   Method FPS_Val:Float(value:Float)
      Return _fps.FPS_Val(value)
   End Method
   
End Type

'Globale Instanz vom GameManager
Global GameManager:TGameManager = New TGameManager

Strict

Type TMyState Extends TGameState

   Field x:Float, y:Float

   Method Enter()
      x = 10.0
      y = 200.0
   End Method
   
   Method Process()
      If KeyHit(KEY_ESCAPE) Then
         GameManager.SetGameState(Null)
         Return
      EndIf
      
      If KeyHit(KEY_SPACE) Then
         GameManager.SetGameState(New TMyOtherState)
         Return
      EndIf
   
      x  :+ GameManager.FPS_Val(50.0)
   
      Draw()
   End Method
   
   Method Leave()
   End Method
   
   Method Draw()
      DrawText GameManager.FPS(), 10, 300
      DrawRect x, y, 10, 10
   End Method

End Type


Type TMyOtherState Extends TGameState

   Method Enter()
   End Method
   
   Method Process()
   
      If KeyHit(KEY_ESCAPE) Then
         GameManager.SetGameState(Null)
         Return
      EndIf
   
      If KeyHit(KEY_SPACE) Then
         GameManager.SetGameState(New TMyState)
         Return
      EndIf
      
      Draw()
   End Method
   
   Method Leave()
   End Method
   
   Method Draw()
      DrawText "Der andere Gamestate", 10, 10
   End Method
   
End Type


'**** HAUPTTEIL ****
Graphics 1024,768,32,-1

GameManager.Run(New TMyState)

EndGraphics
FlushMem
End