AppTitle "Glaskugel Demo"

Graphics3D 800,600,32,2

Global GameSpeed%=60
Global SW%=GraphicsWidth()
Global SH%=GraphicsHeight()
Global FramePeriod%=1000/GameSpeed
Global FrameTime%=MilliSecs()-FramePeriod
Global DeltaTimeOld%

Camera=CreateCamera()
CameraRange Camera,0.1,10
PositionEntity Camera,1.5,0.5,-1
CameraClsColor Camera,100,150,255

Light=CreateLight(2)
PositionEntity Light,100,100,100
LightRange Light,200
AmbientLight 64,64,64

Glas=CreateGlass(128,0.25,100,150,255,0.95)

PointEntity Camera,Glas

MoveMouse SW/2,SH/2

While Not KeyHit(1)
   
   ; Frametween calculation
   Local FrameElapsed%,FrameTicks%,FrameTween#,t%
   Repeat FrameElapsed=MilliSecs()-FrameTime Until FrameElapsed
   FrameTicks=FrameElapsed/FramePeriod
   FrameTween=Float(FrameElapsed Mod FramePeriod)/Float(FramePeriod)
   
   ; Frametween loop
   For t=1 To FrameTicks
      
      ; Frametween Captureworld
      FrameTime=FrameTime+FramePeriod : If t=FrameTicks Then CaptureWorld
   
      If KeyHit(57) Then wf=1-wf : WireFrame wf
      
      FreeCam(Camera,85,0.01)
      
      
   Next
   
   RenderWorld FrameTween
   
   Flip 0
   
Wend

Function CreateGlass(detail%=32,shininess#=0.25,r%=100,g%=150,b%=255,alpha#=0.5)
   
   Local v%
   Local mesh%=CreateSphere(detail)
   Local surf%=GetSurface(mesh,1)
   Local tex%=LoadTexture("glow.png",2+64)
   
   EntityTexture mesh,tex
   EntityBlend mesh,3
   TextureBlend tex,2
   EntityFX mesh,2
   EntityShininess mesh,shininess
   
   For v=0 To CountVertices(surf)-1
      VertexColor surf,v,r,g,b,alpha
   Next
   
   Return mesh
   
End Function

Function FreeCam(camera%,maxpitch#=85.0,movespeed#,rotspeed#=16.666,rotfloat#=8.0)
   
   Local movex#,movez#,dx#,dy#,dk#,dt%,t%
   Local pitch#
   
   ; Arrows = Move
   movex=KeyDown(205)-KeyDown(203)
   movez=KeyDown(200)-KeyDown(208)
   
   ; smooth movement
   t=MilliSecs() : dt=t-DeltaTimeOld : DeltaTimeOld=t : dk=Float(dt)/rotspeed
   dx=(SW/2-MouseX())*0.01*dk : dy=(SH/2-MouseY())*0.01*dk
   TurnEntity camera,-dy,dx*0.1*dk*rotfloat,0
   
   ; limit pitch
   pitch=EntityPitch(camera,1) : If pitch>maxpitch Then pitch=maxpitch Else If pitch<-maxpitch Then pitch=-maxpitch
   
   ; rotate and move
   RotateEntity camera,pitch,EntityYaw(camera,1),0,1   
   MoveEntity camera,movex*movespeed,0,movez*movespeed
   
End Function