Extern "win32"
   Function mciSendStringA(cmd$z,resultbuffer:Byte Ptr=Null,buffersize:Int=0,hwndcallback:Int=0)
   Function SetForegroundWindow:Int(hwnd:Int)
End Extern

Type TMusic
   Global musicnumber:Int=0
   Field number:Int,paused:Int
   Field playing:Int
   Field volume:Int
   Field pos:Int
   Field starttime:Int
   Field str:Byte[128]
   
   Function Create:TMusic()
      Local music:TMusic=New TMusic
      music.number=TMusic.musicnumber
      TMusic.musicnumber:+1
      mciSendStringA("set "+music.Name()+" time format milliseconds")
      Return music      
   End Function
   
   Function Open:TMusic(sfile:String)
      Local music:TMusic=New TMusic
      music.number=TMusic.musicnumber
      TMusic.musicnumber:+1
      mciSendStringA("set "+music.Name()+" time format milliseconds")
      music.Load(sfile)
      Return music
   End Function
   
   Method Load(sfile:String)
      mciSendStringA("open ~q"+sfile+"~q alias "+Name())
   End Method
   
   Method SetVolume(vol:Int)
      mciSendStringA("setaudio "+Name()+" volume to "+vol)
      volume = vol
   End Method
   
   Method PlayFrom(from:Int)
      mciSendStringA("play "+Name()+" from "+from)
      pos = from
   End Method
   
   Method Play(from:Int=0)
      If Not paused
         mciSendStringA("play "+Name()+" from "+from)
         playing=1
         pos = from
      Else
         mciSendStringA("resume "+Name())
         playing=True
         paused=False
      EndIf
      starttime = MilliSecs()
   End Method
   
   Method getPos:Int()
      If playing Then
         pos:+ MilliSecs()-starttime
         starttime = MilliSecs()
      EndIf
      Return pos
   End Method
   
   Method Pause()
      If paused Return
      mciSendStringA("pause "+Name())
      getPos()
      paused=True
      playing=False
   End Method
   
   Method Stop()
      mciSendStringA("stop "+Name())
      mciSendStringA("close "+Name())
      mciSendStringA("set "+Name()+" time format milliseconds")
      playing=False
      paused=False
   End Method
   
   Method Name:String()
      Return ("TMusic"+String(number))
   End Method
   
   Method SetPos()
      mciSendStringA("play "+Name()+" from "+pos)
   End Method
   
   Method length:Int()
      Local Retbank:TBank = CreateBank(12)
      mciSendStringA("set "+Name()+" time format ms")
      mciSendStringA("Status "+Name()+" Length",BankBuf(Retbank),12,0)
      Local retval:String = PeekStr(retbank,12,0)
      Retbank = Null
      Return Int(Trim(retval))
   End Method
End Type

Function PeekStr:String(bank:TBank,Size:Int=64,Offset:Int=0)
   Local NewStr:String = ""
   For Local count:Int = offset To (offset+size-1)
      Local newchr:Byte = PeekByte(bank,count)
      If newchr = 0 Then Exit
      newstr = newstr + Chr(newchr)
   Next
   Return Newstr
End Function