;######################################
;
;   TImage einfach einfügen im prog
;
;######################################
Global ImageToDraw%
Type TImage
   Field Img
   Field Width#,Height#,Url$,Count%,Size#,Exist%
End Type

Function ImageLoad.TImage (Url$,Width%=-1,Height%=-1,Count%=0)
   Local Img.TImage=New TImage
   Img\Width=Width
   Img\Height=Height
   Img\Count=Count
   Img\Url=Url
   Img\Size=FileSize(Url)
   If Img\Size>0 Then Img\Exist=1
   Return Img   
End Function

Function ImageExist(Image.TImage)
   If Image\Exist=1
      If Image\Img=False Then GetImage (Image)
      Return Image\Exist
   EndIf
   Return 0
End Function

Function GetImage(Image.TImage)
   If Image\Exist=1
      If Image\Img=False Then
         If Image\Width=-1 And Image\Height=-1 And Image\Count=0 Then
            Image\Img=LoadImage(Image\Url)
         Else
            Image\Img=LoadAnimImage(Image\Url,Image\Width,Image\Height,0,Image\Count)
         EndIf
      EndIf
   EndIf
End Function

Function ImageDraw(Image.TImage,X%,Y%,Tile%=0,DisableCheckSum%=0)
   If ImageExist(Image)=1 Then
      If DisableCheckSum=1 Or X>-1 And Y>-1 And X+ImageWidth(Image\Img) < GraphicsWidth() + 1 And Y+ImageHeight(Image\Img) < GraphicsHeight() + 1 Then
         DrawImage (Image\Img,X,Y,Tile)
         ImageToDraw=ImageToDraw+1
      Endif
   EndIf
End Function

Function ImageScale(Image.TImage,Width%,Height%)
   If ImageExist(Image)=1 Then
      ResizeImage Image\Img,Width,Height
   EndIf
End Function

Function GetDrawImage%()
   Local A%=ImageToDraw
   ImageToDraw=0
   Return A
End Function

Function ImageW%(Image.TImage)
   If ImageExist(Image)=1 Then
      Return ImageWidth(Image\Img)
   EndIf
End Function

Function ImageH%(Image.TImage)
   If ImageExist(Image)=1 Then
      Return ImageHeight(Image\Img)
   EndIf
End Function

Graphics 800,600,32,2
Local BG.TImage= ImageLoad ("Space.jpg")
ImageScale(BG, 800,600)
Local Maus.TImage=ImageLoad("Maus.png")

Repeat
   ImageDraw BG,0,0

   ImageDraw Maus,MouseX(),MouseY()
   Flip
   Cls
Until KeyDown(1)