Graphics3D 800,600,0,1
SetBuffer BackBuffer()

Global camera=CreateCamera()
PositionEntity camera,0,0,-40
CameraClsColor camera,32,32,64

Const anzahl=2000

Type flare
 Field xp#
 Field yp#
 Field xg#
 Field yg#
 Field rp#
 Field rg#
 Field pa#
End Type

Global wkc#[90]
Global wks#[90]
For wk=0 To 90
 wkc[wk]=Cos(wk*4)*3
 wks[wk]=Sin(wk*4)*3
Next

brush=CreateBrush()   
BrushFX brush,35
Global mesh=CreateMesh()
Global face=CreateSurface(mesh,brush)

For q=1 To anzahl
 v0=AddVertex(face,0,32767,0)
 v1=AddVertex(face,0,32767,0)
 v2=AddVertex(face,0,32767,0)
 AddTriangle face,v0,v1,v2
Next

FreeBrush brush




;HAUPTSCHLEIFE
While Not KeyHit(1)

 If KeyDown(28) NewParticle(0,0,Rnd(-.015,.015),Rnd(-.015,.015),0,Rnd(-.25,.25))

 AniParticle()
 RenderWorld

 ms=MilliSecs():frame=frame+1
 If ms>mt mt=ms+250:fps=frame*4:frame=0
 Text 0,0,fps

 Flip 0
Wend
End




;Partikel erzeugen
Function NewParticle(xp#,yp#,xg#,yg#,rp#,rg#)
 f.flare=New flare
 f\xp=xp
 f\yp=yp
 f\xg=xg
 f\yg=yg
 f\rp=rp
 f\rg=rg
 f\pa=1
End Function




;Partikel animieren
Function AniParticle()

 ;Indexzähler
 zaehler=0

 ;Alle durchgehen
 For f.flare=Each flare
  f\xp=f\xp+f\xg
  f\yp=f\yp+f\yg
  f\rp=f\rp+f\rg
  If f\rp>30 f\rp=f\rp-30
  If f\rp<0 f\rp=f\rp+30

  ;Farbberechnung
  s#=f\pa/anzahl*2222
  r=500-s/3
  g=400-s/2
  b=300-s

  ;Positionierung
  VertexCoords face,zaehler,f\xp+wkc[f\rp]*f\pa/anzahl,f\yp+wks[f\rp]*f\pa/anzahl,0
  VertexCoords face,zaehler+1,f\xp+wkc[f\rp+60]*f\pa/anzahl,f\yp+wks[f\rp+60]*f\pa/anzahl,0
  VertexCoords face,zaehler+2,f\xp+wkc[f\rp+30]*f\pa/anzahl,f\yp+wks[f\rp+30]*f\pa/anzahl,0

  ;Farbanpassung
  VertexColor face,zaehler,r,g,b,1-f\pa/anzahl
  VertexColor face,zaehler+1,r,g,b,1-f\pa/anzahl
  VertexColor face,zaehler+2,r,g,b,1-f\pa/anzahl

  ;Alte ausrangieren
  If f\pa>anzahl-1 Delete f Else f\pa=f\pa+1
  zaehler=zaehler+3
 Next

 ;Letzen aus dem 'Blickfeld' bewegen
 VertexCoords face,zaehler,0,32767,0
 VertexCoords face,zaehler+1,0,32767,0
 VertexCoords face,zaehler+2,0,32767,0

;Funktionende
End Function