Function CenterMesh(Entity,cx,cy,cz)

 ;MR 08.01.2003

 ;Center a Mesh
 ; on X If cx=True
 ; on Y If cy=True
 ; on Z If cz=True

 If Entity=0 Then Return 0

 ;----------------------------------- Find Mesh Min Max XYZ

 Local mx1#= 3.4*10^38,my1#= 3.4*10^38,mz1#= 3.4*10^38
 Local mx2#=-3.4*10^38,my2#=-3.4*10^38,mz2#=-3.4*10^38
 Local i,vi,s
 Local check=False

 If CountSurfaces(Entity)>0 Then
  For i=1 To CountSurfaces(Entity)
   s=GetSurface(Entity,i)
   If CountVertices(s)=>1 Then
    For vi = 0 To CountVertices(s)-1
     If VertexX(s,vi)<mx1 Then mx1=VertexX(s,vi)
     If VertexY(s,vi)<my1 Then my1=VertexY(s,vi)
     If VertexZ(s,vi)<mz1 Then mz1=VertexZ(s,vi)
     If VertexX(s,vi)>mx2 Then mx2=VertexX(s,vi)
     If VertexY(s,vi)>my2 Then my2=VertexY(s,vi)
     If VertexZ(s,vi)>mz2 Then mz2=VertexZ(s,vi)
     check=True
    Next
   EndIf ;Count Vert
  Next
 EndIf ;Count Surf

 If check=False Then Return 0

 ;-----------------------------------

 Local mw#,mh#,md#,xp#,yp#,zp#

 mw# = Abs(mx2-mx1)
 mh# = Abs(my2-my1)
 md# = Abs(mz2-mz1)

 If CountSurfaces(Entity)>0 Then
  For i=1 To CountSurfaces(Entity)
   s=GetSurface(Entity,i)
   If CountVertices(s)=>1 Then
    For vi = 0 To CountVertices(s)-1
     xp#=VertexX(s,vi)
     yp#=VertexY(s,vi)
     zp#=VertexZ(s,vi)
     If cx<>0 Then xp#=xp#-mx1-mw#/2
     If cy<>0 Then yp#=yp#-my1-mh#/2
     If cz<>0 Then zp#=zp#-mz1-md#/2
     VertexCoords s,vi,xp#,yp#,zp#
    Next
   EndIf ;Count Vert
  Next
 EndIf ;Count Surf

 Return True
 
End Function