Strict

Graphics 640,480,0,85

Global playerlist:TList=CreateList() 'Liste für den Spieler
Global shotlist:TList=CreateList() 'Liste für Schüsse

'neuen Spieler erzeugen
t_player.f_create(320,460)

'Hauptschleife
Repeat
   f_update() 'Objekte mit der Funktion f_update erneuern
   Flip
   Cls
Until KeyHit(key_escape) Or AppTerminate()

'Spieler Objekt
Type t_player
   'Spieler Position und Eigenschaften
   Field x#
   Field y#
   Field speed#
   Field cooldown:Byte
   
   'Spieler erzeugen
   Function f_create(x,y)
      Local player:t_player=New t_player 'neue Instanz von t_player
      player.x=x 'Objekt Eigenschaften übergeben
      player.y=y
      player.speed=2
      player.cooldown=0
      ListAddLast playerlist,player 'Objekt in die Liste playerlist eintragen
   End Function
   
   'Spieler steuern und anzeigen
   Method m_update()
      'schiessen
      If cooldown>0 cooldown:-1
      If cooldown=0 And KeyDown(key_space)
         cooldown=20
         t_shot.f_create(x,y) 'neuer Schuss an Spieler x/y-Position
      EndIf
      'bewegen
      If KeyDown(key_left) And x>20 x:-speed
      If KeyDown(key_right) And x<620 x:+speed
      'anzeigen
      DrawRect x-20,y-10,40,20
   End Method
End Type

'Schuss Objekt
Type t_shot
   'Schuss Position und Eigenschaften
   Field x#
   Field y#
   Field speed#
   
   'neuen Schuss erzeugen
   Function f_create(x,y)
      Local shot:t_shot=New t_shot 'neue Instanz von t_shot
      shot.x=x 'Objekt Eigenschaften übergeben
      shot.y=y
      shot.speed=5
      ListAddLast shotlist,shot 'Objekt in die Liste shotlist eintragen
   End Function
   
   'Schuss bewegen und anzeigen
   Method m_update()
      'bewegen
      y:-speed
      'löschen
      If y< 100 shotlist.remove(Self) 'Schuss aus Liste entfernen wenn er zu weit oben ist
      'anzeigen
      DrawRect x-5,y-10,10,20
   End Method
End Type

'alle Objekte erneuern
Function f_update()
   'für alle Objekte in den Listen die Methode m_update() ausführen
   For Local player:t_player=EachIn playerlist
      player.m_update()
   Next
   For Local shot:t_shot=EachIn shotlist
      shot.m_update()
   Next
End Function