Type TInput 'Type für die ausgelesenen Zeilen
	Global List:TList = New TList
	Field sLine:String
	
	Method New()
		List.Addlast(Self) 'Automatisch der Liste hinzufügen
	End Method
	
	Function Create:TInput(sInput:String) 'Einfacher Konstruktor
		Local Input:TInput = New TInput
			Input.sLine = sINput
		Return Input
	End Function
End Type


Function WriteCompleteFile(sSection:String, sSearchTerm:String, sValue:String, sFile:String) 'Liest die komplette Datei aus	und schreibt dann eine neue
	Local sLine:String, fileINI:TStream
	TInput.List.Clear() 'Erstmal die Liste leeren, damit keine alten Relikte darin stecken
	
	If FileType(sFile) = 1 Then	'Die Datei kann nur ausgelesen werden, wenn sie vorhanden ist, ansonsten gehts direkt mit dem Schreiben weiter
		fileINI = ReadFile(sFile)
		While Not Eof(fileINI)
			sLine = ReadLine(fileINI)
			TInput.Create(sLine) 'Einfach die Zeile der Liste hinzufügen
		Wend
		CloseFile(fileINI)
	EndIf
	WriteInFile(sSection, sSearchTerm, sValue, sFile)
	
End Function

Function GetLeftPart:String(sLine:String) 'Gibt die Bezeichnung, also das was links vom "=" steht zurück
	If Instr(sLine, "=") > 0 Then
		Return Left(sLine, Instr(sLine, "=") - 1)
	Else
		Return ""
	EndIf
End Function

Function WriteInFile(sSection:String, sSearchTerm:String, sValue:String, sFile:String) 'Die Funktion schreibt dann alles wieder in die Datei
	sSection = "[" + sSection + "]"
	Local LastPossible:TInput = Null
	Local bHasSection:Byte = False, bHasTerm:Byte = False
	
	For Local Inp:TInput = EachIn TInput.List 'Alles in der Liste
		If  (Left(Inp.sLine, 1) = "[") Then	'Neue Sektion?
			If bHasSection Then 'Wenn die gesuchte Sektion schon gefunden wurde
				If Not bHasTerm Then 'Aber die gesuchte Variable noch nicht
					If Lastpossible = Null Then 'Nur wenn Lastpossible noch nicht ersetzt wurde
						LastPossible = Inp 'Dann ist eine Zeile davor die letzt mögliche Stelle für einen neuen Eintrag
					EndIf
				EndIf
			EndIf
		EndIf
		If (Lower(Inp.sLine) = Lower(sSection)) Then 'Wurde die gesuchte Sektion gefunden?
			bHasSection = True
		EndIf
		If (Lower(Trim(GetLeftPart(Inp.sLine))) = Lower(sSearchTerm)) Then 'Gesuchte Variable?
			If bHasSection Then 'in der richtigen Sektion?
				Inp.sLine = sSearchTerm + "=" + sValue 'Dann einfach den Wert an der Stelle abändern
				bHasTerm = True
			EndIf
		EndIf
	Next
	
	If bHasSection Then 'Sektion gefunden?
		If Not bHasTerm Then 'Aber die Variable nicht?
			If LastPossible <> Null Then 'LastPossible ist null wenn keine Sektion mehr folgte
				Local NewInp:TInput = TInput.Create(sSearchTerm + "=" + sValue) 'Neue Zeile erstellen
				TInput.List.Remove(NewInp) 'Und diese vom Ende der Liste entfernen, da sie dort falsch wäre
				Local Link:TLink = TInput.List.FindLink(LastPossible) 'Hier beginnt die neue Sektion
				TInput.List.InsertBeforeLink(NewInp, Link) 'Die Zeile eine Reihe vor der neuen Sektion, also noch in der richtigen Sektion einfügen
			Else
				Tinput.Create(sSearchTerm + "=" + sValue) 'Ansonsten gehört das ganze noch zur ersten Sektion, also einfach einfügen
			EndIf
		EndIf
	Else 'Wenn keine Sektion vorhanden war
		TInput.Create(ssection ) 'Eine neue erstellen
		TinPut.Create(ssearchterm + "=" + sValue) 'Und auch die Reihe erstellen
	EndIf
	
	Local INIFile:TStream = WriteFile(sFile)
	For Local InpNew:TInput = EachIn TInput.List
		WriteLine(INIFile, InpNew.sLine) 'Jeden Eintrag in die Datei schreiben
	Next
	CloseFile(INIFile)
End Function

WriteCompleteFile("Player1", "Points", "100", "Player.ini")
WriteCompleteFile("Player1", "Power", "30", "Player.ini")
WriteCompleteFile("Player2", "Points", "200", "Player.ini")
WriteCompleteFile("Player2", "Power", "50", "Player.ini")
WriteCompleteFile("Player1", "Games", "10", "Player.ini")