Unicode über 65000? [Gelöst: es geht doch!]

Übersicht BlitzMax, BlitzMax NG Allgemein

Neue Antwort erstellen

Midimaster

Betreff: Unicode über 65000? [Gelöst: es geht doch!]

 BeitragDi, Mai 25, 2010 9:37
Antworten mit Zitat
Benutzer-Profile anzeigen
Ich experimentiere gerade mit Unicode-Zeichensätzen in BlitzMax.

Dabei gibt es Zeichensätze für z.B. Japanisch oder Chinesisch, die sich sehr einfach unter BlitzMax ansprechen lassen:

BlitzMax: [AUSKLAPPEN] 
SuperStrict
Graphics 800,600

Global ZeichenFont:Timagefont=LoadImageFont("msgothic.ttf",60)
Global Zeichen$

Zeichen=Chr(20098)

SetImageFont ZeichenFont
DrawText  Zeichen ,100,100
Flip 0
WaitKey()
(Der BeispielFont liegt dem Microsoft-Office-Paket bei und enthält die Schriftzeichen bereits vieler Sprachen)

Hierbei kann man bei der Funktion CHR$() auch Werte über 255 eingeben. Ausgegeben werden dann chinesische Schriftzeichen.
Das klappt aus so weit ganz gut, aber es gibt auch Unicode-Zeichen jeseits der 65000. Und hier beginnt BlitzMax plötzlich wieder von vorne:

BlitzMax: [AUSKLAPPEN] 
Zeichen= Chr(33) + Chr(33+65248)
DrawText  Zeichen ,100,100


z.b. Musikzeichensätze wie "Musica.otf" oder Hieroglyphen wären so möglich.

Frage: kennt sich hier jemand aus und weiß vielleicht eine Lösung?

Hier noch der Zeichensatz-Betrachter zum experimentieren:
interessante Stellen sind z.b. bei 900,1000, 8200, 8500, 9300, 12300, 20000ff

BlitzMax: [AUSKLAPPEN] 
SuperStrict
Graphics 1024,768

Global NeutralFont:Timagefont=LoadImageFont("",10)
Global ZeichenFont:Timagefont=LoadImageFont("msgothic.ttf",60)
Global Anfang%, Such%, Taste%
such=-1
Repeat
	If Anfang <>Such Then
		Cls
		Such=Anfang
		For Local i%= 0 To 99
			Local X%, Y%, Zeichen$ 
			x= i Mod 10
			y= i/10
			Zeichen=Chr(Anfang+i)

			SetColor 255,255,255
			DrawRect X*102,Y*75,100,73
			SetColor 5,5,5

			SetImageFont NeutralFont
			DrawText (Anfang+i),x*102+10,y*75+62
			
			SetImageFont ZeichenFont
			DrawText  Zeichen ,x*102+10,y*75+0
		Next
			SetColor 255,255,255
		SetImageFont NeutralFont
		DrawText  "weiter mit Taste... <H>=+100 <T>=+1000 <Z>=+10000 <R>=Reset",50,752
	EndIf 
	Taste =GetChar() 
	Select Taste
		Case 0
		
		Case Asc("r") ' tausend"
			Anfang=0
		Case Asc("t") ' tausend"
			Anfang=Anfang+1000
		Case Asc("z") ' zehntausend"
			Anfang=Anfang+10000
		Default
			Anfang=Anfang+100
	End Select
	Flip 0
	Delay 30	
Until AppTerminate()


[EDIT]
ein weiterer schöner Zeichensatz wäre "code2000.ttf". Er enthält über 60.000 Glyphen. Download hier: http://www.code2000.net/

[Edit II]
selbst mit dem schnöden "ARIAL.TTF" kann man bereits (z.b. mit obigem Zeichensatzbetrachter) arabische Schriftzeichen sehen! Ab 1500...
  • Zuletzt bearbeitet von Midimaster am Do, Mai 27, 2010 9:07, insgesamt 3-mal bearbeitet
 

#Reaper

Newsposter

BeitragDi, Mai 25, 2010 10:34
Antworten mit Zitat
Benutzer-Profile anzeigen
Das ganze liegt daran, dass BMax (soweit ich weiß) intern mit UTF-16 (also 16 bit pro Zeichen) arbeitet. UTF-16 kann zwar auch für einzelne Zeichen 32 bit verwenden, aber ich nehme mal an, dass das in BMax nicht geht (da ja alle Zeichen im Speicher gleich groß sein sollen). Für dein Vorhaben bräuchte es dann wohl UTF-32, das wird BMax wahrscheinlich aber nicht von Haus aus können und wäre dann wohl auch nur mit einer eigenen String-Klasse machbar.
Soviel zu meinem Halbwissen. Wink
AMD Athlon 64 3500+, ATI AX800 Pro/TD, 2048 MB DRR 400 von Infineon, ♥RIP♥ (2005 - Juli 2015 -> sic!)
Blitz3D, BlitzMax, MaxGUI, Monkey X; Win7

Midimaster

 BeitragDo, Mai 27, 2010 9:06
Antworten mit Zitat
Benutzer-Profile anzeigen
Also ich habe inzwischen im englischen Forum eine Lösung angeboten bekommen, die ich hier noch für die Nachwelt erhalten wollte, da damit kar wird, dass zwei scheinbare Einschränkungen von BlitzMax nicht gelten:

1. BlitzMax kann Open Type Font *otf laden

2. BlitzMax kann Unicode über 65.000 darstellen

Es geht doch mit BlitzMax die Unicode-Zeichen über 65.000 ausgeben zu lassen. Dabei wird ein Trick angewendet, die Zeichen gleich als Images auszugeben. Der Zeichen satz darf sogar ein Open Type Font .OTF sein. Der wird ganz normal geladen, dann aber die Glyphes direkt angesprochen.

Die Ausgabe eines Zeichens wird durch die Funktion DrawChar ersetzt:

BlitzMax: [AUSKLAPPEN] 
Function DrawChar(char%, x#, y#, Font:TImageFont = Null)
	If Not Font
            Font = GetImageFont()
	EndIf
        Local idx% = Font.CharToGlyph(char)
	If idx >= 0
		Local gly:TImageGlyph = font.LoadGlyph(idx)
		If gly And gly._image
			DrawImage(gly._image, x, y, 0)
		EndIf
	EndIf
End Function

Neue Antwort erstellen


Übersicht BlitzMax, BlitzMax NG Allgemein

Nach Oben

Gehe zu:

Powered by phpBB © 2001 - 2006, phpBB Group