SuperStrict
Graphics 800,600

Global FensterBreite#=600, BildBreite#=900, ScrollPosX#=0
Global ScrollBarFaktor#=FensterBreite/BildBreite
Global FPS:TTimer=CreateTimer(60)
Repeat
	SetClsColor 0,0,255
	SetColor 255,255,255
	Cls
		DrawRect 100,100,FensterBreite,300
		SetColor 111,111,111
		DrawRect 100,100,FensterBreite,15
		SetColor 55,55,55
		DrawRect 100+ScrollPosX,100,FensterBreite*ScrollbarFaktor,15
		SetColor 255,0,0
		DrawRect 100-ScrollPosX/ScrollbarFaktor,150,BildBreite,20
		If MouseDown(1)
			Local localX#=MouseX()-100
			If (localX>=0) And (localX<=(1-ScrollbarFaktor)*FensterBreite)
				ScrollPosX=LocalX
			EndIf
		EndIf
	Flip 0
	WaitTimer FPS
Until KeyHit(Key_Escape)

SuperStrict
Graphics 800,600

Global FensterBreite#=500, BildBreite#=1000, ScrollPosX#=0

' nun mal so Rahmen ungleich Fenster
Global RahmenBreite#=300
Global SizeFaktor#=FensterBreite/RahmenBreite

Global ScrollBarFaktor#=FensterBreite/BildBreite
Global FPS:TTimer=CreateTimer(60)
Repeat
	SetClsColor 0,0,255
	Cls
		' das Fenster in weiß:
		SetColor 255,255,255
		DrawRect 100,100,FensterBreite,300
		
		' der Slider-Rahmen in grau
		SetColor 111,111,111
		DrawRect 100,100,RahmenBreite,15

		' der Slider in dunkelgrau:
		SetColor 55,55,55
		DrawRect 100+ScrollPosX,100,RahmenBreite*ScrollbarFaktor,15
		
		' das Bild in rot
		SetColor 255,0,0
		DrawRect 100-ScrollPosX/ScrollbarFaktor*SizeFaktor,150,BildBreite,20



		If MouseDown(1)
			Local localX#=MouseX()-100
			If (localX>=0) And (localX<=(1-ScrollbarFaktor)*RahmenBreite)
				ScrollPosX=LocalX
			EndIf
		EndIf
	Flip 0
	WaitTimer FPS
Until KeyHit(Key_Escape)

SuperStrict

Const WINDOW_SIZE_X:Int = 1024
Const WINDOW_SIZE_Y:Int = 768


Type TSlider

	'goodie: "Fensterposition" um diese in die DrawBerechnung mit einfließen zu lassen :)
	Field WindowPosX:Int = 50
	Field WindowPosY:Int = 50
	Field WindowSizeX:Int = 0
	Field WindowSizeY:Int = 0
	
	Field ContentWidth:Int = 0

	'Nötiges, um die berechnugnen durchzuführen:
	Field sizeX:Int = 0
	Field sizeY:Int = 0
	Field pinSizeX:Int = 0
	Field pinSizeY:Int = 0

	'Internes: _pos als momentane sliderposition	
	Field _pos:Double = 0.0
	'Internes: _active, um festzustellen, ob überhaupt etwas "scrollbares" dargestellt werden muss.
	Field _active:Int = 1
	
	Function Create:TSlider(fensterBreite:Int, inhaltBreite:Int, fensterHoehe:Int)
		'Fensterbreite bezieht sich auf den Sichtbaren bereich, dein Viewport.
		'inhaltBreite bezieht sich auf das totale ganze.
		
		Local slider:TSlider = New TSlider
		slider.WindowSizeX = fensterBreite
		slider.WindowSizeY = fensterHoehe
		
		slider.ContentWidth = inhaltBreite
		
		slider.sizeX = fensterBreite
		slider.sizeY = 30
		
		If inhaltBreite = 0 Or (fensterBreite >= inhaltBreite) Then
			slider._active = 0
		Else
			slider._active = 1
			slider.pinSizeX = slider.sizeX * (Double(fensterBreite) / Double(inhaltBreite))
			slider.pinSizeY = slider.sizeY
		EndIf
		
		Return slider
	End Function
	
	Method SetTotalPosition:Int(pos:Int)
		If pos < 0 Then pos = 0
		If pos > sizeX Then pos = sizeX
	
		_pos = Double(pos) / Double(sizeX) 'Warnung: Stellt nicht den startpunkt des sliders dar, sondern den umgerechneten punkt auf dem Scrollbalken :)
	End Method
	Method SetPosition:Int(pos:Double)
		If pos < 0 Then pos = 0
		If pos > 1 Then pos = 1
		_pos = pos
	End Method
	Method GetPosition:Double()
		Return _pos
	End Method
	Method GetTotalPosition:Int()
		Return _pos * sizeX ' Warnung: Stellt nicht den startpunkt des sliders dar, sondern den umgerechneten punkt auf dem Scrollbalken :)
	End Method
	
	Method doStep:Int(px:Int)
		'doStep ist eine hilfsfunktion, der man pixel-einheiten einer bewegung am slider übergibt. Zb Von MouseXSpeed(). Sie rechnet den pixelwert in die eigentliche Position.
		Local fak:Double = Double(px) / Double(sizeX - pinSizeX)
		_pos:+fak
		
		'Clamping: Verhindern, das der slider seinen rahmen sprengt :)
		If _pos > 1 Then _pos = 1
		If _pos < 0 Then _pos = 0
	EndMethod
	
	Method calcPosition:Double(x:Int)
		'x steht für die gewünschte mitte des sliders. Typischerweise für MouseX()-self.windowPosX zu verwenden :) 
		Return (Double(x - (pinSizeX * 0.5)) / Double(sizeX - pinsizex))
	End Method
	
	Method calcTotalPosition:Int(x:Int)
		'x steht für die gewünschte mitte des sliders. 
		Return (Double(x - (pinSizeX * 0.5)) / Double(sizeX - pinsizex)) * sizeX
	End Method
	
	Method Resize:Int(fensterBreite:Int, inhaltBreite:Int, fensterHoehe:Int)
		WindowSizeX = fensterBreite
		WindowSizeY = fensterHoehe
		
		ContentWidth = inhaltBreite
	
		sizeX = fensterBreite
		sizeY = 30
		
		If inhaltBreite = 0 Or (fensterBreite >= inhaltBreite) Then
			_active = 0
		Else
			_active = 1
			pinSizeX = sizeX * (Double(fensterBreite) / Double(inhaltBreite))
			pinSizeY = sizeY
		EndIf
	End Method
	
	
	Method Draw:Int()
		Local x:Int = windowPosX 'faulheit: Da ich diese beiden variablen nur zum nachvollziehen mit einbaue, kürze ich sie hier mit x und y ab.
		Local y:Int = windowPosY
	
		'------ Scrollbalken part
		
		If _active Then
			'slider hat was zu tun: Zeichnen.
			SetColor(150, 150, 150)
			
			'Den Hintergrund, sprich der slider an sich :)
			DrawRect(x, y + WindowSizeY - pinSizeY, sizeX, sizeY) 'ACHTUNG: Hier habe ich von der höhe pinSizeY abgezogen, damit der slider noch innerhalb des "Fensters" liegt
			
			
			SetColor(255, 255, 255)
			
			'Den Anfasser, den ich generell überall als Pin bezeichne			
			DrawRect(x + (WindowSizeX - pinSizeX) * Self.GetPosition(), y + WindowSizeY - pinSizeY, pinSizeX, pinSizeY) 'ACHTUNG: Hier habe ich ebenfalls pinSizeY der höhe abgezogen.
			
		EndIf
		
		'"rahmen" zeichnen. -> Für das Gedachte fenster drumrum.
		SetColor(255, 230, 230)
		DrawLine(x, y, WindowSizeX + x, y)
		DrawLine(WindowSizeX + x, y, WindowSizeX + x, WindowSizeY + y)
		DrawLine(WindowSizeX + x, WindowSizeY + y, x, WindowSizeY + y)
		DrawLine(x, WindowSizeY + y, x, y)
		SetColor(255, 0, 0)
		
		'"inhalt" zeichnen. -> Um den Scrolleffekt sichtbar zu machen. Achte auf SetViewport und SetOrigin - diese befehle sind nur die faulste methode die mir eingefallen sind.
		' In wirklichkeit kannst du alles mit dem Self.GetPosition() wert anfangen, was du magst :)
		SetViewport(x, y, WindowSizeX, WindowSizeY)
		SetOrigin(-Self.GetPosition() * (ContentWidth - WindowSizeX), 0)
		
		'Der eigentliche inhalt: eine Diagonale linie, um den scrolleffekt sichtbar zu machen.
		DrawLine(x, y, ContentWidth + x, WindowSizeY + y - pinSizeY) 'ACHTUNG: Ums korrekt darzustellen, hab ich hier pinSizeY abgezogen *g* Der Platz des sliders eben.
		
		'Wieder aufräumen:
		SetViewport(0, 0, WINDOW_SIZE_X, WINDOW_SIZE_Y)
		SetOrigin(0, 0)
		
		SetColor(255, 255, 255)

	End Method
	
	
	'Steuerung:
	Method isPointInside:Int(x:Int, y:Int)
		
		Local sliderSX:Int = WindowPosX + (WindowSizeX - pinSizeX) * Self.GetPosition()
		Local sliderSY:Int = WindowPosy + WindowSizeY - pinsizeY
				
	
		
		'Soll prüfen, ob ein punkt innerhalb des sliders ist und ob dieser eventuell sogar auf dem pin sitzt.
		If x < WindowPosX Or y < WindowPosY Or x > WindowPosX + WindowSizeX Or y > WindowPosY + WindowSizeY Then
			Return 0 ' ganz und gar ausserhalb des fensters.
		EndIf
		If y < sliderSY Then
			Return 0 ' oberhalb des sliders? schlecht.
		EndIf
		If x >= sliderSX And x <= sliderSX + pinSizeX And y >= sliderSY And y <= sliderSY + pinSizeY Then
			Return 2 'auf dem slider`- pin
		EndIf
		
		Return 1 ' nur irgendwo auf dem slider
	End Method
End Type




Graphics(WINDOW_SIZE_X, WINDOW_SIZE_Y)

Local winWidth:Int = 500
Local contentWidth:Int = 2000


Local slider:TSlider = TSlider.Create(winWidth, contentWidth, 500)

While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()

	Select slider.isPointInside(MouseX(), MouseY())
		Case 0 ' nix..
		Case 1 ' auf dem slider: Punkt umrechnen und Totale Position setzen.
			If MouseHit(1) Then
				slider.SetPosition(slider.calcPosition(MouseX() - slider.WindowPosX))
				FlushMouse()
			EndIf
		Case 2 ' auf dem slider-pin: MouseXSpeed() übertragen.
			If MouseDown(1) Then slider.doStep(MouseXSpeed())
	End Select
	
	MouseXSpeed() 'aufrufen, um wert "frisch" zu halten

	Cls
	
	slider.Draw()
	
	contentWidth:+(KeyDown(KEY_D) - KeyDown(KEY_A)) * 5
	slider.Resize(winWidth, contentWidth, 500)
	
	Flip 1
Wend

'Abfrage, ob maus auf dem slider ist. Returnt 0, wenn nicht, 1 wenn die maus NUR auf dem Slider ist und 2, wenn die maus auf dem Slider-Pin (Anfasser) ist.
Select slider.isPointInside(MouseX(), MouseY())

'Updatet den Slider. Braucht Fensterbreite, Inhaltbreite (um die breite des Sliders zu berechnen), sowie die fensterhöhe (nur für zeichnung intressant. Musste ich mit reinnehmen :3
	slider.Resize(winWidth, contentWidth, 500)

'doStep ist mit Translate aus 3d engines zu vergleichen. es nimmt zb -1 oder 1 als wert. Der wert entspricht (je nach gleitzahlen ungenauigkeit) etwa einer anzahl pixeln ( wert: -1 = ungefähr -1 pixel bewegung auf den slider)
slider.doStep(MouseXSpeed())

'Berechnet den nötigen pos-wert, um den Slider mittig zu platzieren. 
'ACHTUNG: Da der Slider das fenster eigentlich nicht umbedingt kennen sollte, muss man hier die fensterposition von der Mausposition zb abziehen :) Das hardcoded zu übernehmen ist einfach dreckig.. :3
slider.calcPosition(MouseX() - slider.WindowPosX)