Strict

SetGraphicsDriver GLMax2DDriver()
Graphics 640,480,0
SetBlend ALPHABLEND


Rem
   ------------------------------------------------
   Kreis Shadowcaster
   ------------------------------------------------
EndRem
Type TCCircle
   Global _list:TList
   
  Field x:Int
   Field y:Int
   Field r:Int
   
   Method New()
      If _list:TList = Null Then _list:TList = New TList
      _list.AddLast(Self)
   End Method
   
   Method Add(x:Int, y:Int, r:Int)
      self.x = x
      self.y = y
      self.r = r
   End Method
   
   Method Kill()
      _list.Remove(Self)
   End Method
End Type
Global cast_circle:TCCircle


Rem
   ------------------------------------------------
   Polygon Shadowcaster
   ------------------------------------------------
EndRem
Type TCForm
   Global _list:TList
   
  Field x:Int
   Field y:Int
   Field r:Int
   Field c:Int
   Field a:Int
   
   Method New()
      If _list:TList = Null Then _list:TList = New TList
      _list.AddLast(Self)
   End Method
   
   Method Add(x:Int, y:Int, r:Int, c:Int, a:Int)
      self.x = x
      self.y = y
      self.r = r
      self.c = c
      self.a = a
   End Method
   
   Method Kill()
      _list.Remove(Self)
   End Method
End Type
Global cast_form:TCForm


Rem
   ------------------------------------------------
   ein paar Tatsachen in Stein meißeln
   ------------------------------------------------
EndRem
Global shadowlenght:Int   = 2000
Global playerx:Int            = 320
Global playery:Int          = 240


Rem
   einige Shadow-Caster erzeugen
EndRem
cast_circle:TCCircle = New TCCircle
cast_circle.Add(160,110,80)

cast_circle:TCCircle = New TCCircle
cast_circle.Add(470,380,50)

cast_form:TCForm = New TCForm
cast_form.Add(200,350,50,3,0)

cast_form:TCForm = New TCForm
cast_form.Add(400,200,50,6,0)


Rem
   ------------------------------------------------
   Mainloop
   ------------------------------------------------
EndRem
SetClsColor 128,128,128

While Not KeyHit(KEY_ESCAPE)
  Cls

  If KeyDown(KEY_LEFT) Then playerx=playerx-5
  If KeyDown(KEY_RIGHT) Then playerx=playerx+5
  If KeyDown(KEY_UP) Then playery=playery-5
  If KeyDown(KEY_DOWN) Then playery=playery+5

  draw_shadow()
  draw_obj()

  Flip
   FlushMem()
Wend
End


Function draw_shadow()
  Local p1x:Int
   Local p2x:Int
   Local p3x:Int
   Local p4x:Int
   Local p1y:Int
   Local p2y:Int
   Local p3y:Int
   Local p4y:Int
      
   SetColor 0,0,0

  For cast_circle:TCCircle=EachIn cast_circle._list
    Local dist:Float      = Sqr((cast_circle.x - playerx)^2 + (cast_circle.y - playery)^2)
    Local angle:Float   = ATan2(cast_circle.y - playery, cast_circle.x - playerx)
    Local distX:Float   = Sqr(dist^2 - cast_circle.r^2)
    Local angleX:Float   = ASin(Float(cast_circle.r) / dist)

    p1x = playerx + Cos(angle + angleX) * distX
    p1y = playery + Sin(angle + angleX) * distX
    p2x = playerx + Cos(angle - angleX) * distX
    p2y = playery + Sin(angle - angleX) * distX
    p3x = playerx + Cos(angle + angleX) * (distX + shadowlenght)
    p3y = playery + Sin(angle + angleX) * (distX + shadowlenght)
    p4x = playerx + Cos(angle - angleX) * (distX + shadowlenght)
    p4y = playery + Sin(angle - angleX) * (distX + shadowlenght)

    DrawLine p1x,p1y,p2x,p2y
    DrawLine p3x,p3y,p4x,p4y
    DrawLine p1x,p1y,p3x,p3y
    DrawLine p2x,p2y,p4x,p4y
'   DrawLine p1x,p1y,p4x,p4y <-triangle
  Next

  For cast_form:TCForm = EachIn cast_form._list
    Local angle:Float = (ATan2(cast_form.y - playery, cast_form.x - playerx) + 360) Mod 360
    Local _min:Float = 0.0
    Local _max:Float = 0.0

    Local a:Float = 360/cast_form.c

    For Local i:Int = 0 To cast_form.c-1
      Local px:Int = cast_form.x + Cos(i * a + cast_form.a) * cast_form.r
      Local py:Int = cast_form.y + Sin(i * a + cast_form.a) * cast_form.r

         Local angleX:Float = ((ATan2(py - playery, px - playerx) + 360) - angle + 720) Mod 360
      If angleX>180 Then angleX:-360
      If angleX<_min Then _min = angleX; p1x = px; p1y = py
      If angleX>_max Then _max = angleX; p2x = px; p2y = py
    Next
      
    p3x = p1x + Cos(angle + _min) * shadowlenght
    p3y = p1y + Sin(angle + _min) * shadowlenght
    p4x = p2x + Cos(angle + _max) * shadowlenght
    p4y = p2y + Sin(angle + _max) * shadowlenght
   
      DrawLine p1x,p1y,p2x,p2y
    DrawLine p3x,p3y,p4x,p4y
    DrawLine p1x,p1y,p3x,p3y
    DrawLine p2x,p2y,p4x,p4y
    'Line p1x,p1y,p4x,p4y <-triangle
  Next

   SetColor 255,255,255
End Function


Function draw_obj()
  SetColor 255,255,255
   Local ox:Int
   Local oy:Int
   
  For cast_circle:TCCircle = EachIn cast_circle._list
    DrawOval cast_circle.x - cast_circle.r, cast_circle.y - cast_circle.r, cast_circle.r*2, cast_circle.r*2
  Next

  For cast_form:TCForm = EachIn cast_form._list
    Local a:Float = 360/cast_form.c
    For Local i:Int = 0 To cast_form.c
      Local x:Int = cast_form.x + Cos(i * a + cast_form.a) * cast_form.r
      Local y:Int = cast_form.y + Sin(i * a + cast_form.a) * cast_form.r
      If i>0 Then DrawLine x,y,ox,oy
     
         ox=x
      oy=y
    Next
  Next

  SetColor 255,0,0
  DrawOval playerx-10,playery-10,20,20

   SetColor 255,255,255
End Function