Angle# = ATan2( MouseY() - SpielerY#, MouseX() - SpielerX# )

AppTitle("Sinus & Kosinus")
Graphics(800, 600, 0, 2)
SetBuffer BackBuffer()
Local timer = CreateTimer(60)

Const KEY_Escape = 1, KEY_UP = 200, KEY_DOWN = 208
Const KEY_LEFT = 203, KEY_RIGHT = 205
Local radius = 150, winkel = 45, x, y

Repeat
   
   If KeyDown(KEY_UP) Then radius = ((radius + 1)+300) Mod 300
   If KeyDown(KEY_DOWN) Then radius = ((radius -1)+300) Mod 300
   If KeyDown(KEY_LEFT) Then winkel = ((winkel + 1)+360) Mod 360
   If KeyDown(KEY_RIGHT) Then winkel = ((winkel - 1)+360) Mod 360
   
   x = 400 + Cos(winkel) * radius
   y = 300 - Sin(winkel) * radius
   
   ;** Der Radius:
   Color(255, 0, 0)
   Line(400, 300, x, y)
   Text(400 + Cos(winkel) * radius/2, 300 - Sin(winkel) * radius/2, "Atan2: "+ATan2(y-300,x-400))
   ;** Die 0° Linie:
   Color(0, 0, 255)
   Line(400, 300, 400 + Cos(0) * radius, 300)
   Text(400 + Cos(0) * radius, 300, " 0°", False, True)
   
   ;*** Sinus:
   Color(255, 255, 0)
   Line(400, 300, 400, 300 - Sin(winkel) * radius)
   Line(x, y, 400, 300 - Sin(winkel) * radius) ;Zum Trabant
   Text(380, 300 - Sin(winkel) * radius/2, "Sin", True, True)
   
   ;*** Kosinus:
   Color(0, 255, 0)
   Line(400, 300, 400 + Cos(winkel) * radius, 300)
   Line(x, y, 400 + Cos(winkel) * radius, 300) ;Zum Trabant
   Text(400 + Cos(winkel) * radius/2, 300, "Cos")
   
   Color(255, 255, 255)
   ;** Die Mitte...
   DrawKreis(400, 300, 10)
   ;** Die Umlaufbahn...
   DrawKreis(400, 300, radius, False)
   ;** Der Trabant...
   DrawKreis(x, y, 5)
   
   Text(10, 10, "Winkel: "+winkel+"°")
   Text(10, 25, "Sinus: "+Sin(winkel))
   Text(10, 40, "Kosinus: "+Cos(winkel))
   
   Flip(0)
    WaitTimer(timer)
    Cls
Until KeyHit(KEY_Escape)
End


Function DrawKreis(fx, fy, fr, solid=1)
   Oval(fx-fr, fy-fr, fr*2, fr*2, solid)
End Function