'BlitzMax 1.20

'M.Rauch 07.05.2006
'berechnen der Azimut und Elevation Winkel vom Standort zu einem Geostationären Satelliten (TV)

'http://www.fen-net.de/satellitentechnik-online/texte/orbit/orbit.htm
'http://www.fen-net.de/satellitentechnik-online/texte/orbit/azimut.htm

Strict

Rechne()
End

Function Rechne()

 Local BreiteNord:Float
 Local LaengeOst:Float
 'BreiteNord = 51.413488 'für Mülheim Ruhr
 'LaengeOst = 6.860801 'für Mülheim Ruhr

 'D.D° deine Position auf der Erde
 BreiteNord = 51.413488 'in Grad !
 LaengeOst = 6.860801 'in Grad !
 
 DebugLog Zeige("DFS Kopernikus 3", BreiteNord, LaengeOst, 23.5:Float)
 DebugLog Zeige("Eutel F5", BreiteNord, LaengeOst, 21.5:Float)
 DebugLog Zeige("Astra 1A-1G", BreiteNord, LaengeOst, 19.2:Float)
 DebugLog Zeige("Eutel F3", BreiteNord, LaengeOst, 16.0:Float)
 DebugLog Zeige("Eutel F1 & F6", BreiteNord, LaengeOst, 13.0:Float)
 DebugLog Zeige("Eutel F2", BreiteNord, LaengeOst, 10.0:Float)
 DebugLog Zeige("Eutel F4", BreiteNord, LaengeOst, 7.0:Float)
 DebugLog Zeige("Telecom 2A,2B", BreiteNord, LaengeOst, -5.0:Float) 'West

End Function

Function Zeige:String(Sat:String,IchNordGrad:Float,IchOstGrad:Float,SatOstGrad:Float)

 Local z:String

 z = Sat + " : " + SatOstGrad + "° Ost" + Chr(9)
 z = z + Elevation(Sat, IchNordGrad, IchOstGrad, SatOstGrad) + Chr(9)
 z = z + Azimut(Sat, IchNordGrad, IchOstGrad, SatOstGrad)
 z = z + Chr(13)+Chr(10)
 
 Return Z

End Function

Function Azimut:String(Sat:String,IchNordGrad:Float,IchOstGrad:Float,SatOstGrad:Float)

 'Azimut = 180° + ATN(TAN(L-P)/SIN(B))

 'B=geografischen Breite des Empfangsortes 51.413488
 'L=geografischen Länge des Empfangsortes 6.860801
 'P=geografischen Länge der Satellitenposition 19.2

 Local A:Float
 A = 180:Float + ATan(Tan(IchOstGrad - SatOstGrad) / Sin(IchNordGrad))
 
 Return "Azimut " + A + "°"

End Function

Function Elevation:String(Sat:String,IchNordGrad:Float,IchOstGrad:Float,SatOstGrad:Float)
 
 Local E:Float
 Local B:Float
 Local L:Float
 Local P:Float
 
 B = IchNordGrad 'z.B. 51.413488
 L = IchOstGrad 'z.B. 6.860801
 P = SatOstGrad 'z.B. 19.2
 
 E = ATan((Cos(B) * Cos(L - P) - 0.1513) / Sqr(1:Float - (Cos(B) * Cos(L - P)) ^ 2:Float))

 Return "Elevation " + E + "°"
 
End Function