SuperStrict

Framework BtbN.MinimalSDL
Import BRL.Math
Import BRL.Threads

?Not Threaded
Throw "This needs Threaded build!"
?Threaded

SDL_Init(800, 600, 32, "Mandelbrot")

Global threadCount:Int = 8

Global valsLock:TMutex = TMutex.Create()
Global scrW:Int = SDL_ScreenWidth, scrH:Int = SDL_ScreenHeight
Global xMin:Double = 0.0, xMax:Double = 1.0
Global yMin:Double = 0.0, yMax:Double = 1.0
Global iter:Int = 1000
Global bg_r:Int = 0, bg_g:Int = 0, bg_b:Int = 0

Global pixelLock:TMutex = TMutex.Create()
Function PutPixelThread(x:Int, y:Int, r:Int, g:Int, b:Int)
	pixelLock.Lock()
	SDL_help_PutPixelFast(x, y, r, g, b)
	pixelLock.Unlock()
EndFunction

Function DoZoom(x:Int, y:Int, w:Int, h:Int)
	Local sw:Int = scrW
	Local sh:Int = scrH
	
	valsLock.Lock()
	
	Local SpanX:Double = (xMax - xMin)/Double(sw)
	Local SpanY:Double = (yMax - yMin)/Double(sh)
	Local oxMin:Double = xMin
	Local oyMin:Double = yMin

	xMin = xMin + (x - w/2) * SpanX
	xMax = oxMin + (x + w/2) * SpanX
	yMin = yMin + (y - h/2) * SpanY
	yMax = oyMin + (y + h/2) * SpanY
	
	valsLock.Unlock()
EndFunction

Function ThreadFunc_CalcMandelbrot:Object(inp:Object)
	Local arr:Int[] = Int[](inp) ' [xFrom, xTo, yFrom, yTo, n]
	If Not arr Then Throw "Error, data was not Int-Array!"

	WriteStdout("Thread "+arr[4]+" starts~n")

	For Local x:Int = arr[0] To arr[1]
		For Local y:Int = arr[2] To arr[3]
			valsLock.Lock()
			Local iter:Int = .iter
			Local c_x:Double = xMin + ((xMax-xMin) * (Double(x+1)/Double(scrW)))
			Local c_y:Double = yMin + ((yMax-yMin) * (Double(y+1)/Double(scrH))) - 1.0
			valsLock.Unlock()

			
			Local cnt:Int = 0
			Local z_x:Double = c_x
			Local z_y:Double = c_y
			For Local i:Int = 0 Until iter
				Local xv:Double = (z_x * z_x - z_y * z_y) + c_x
				Local yv:Double = (z_y * z_x + z_x * z_y) + c_y
				
				If (xv * xv + yv * yv) > 4.0 Then Exit
				z_x = xv
				z_y = yv

				cnt :+ 1
			Next
			
			If cnt = iter Then
				PutPixelThread(x, y, bg_r, bg_g, bg_b)
			Else
				PutPixelThread(x, y,..
					Byte( ((Sin(cnt+cnt)+1.0)/2.0)*255 ),..
					Byte( ((Cos(cnt+cnt)+1.0)/2.0)*255 ),..
					Byte( ((Cos(cnt+cnt)+1.0)/2.0)*255 )..
				)
			EndIf
		Next
	Next
	
	WriteStdout("Thread "+arr[4]+" finished~n")
	
	Return Null
EndFunction

Global threads:TThread[] = New TThread[threadCount]

Repeat
	SDL_Cls()

	For Local n:Int = 0 Until threadCount
		Local arr:Int[] = New Int[5]
		arr[0] = 0 ' FromX
		arr[1] = SDL_ScreenWidth - 1 ' ToX
		arr[2] = (SDL_ScreenHeight*n)/threadCount' FromY
		arr[3] = (SDL_ScreenHeight*(n+1))/threadCount - 1' ToY
		arr[4] = n
		threads[n] = TThread.Create(ThreadFunc_CalcMandelbrot, arr)
	Next
	
	For Local n:Int = 0 Until threadCount
		If threads[n].Running() Then threads[n].Wait()
	Next

	SDL_Flip()
	
	If MouseHit(1) Then DoZoom(MouseX(), MouseY(), SDL_ScreenWidth, SDL_ScreenHeight)
	
	If MouseHit(2) Then DoZoom(MouseX(), MouseY(), SDL_ScreenWidth/2, SDL_ScreenHeight/2)
	If MouseHit(3) Then DoZoom(MouseX(), MouseY(), SDL_ScreenWidth/4, SDL_ScreenHeight/4)
Until AppTerminate() Or KeyHit(KEY_ESCAPE)

SDL_Quit()
End