z1\objekt = CreateMesh()
         If z1\Zellart= 1 Then brushtouse = brushtexturevorhoflinks
         If z1\Zellart= 6 Then brushtouse = brushtexturevorhofrechts
               
         z1\surface = CreateSurface(z1\objekt, brushtouse )
         z1\v0 = AddVertex(z1\surface, 0, 0, 0)
         z1\v1 = AddVertex(z1\surface, 1, 0, -1)
         z1\v2 = AddVertex(z1\surface, -1, 0, -1)

         z1\v02 = AddVertex(z1\surface, -1, 0, -1)
         z1\v12 = AddVertex(z1\surface, 1, 0, -1)
         z1\v22 = AddVertex(z1\surface, 0, 0, -2)          
         
         AddTriangle(z1\surface, z1\v0, z1\v1, z1\v2)
         AddTriangle(z1\surface, z1\v02, z1\v12, z1\v22)
                  
         z1\objekt2 = CopyMesh( z1\objekt, z1\objekt)         
         FlipMesh z1\objekt2
   
         UpdateNormals z1\objekt
         UpdateNormals z1\objekt2
         
         PositionEntity z1\objekt, Readx#*faktor, Ready#*faktor, Readz#*faktor
         ScaleEntity z1\objekt, faktor2, faktor2*faktory, faktor2

; SingleSurface engine by PSY
; Made Feb 2013
; http://psy-labs.com


; Aufloesung spielt fuer die SingleSurface Engine speedtechnisch ueberhaupt keine Rolle!
Graphics3D 1024,768,32,1
SetBuffer BackBuffer()

SeedRnd MilliSecs()

Global FPS_frames% ,FPS_fps% ,FPS_timer%, bMode%=0, wFrame%=0, cycle%=0, updateInterval%=10
Global pivot%, cam%, tex%, ghostmesh%, ghostsurface%
Local angle#=240.0 ; Init-Wert fuer Cam-Fahrt

; 4 Meshes und 4 Surfaces erstellen
; Auf jedem Mesh koennen eine bestimmte Anzahl Tris untergebracht werden
; Damit es auf aelteren/billigeren Grakas laeuft, sollte man 16k Tris pro Mesh nicht ueberschreiten.
; Bei neueren sind 32k Tris pro Mesh kein Thema
; Gesamtzahl der Tris(auf mehrere Meshes verteilt) wird letztendlich nur durch Grafikkartenpower bestimmt
Dim mesh%(3)
Dim surface%(3)

; Hier werden die einzelnen 3D Punkte gespeichert
Type TQuad
   Field x#, y#, z#   ; Position
   Field r%, g%, b%   ; Farben
   Field rotation#      ; Rotation (kannste auch rausnehmen, musst sehn was besser aussieht)
End Type

Global quad.TQuad


Init()          ; CAM / MESHES / SURFACES erstellen
LoadData3D()   ; Herzdaten laden und in den Type uebertragen







Repeat
   
   ; Die 3 Zeilen hier sind fuer die Kamerafahrt. Camera hat Pivot als Parent. Dient alles nur der Optik
   angle = (angle + .5 ) Mod 360
   PositionEntity cam, 0, 0, -200+100*Sin(angle)
   TurnEntity pivot, .2, .2, .2, 1
   
   Keys()          ; Usereingaben abfragen
   SingleSurface() ; SINGLE SURFACE ENGINE
   RenderWorld()
   
   Text 0, 00, "FPS:  " + fps()   
   Text 0, 20, "Tris: " + TrisRendered()
   Text 0, 40, "RETURN - Toggle WireFrame: " + wFrame
   Text 0, 60, "SPACE - Toggle Blendmode:  " + bMode
   Text 0, 80, "',' and '.' to toggle heart update interval:  " + updateInterval
   
   
   Flip 0
   
Until KeyHit(1)
End















; SINGLE SURFACE ENGINE
; FUNKTIONSWEISE:
; ---------------------
; 0. Alle Surfaces werden geloescht
; 1. Alle Types werden durchlaufen
; 2. Der GHOSTMESH wird an den jeweiligen Type-Koordinaten positioniert
; 3. Der GHOSTMESH wird per PointEntity auf die CAM ausgerichtet (und gedreht)
; 4. Die 3(bei Tris) oder 4(bei Quads) Vertexpunkte des GHOSTMESH werden per TFormPoint global bestimmt
; 5. Die bei Punkt 4 bestimmten Vertexpunkte werden nun per AddVertex auf das passende Surface der SingleSurface-Meshs uebertragen
; 6. Sie bekommen per Vertexcolor ihre Farbe zugewiesen
; 7. Zum Schluss werden mit AddTriangle die Vertexpunkte zu Tris verbunden
Function SingleSurface()
   Local x#, y#, z#, v%, surf%, c%=-1, i%
   
   ; TRICK: Die ganzen Types muessen nicht bei jedem Loop durchlaufen werde, das ist total unnoetig und kostet Unmengen an Rechenzeit
   ; Stattdessen wird einfach nur jeder x.te Cycle durchlaufen (x = Updateinterval)
   ; Damit kannst Du die FPS MASSIV steigern
   cycle = cycle + 1 : If cycle < updateInterval Then Return
   cycle = 0
   
   ; Alle 4 Surfaces loeschen
   For i=0 To 3
      ClearSurface surface(i), 1, 1
   Next
   
   For quad.TQuad = Each TQuad
      
      ; Diese beiden Zeilen sorgen einfach dafuer, dass per MOD die 3D Punkte auf die 4 Meshs/Surfaces verteilt werden
      c = c + 1
      i = c Mod 4
      
      PositionEntity ghostmesh, quad\x, quad\y, quad\z, 1 ; Ghostmesh an Typekoordinaten positionieren
      PointEntity ghostmesh, cam, quad\rotation         ; Ghostmesh auf Cam ausrichten (und drehen falls gewuenscht)
      
      ; Hier werden die 3(bei Tris) oder 4(bei Quads) Vertexpunkte des Ghostmesh global bestimmt und auf die Single Surface Meshs uebertragen
      TFormPoint VertexX(ghostsurface,0), VertexY(ghostsurface,0), VertexZ(ghostsurface,0), ghostmesh, 0
      x = TFormedX()
      y = TFormedY()
      z = TFormedZ()
      v = AddVertex (surface(i),x,y,z,0,0) ; Einmal den Vertexindex LINKS OBEN merken, braucht man fuer Vertexcolor und AddTriangle weiter unten
      TFormPoint VertexX(ghostsurface,1), VertexY(ghostsurface,1), VertexZ(ghostsurface,1), ghostmesh, 0
      x = TFormedX()
      y = TFormedY()
      z = TFormedZ()
      AddVertex  surface(i),x,y,z,1,0
      TFormPoint VertexX(ghostsurface,2), VertexY(ghostsurface,2), VertexZ(ghostsurface,2), ghostmesh, 0
      x = TFormedX()
      y = TFormedY()
      z = TFormedZ()
      AddVertex  surface(i),x,y,z,0,1
      TFormPoint VertexX(ghostsurface,3), VertexY(ghostsurface,3), VertexZ(ghostsurface,3), ghostmesh, 0    ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      x = TFormedX()                                                                  ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      y = TFormedY()                                                                  ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      z = TFormedZ()                                                                  ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      AddVertex  surface(i),x,y,z,1,1                                                      ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      
      ; Farbe des Vertexpunkte setzen
      VertexColor surface(i), v  , quad\r, quad\g, quad\b, 1
      VertexColor surface(i), v+1, quad\r, quad\g, quad\b, 1
      VertexColor surface(i), v+2, quad\r, quad\g, quad\b, 1
      VertexColor surface(i), v+3, quad\r, quad\g, quad\b, 1                                    ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      
      ; Punkte zu Dreiecken oder Quads (2 Dreiecke) verbinden
      AddTriangle surface(i), v  , v+1, v+2
      AddTriangle surface(i), v+1, v+3, v+2                                                ; weglassen wenn statt Quads nur Tris verwendet werden sollen
      
   Next
   
End Function




; Hier werden einfach nur Tastatureingaben abgefragt
Function Keys()
   Local i%
   
   ; Blendmodus 1(normal) oder 3(addieren)
   If KeyHit(57)
      bMode = 1 - bMode
      For i=0 To 3
         EntityBlend mesh(i), bMode*3
      Next
   EndIf
   
   If KeyHit(28) Then wFrame = 1 - wFrame : WireFrame wFrame ; Wireframe an/aus
   
   ; Hier wird ueber ',' und '.' das Updateintervall erhoeht bzw. verringert
   If KeyHit(52) Then updateInterval = updateInterval+1
   If KeyHit(51) And updateInterval>1 Then updateInterval = updateInterval-1
   
End Function




; Hier wird das SingleSurface System initialisiert
; Jeder Mesh bekommt dabei die gleiche Textur zugewiesen
; ALPHA IST DEAKTIVIERT, ANSONSTEN KOMMT ES ZU Z-BUFFER FEHLERN
; GENAUERES IN DER HILFE ZUM BEFEHL 'LOADTEXTURE'
Function Init()
   Local i%
   
   pivot   = CreatePivot()                  ; Nur fuer die Camfahrt
   cam    = CreateCamera(pivot)            ; Nur fuer die Camfahrt
   tex    = LoadTexture ("tex.png",4)
   
   For i=0 To 3
      mesh(i)      = CreateMesh()
      surface(i)    = CreateSurface(mesh(i))
      EntityBlend    mesh(i), 1            ; Normaler Blendmodus bei Start
      EntityFX       mesh(i), 1+2+4+8+16      ; leuchtend, Vertexfarbe, flache Schattierung, ohne Nebel, kein Backface culling. ALPHA NICHT AKTIVIEREN, SONST Z-BUFFER FEHLER
      EntityTexture   mesh(i), tex         ; Mesh mit Textur ueberziehen
   Next
   
   ghostmesh%       = CreateMesh()            ; Unser Geheimtrick, der Ghostmesh ;)
   ghostsurface%    = CreateSurface(ghostmesh)
   HideEntity  ghostmesh                  ; Verstecken das Teil, braucht man nicht zu sehn...
   
   AddVertex   ghostsurface, -1,  1, 0         ; QUAD (oder TRI) erstellen. Diese 3(4) Vertexpunkte werden wir nachher bestimmen und auf die SingleSurface Meshs uebertragen
   AddVertex   ghostsurface,  1,  1, 0
   AddVertex   ghostsurface, -1, -1, 0
   AddVertex   ghostsurface,  1, -1, 0       ; weglassen wenn statt Quads nur Tris verwendet werden sollen
   
End Function




; Hier werden Deine Herzdaten geladen...
Function LoadData3D()
   
   Local file%, plane%, cell%, mp%
   
   file% = OpenFile("Herzdata53.txt")
   While Not Eof(file)
      
      plane         = Int(ReadLine$(file))
      cell         = Int(ReadLine$(file))
      
      quad.TQuad       = New TQuad
      quad\x          = Int(ReadLine$(file))
      quad\y          = Int(ReadLine$(file))
      quad\z          = Int(ReadLine$(file))
      quad\rotation    = Rnd(359.0)
      
      mp            = Int(ReadLine$(file))
      
      ; Verschiedene Farben setzen. Hab hier einfach Farben vergeben. Musste fuer Deine Zwecke anpassen ^^
      Select cell
         Case 1 quad\r = 255 : quad\g = 255 : quad\b = 255
         Case 2 quad\r = 255 : quad\g = 000 : quad\b = 000
         Case 3 quad\r = 000 : quad\g = 255 : quad\b = 000
         Case 4 quad\r = 000 : quad\g = 000 : quad\b = 255
         Case 5 quad\r = 255 : quad\g = 255 : quad\b = 000
         Case 6 quad\r = 000 : quad\g = 255 : quad\b = 255
         Case 7 quad\r = 255 : quad\g = 000 : quad\b = 255
         Case 8 quad\r = 050 : quad\g = 150 : quad\b = 250
      End Select
      
   Wend
   CloseFile (file)
   
End Function




; Bloss die FPS...
Function fps ()
   FPS_frames = FPS_frames + 1
   If FPS_timer + 1000 < MilliSecs()
      FPS_fps    = FPS_frames
      FPS_frames    = 0
      FPS_timer    = MilliSecs()
   EndIf
   Return(FPS_fps)
   
End Function