SuperStrict

Local Raetselzahl:String = "140454"

'Da die größte Ziffer der Raetselzahl eine 5 ist, muss es sich beim Ausgangszahlensystem
'mindestens um ein 6er-System handeln, also starten wir bei der Basis1 mit der 6:
For Local Basis1:Int = 6 To 36
	For Local Basis2:Int = 2 To 36
		If Basis1 <> Basis2 Then
			Local Zahlenstring:String = ZahlensystemKonvertierung(Raetselzahl, Basis1, Basis2)
			If Palindrom(Zahlenstring) = True Then
				Print "Die Zahl " + Raetselzahl + " des " + Basis1 + "er-Systems ergibt, konvertiert ins " + Basis2 + "er-System, das Palindrom " + Zahlenstring
			End If
		End If
	Next
Next

'Die folgende Funktion prüft, ob eine String-Variable ein Palindrom ist:
Function Palindrom:Byte(StringVar:String)
	Local Laenge:Int = Len(StringVar)
	For Local i:Int = 1 To Laenge/2
		If Mid(StringVar, i, 1) <> Mid(StringVar, Laenge + 1 - i, 1) Then Return False
	Next
	Return True
End Function

'Die folgende Funktion wandelt eine Zahl zwischen zwei beliebigen Zahlensystemen um:
Function ZahlensystemKonvertierung:String(QuellZahl:String, QuellBasis:Long, ZielBasis:Long)

	'Als Ziffern dienen die normalen Zahlenziffern 0 bis 9 und danach die Grossbuchstaben A bis Z,
	'deshalb sollen die Zahlensysteme auf die maximale Basis 36 begrenzt werden:
	If QuellBasis < 2 Or ZielBasis < 2 Or QuellBasis > 36 Or ZielBasis > 36 Then RuntimeError(" Die Zahlensystemkonvertierung behandelt nur Zahlensysteme mit Basen zwischen 2 und 36")
	
	'Als erstes soll die QuellZahl in das Zehnersystem umgewandelt werden:
	Local DezimaleGanzzahl:Long, Exponent:Long
	For Local Stelle:Long = Len(QuellZahl) To 1 Step -1
		Local Faktor:Long, Zeichen:String = Mid(QuellZahl, Stelle, 1)
		If Asc(Zeichen) < 65 Then	 '(normale Ziffer 0 - 9)
			Faktor = Long(Zeichen)
		Else    '(Buchstabe A - Z)
			Faktor = Asc(Zeichen) - 55
		End If
		DezimaleGanzzahl = DezimaleGanzzahl + Faktor * (QuellBasis ^ Exponent)
		Exponent:+1
	Next
	If ZielBasis = 10 Or DezimaleGanzzahl = 0 Then Return String(DezimaleGanzzahl)
	
	'Dann erfolgt die Umwandlung in das Ziel-Zahlensystem:
	Local ZielZahl:String
	Exponent = Long(Log(DezimaleGanzzahl) / Log(ZielBasis))
	While Exponent >= 0
		Local Potenz:Long = ZielBasis ^ Exponent 
		Local Quotient:Long = DezimaleGanzzahl / Potenz
		If Quotient < 10 Then
			Zielzahl = Zielzahl + String(Quotient)
		Else
			Zielzahl = Zielzahl + Chr(Quotient + 55)
		End If
		DezimaleGanzzahl = DezimaleGanzzahl - Quotient * Potenz
		Exponent = Exponent - 1
	Wend
	
	Return Zielzahl
	
End Function

'#####################################################
'Lösungsvorschlag zum BlitzQuiz "Zahlensysteme"
'von Grafe
'-----------------------------------------------------
'Kleine Anmerkung vom Autor: 
'Der Code ist nicht sehr Ordentlich 
'da er in Hast geschrieben wurde!
'#####################################################

SuperStrict

Global Wert:Int = 140454

Local Result:Int[] = PalindromMaker(Wert)

Print "Das Palindrom ist " + Result[0] + ", welches entstand als das Programm die Zahl " + Wert + " im " + Result[1] + "er System ins " + Result[2] + "er System umwandelte."

WaitKey()

Function PalindromMaker:Int[] (Wert:Int)
	Local tmpReturn:String
	For Local VonZS:Int = 6 To 36
		For Local NachZS:Int = 2 To 36
			'Umwandeln###########
			Local tmpWert:String = WechselZahlenSystem(Wert, VonZS, NachZS)
			
			'Überprüfen###########
			tmpReturn = tmpWert
			For Local i:Int = 1 To Len(tmpWert)
				Local ichanged:Int = Len(tmpWert) - i
				If Mid(tmpWert, i, 1) <> Mid(tmpWert, ichanged + 1, 1)
					tmpReturn = 0
					Exit
				EndIf
			Next
			
			'Falls Richtig dann zurückgeben###########
			If tmpReturn <> 0
				Return[Int(tmpReturn), VonZS, NachZS]
			EndIf
		Next
	Next
End Function

Function WechselZahlenSystem:String(Wert1:String, ZahlSys1:Double, ZahlSys2:Double)
	Local Wert10Sys:Double
	
	For Local i:Int=0 To Len(Wert1)-1
		Local Vari:String = Mid(Wert1, Len(Wert1) - i, 1)
		If Int(Vari)>=ZahlSys1 Then RuntimeError "Angegebener Wert wurde nicht im "+ZahlSys1+"er System angegeben"
		Wert10Sys = Wert10Sys + Int(Vari) * ZahlSys1 ^ i
	Next
	
	Local tmpMaxHoch:Int
	Repeat
		If Wert10Sys/ZahlSys2^tmpMaxHoch<1 Then Exit
		
		tmpMaxHoch=tmpMaxHoch+1
	Forever
	
	Local tmpRest:Double = Wert10Sys
	Local tmpResult:String
	
	
	For Local i:Int = 1 To tmpMaxHoch
		Local ichanged:Double = tmpMaxHoch - i
		If ichanged = 0 Then
			tmpResult = tmpResult + IntOrAlphabet(tmpRest)
			Exit
		EndIf
		
		tmpResult = tmpResult + IntOrAlphabet((tmpRest / ZahlSys2 ^ ichanged))
		
		tmpRest = tmpRest Mod ZahlSys2 ^ ichanged
	Next
	
	Return tmpResult
End Function

Function IntOrAlphabet:String(Vari:Int)
	Vari = Int(Vari)
	If Vari > 9
		Vari:-10
		Vari = Vari + 65
		Return Chr(Vari)
	End If
	Return Vari
End Function