Code siehe unten!

setsockopt_(Socket, SOL_SOCKET_, SO_RCVTIMEO, Varptr(Timeout), 4)

int sock_setsockopt(struct socket *sock, int level, int optname,
                    char __user *optval, int optlen)
{
   // ...
   if(optlen<sizeof(int))
      return(-EINVAL);
     
   if (get_user(val, (int __user *)optval))
      return -EFAULT;
   
   valbool = val?1:0;

   lock_sock(sk);

   switch(optname)
   {
      // ...
      case SO_RCVTIMEO:
         ret = sock_set_timeout(&sk->sk_rcvtimeo, optval, optlen);
         break;
      // ...
   }
   // ..
}

static int sock_set_timeout(long *timeo_p, char __user *optval, int optlen)
{
   struct timeval tv;

   if (optlen < sizeof(tv))
      return -EINVAL;
   if (copy_from_user(&tv, optval, sizeof(tv)))
      return -EFAULT;

   *timeo_p = MAX_SCHEDULE_TIMEOUT;
   if (tv.tv_sec == 0 && tv.tv_usec == 0)
      return 0;
   if (tv.tv_sec < (MAX_SCHEDULE_TIMEOUT/HZ - 1))
      *timeo_p = tv.tv_sec*HZ + (tv.tv_usec+(1000000/HZ-1))/(1000000/HZ);
   return 0;
}

#include <sys/select.h>
#include <signal.h>

int pselect_(int ReadCount,   int *ReadSockets,
             int WriteCount,  int *WriteSockets,
             int ExceptCount, int *ExceptSockets,
             int Milliseconds)
{
   int      Index, High, Result;
   fd_set   ReadSet, WriteSet, ExceptSet;
   struct   timespec Timeout;
   sigset_t SignalMask;

   High = -1;

   FD_ZERO(&ReadSet);
   for(Index = 0; Index < ReadCount; Index++)
   {
      FD_SET(ReadSockets[Index], &ReadSet);
      if(ReadSockets[Index] > High) High = ReadSockets[Index];
   }

   FD_ZERO(&WriteSet);
   for(Index = 0; Index < WriteCount; Index++)
   {
      FD_SET(WriteSockets[Index], &WriteSet);
      if(WriteSockets[Index] > High) High = WriteSockets[Index];
   }

   FD_ZERO(&ExceptSet);
   for(Index = 0; Index < ExceptCount; Index++)
   {
      FD_SET(ExceptSockets[Index], &ExceptSet);
      if(ExceptSockets[Index] > High) High = ExceptSockets[Index];
   }

   Timeout.tv_sec  = Milliseconds/1000;
   Timeout.tv_nsec = (Milliseconds%1000)*1000000;

   sigfillset(&SignalMask);
   
   Result = pselect(High + 1, &ReadSet, &WriteSet, &ExceptSet, &Timeout, &SignalMask);
   if(Result == -1) return Result;

   for(Index = 0; Index < ReadCount; Index++)
   {
      if(!FD_ISSET(ReadSockets[Index], &ReadSet)) ReadSockets[Index] = 0;
   }

   for(Index = 0; Index < WriteCount; Index++)
   {
      if(!FD_ISSET(WriteSockets[Index], &WriteSet)) WriteSockets[Index] = 0;
   }

   for(Index = 0; Index < ExceptCount; Index++)
   {
      if(!FD_ISSET(ExceptSockets[Index], &ExceptSet)) ExceptSockets[Index] = 0;
   }

   return Result;
}

SuperStrict

Framework Pub.StdC
?Linux
   Import "linux.c"
?

?Win32
   Global selectex_:Int(ReadCount:Int, ReadSockets:Int Ptr, ..
                        WriteCount:Int, WriteSockets:Int Ptr, ..
                        ExceptCount:Int, ExceptSockets:Int Ptr, ..
                        Milliseconds:Int) = select_
?MacOS
   Global selectex_:Int(ReadCount:Int, ReadSockets:Int Ptr, ..
                        WriteCount:Int, WriteSockets:Int Ptr, ..
                        ExceptCount:Int, ExceptSockets:Int Ptr, ..
                        Milliseconds:Int) = select_
?Linux
   Extern "C"
      Function selectex_:Int(ReadCount:Int, ReadSockets:Int Ptr, ..
                             WriteCount:Int, WriteSockets:Int Ptr, ..
                             ExceptCount:Int, ExceptSockets:Int Ptr, ..
                             Milliseconds:Int) = "pselect_"
   End Extern
?


Extern "OS"
   Const INVALID_SOCKET_ : Int = -1
   Const SOCK_RAW_       : Int = 3
   Const IPPROTO_ICMP    : Int = 1

   ?Win32
      Const SOL_SOCKET_ : Int = $FFFF

      Function inet_addr_:Int(Address$z) = "inet_addr@4"
      Function GetCurrentProcessId:Int() = "GetCurrentProcessId@0"

   ?MacOS
      Const SOL_SOCKET_ : Int = $FFFF

      Function inet_addr_:Int(Address$z) = "inet_addr"
      Function GetCurrentProcessId:Int() = "getpid"

   ?Linux
      Const SOL_SOCKET_ : Int = 1

      Function inet_addr_:Int(Address$z) = "inet_addr"
      Function GetCurrentProcessId:Int() = "getpid"
   ?
End Extern

Type TICMP
   Field _Type     : Byte
   Field Code      : Byte
   Field Checksum  : Short
   Field ID        : Short
   Field Sequence  : Short

   Function BuildChecksum:Short(Buffer:Short Ptr, Size:Int)
      Local Checksum:Long

      While Size > 1
         Checksum :+ Buffer[0]
         Buffer :+ 1
         Size :- 2
      Wend
      If Size Then Checksum :+ (Byte Ptr(Buffer))[0]

      Checksum = (Checksum Shr 16) + (Checksum & $FFFF)
      Checksum :+ Checksum Shr 16
      Return htons_(~Checksum)
   End Function
End Type

Const ICMP_ECHOREPLY   : Byte = 0
Const ICMP_UNREACHABLE : Byte = 3
Const ICMP_ECHO        : Byte = 8

Const ICMP_CODE_NETWORK_UNREACHABLE : Byte = 0
Const ICMP_CODE_HOST_UNREACHABLE    : Byte = 1

Function Ping:Int(RemoteIP:Int, Data:Byte Ptr, Size:Int, Sequence:Int = 0, ..
                  Timeout:Int = 5000)
   Local Socket:Int, ProcessID:Int, ICMP:TICMP, Buffer:Byte Ptr, ..
         Temp:Int, Start:Int, Stop:Int, Result:Int, SenderIP:Int, SenderPort:Int, ..
         IPSize:Int

   Socket = socket_(AF_INET_, SOCK_RAW_, IPPROTO_ICMP)
   If Socket = INVALID_SOCKET_ Then Throw("Socket konnte nicht erstellt werden")

   ProcessID = GetCurrentProcessID()

   ICMP = New TICMP
   ICMP._Type     = ICMP_ECHO
   ICMP.Code      = 0
   ICMP.Checksum  = 0
   ICMP.ID        = ProcessID
   ICMP.Sequence  = Sequence

   Buffer = MemAlloc(65536)
   MemCopy(Buffer, ICMP, 8)
   MemCopy(Buffer + 8, Data, Size)
   Short Ptr(Buffer)[1] = htons_(TICMP.BuildChecksum(Short Ptr(Buffer), 8 + Size))

   Temp = Socket
   If (selectex_(0, Null, 1, Varptr(Temp), 0, Null, 0) <> 1) Or ..
      (sendto_(Socket, Buffer, 8 + Size, 0, RemoteIP, 0) = SOCKET_ERROR_) Then
      MemFree(Buffer)
      closesocket_(Socket)
      Throw("ICMP Echo Request konnte nicht gesendet werden")
   EndIf

   Start = MilliSecs()
   Repeat
      Temp = Socket
      If selectex_(1, Varptr(Temp), 0, Null, 0, Null, Timeout) <> 1 Then
         MemFree(Buffer)
         closesocket_(Socket)
         Throw("Socket ist nicht bereit zum Empfangen -> Timeout")
      EndIf

      Result = recvfrom_(Socket, Buffer, 65536, 0, SenderIP, SenderPort)
      Stop = MilliSecs()
      If Result = SOCKET_ERROR_ Then
         MemFree(Buffer)
         closesocket_(Socket)
         Throw("Fehler beim Empfang")
      EndIf

      ?X86
         IPSize = (Buffer[0] & $0F)*4
      ?PPC
         IPSize = (Buffer[0] & $F0)*4
      ?
      MemCopy(ICMP, Buffer + IPSize, 8)

      If ICMP.ID <> ProcessID Then
         Continue
      ElseIf ICMP._Type = ICMP_UNREACHABLE Then
         If ICMP.Code = ICMP_CODE_HOST_UNREACHABLE Or ..
            ICMP.Code = ICMP_CODE_NETWORK_UNREACHABLE Then
            MemFree(Buffer)
            closesocket_(Socket)
            Throw("Host oder Netzwerk nciht erreichbar")
         EndIf
      ElseIf ICMP.Code = ICMP_ECHOREPLY Then
         Exit
      EndIf
   Forever

   MemFree(Buffer)
   closesocket_(Socket)

   Return Stop - Start
End Function

Function IntIP:Int(IP:String)
   Return htonl_(inet_addr_(IP))
End Function

Function GetHostIP:Int(HostName:String)
   Local Addresses:Byte Ptr Ptr, AddressType:Int, AddressLength:Int
   Local PAddress:Byte Ptr, Address:Int

   Addresses = gethostbyname_(HostName, AddressType, AddressLength)
   If (Not Addresses) Or AddressType <> AF_INET_ Or AddressLength <> 4 Then Return 0

   If Addresses[0] Then
      PAddress = Addresses[0]
      Address = (PAddress[0] Shl 24) | (PAddress[1] Shl 16) | ..
                (PAddress[2] Shl 8) | PAddress[3]
      Return Address
   Else
      Return 0
   EndIf
End Function

Global RemoteIP : Int, ..
       Message  : String, ..
       Data     : Byte Ptr, ..
       Result   : Int

RemoteIP = GetHostIP("google.com")
If Not RemoteIP Then
   WriteStdout("Host not found~n")
   End
EndIf

Message = "Hello, world!"
Data = Message.ToCString()

Try
   Result = Ping(RemoteIP + 200, Data, Message.Length)
   WriteStdout("Ping tooks " + Result + "ms~n")
Catch Exception:Object
   WriteStdout("Error:~n " + Exception.ToString())
End Try

MemFree(Data)
End

Building test
Compiling:test.bmx
Linking:test.debug
Executing:test.debug
Error:
 Socket konnte nicht erstellt werden
Process complete