;-----------------------------------------------------------------------------------------------------
; Abranoix - Published under the terms of the GNU (Gnu's not Unix) GPL (General Public License)
; (C) 2003 -2004 By Paul Anselm Härle
;-----------------------------------------------------------------------------------------------------

AppTitle "|Abranoix|" ; Der Title des Fensters.
Graphics 740, 530, 16, 2 ; Grafik-Modus.
SetBuffer BackBuffer() ; Wir verwenden Doublebuffering.
FPS = CreateTimer(60) ; Frames Per Sekunde.

;#####################################################################################################
;------------------------------------Pre-Hauptschleife------------------------------------------------
;#####################################################################################################

;----------------------------------------Dim-Felder---------------------------------------------------

Dim Map(21,16) ; Das Karten-Dim-Feld.

;------------------------------------Globale Variablen------------------------------------------------

Global P_X = 3; X-Koordinate des Players.
Global P_Y = 8 ; Y-Koordinate des Players.
Global P_Direc = 3 ; Die Richtung (Direction) des Players.
Global P_Anim# = 0 ; Der Frame der Player-Animation
Global Modus$ = "Menü" ; Der Modus in dem sich das Programm gerade befindet. (default = Menü)
Global FileLoad$ ; Die zuladende Karte.

;-------------------------------------------Bilder----------------------------------------------------

Global Cursor = LoadImage("Graphics\Cursor.bmp") ; Die Cursor-Grafik (wird unten transparent gemacht).
Global Button_Dark = LoadImage("Graphics\Button_Dark.bmp") ; Der Button wenn er inaktiv ist.
Global Button_Light = LoadImage("Graphics\Button_Light.bmp") ; Der aktive Button.
Global MessageBox = LoadImage("Graphics\MessageBox.bmp") ; Die Nachrichten-Box.
Global MenueBox = LoadImage("Graphics\MenueBox.png") ; Die Box in der das Menü ist.
Global Loader = LoadImage("Graphics\Loader.png") ; Der Wunderschöne Loader (mit GIMP gemacht).
Global Tileset = LoadAnimImage("Graphics\Tileset.bmp", 32, 32, 0, 21) ; Das Tileset der Karte.
Global P_Image = LoadAnimImage("Graphics\Char.bmp", 32, 32, 0, 12) ; Der Charakter mit Animation,...

;----------------------------------------Transparenz--------------------------------------------------

MaskImage P_Image, 255, 0, 255 ; Damit Rosa Transparent wird.
MaskImage Cursor, 255, 0, 255 ; Damit Rosa Transparent wird.
MaskImage MenueBox, 255, 0, 255 ; Damit Schwarz NICHT Transparent wird.

;-----------------------------------------Schriften---------------------------------------------------

Global Blitz18 = LoadFont("Blitz.fon", 18) ; Die Blitz-Editor-Schrift.

;------------------------------------------Includes---------------------------------------------------

Include "Funktionen.bb" ; Ich habe die meisten Functionen ausgelagert damit dieser Quellcode klein und
                  ; übersichtlich bleibt.
;-------------------------------------Initialisierungen-----------------------------------------------

SetFont Blitz18 ; Setzt die Schriftart auf Blitz18 (s.o.).
Color 255, 200, 0 ; Setzt die Schriftfarbe auf Dunkelgelb.

;#####################################################################################################
;---------------------------------------Hauptschleife-------------------------------------------------
;#####################################################################################################

While 1 = 1 ; Solange NICHT Escape (auf M$-Tastaturen die abgenutzte Taste) gedrückt wird.
WaitTimer(FPS) ; Damit unsere Kleine Framebremse auch wirklich eingehalten wird.
HidePointer ; Versteckt den billigen M$-Mauszeiger.

;---------------------------------------Menue-Modus---------------------------------------------------
   
   If Modus$ = "Menü" ; Wenn der Modus "Menü" ist....
      Origin 50, 25 ; Dann verschiebe den Ursprung auf (50/25) denn sonst ist das bild zu klein.
      DrawImage Loader, 0, 0 ; Und male dann den Cursor.
      NeuesSpielButton = Button(320, 200, "Neues Spiel") ; Erstellt den "Neues Spiel Button.
      If NeuesSpielButton = True Then ; Und wenn dieser gedrückt wird, dann...
         FileLoad$ = "Maps\Map1.abrmap" ; Lade diese Karte...
         LoadMap() ; ...Öffne sie...
         Modus$ = "Spiel" ; ...und setze den Modus auf "Spiel".
      EndIf ; So, diese If-Bedingung wäre hiermit zuende.
      LadeSpielButton = Button(320, 238, "Laden") ; Erstellt den "Laden"-Button.
      If LadeSpielButton = True Then LadeSpiel() ; und wenn dieser gedrückt wird, dann lädt er. ;)
      SpeicherSpielButton = Button(320, 276, "Speichern") ; Speicherbutton.
      If SpeicherSpielButton = True Then SpeicherSpiel() ; wenn gedürckt ; speichern.
      BeendeSpielButton = Button(320, 314, "Beenden") ; Beendenbutton.
      If BeendeSpielButton = True Then End ; Wenn gercükt dann Beenden.
      
      DrawImage Cursor, MouseX(), MouseY()
   EndIf
   
;-------------------------------------Spiel-Modus-----------------------------------------------------
   
   If Modus$ = "Spiel"
      Origin 0, 0
      Move()
      DrawMap()   
      DrawImage P_Image, P_X*32-32, P_Y*32-32, P_Direc + P_Anim
      DrawImage MessageBox, 0, 480
      DrawImage MenueBox, 640, 0
      MenueButton = Button(691, 68, "Menue")
      If MenueButton = True Then Modus$ = "Menü"
      If KeyDown(1)  = True Then Modus$ = "Menü"
      P_Anim# = P_Anim# + 1
      If P_Anim >= 3 Then P_Anim# = 0
      If MouseX() > 640 DrawImage Cursor, MouseX(), MouseY()
   EndIf
Flip
Cls
Wend

;-----------------------------------"befreien"-und-Ende-----------------------------------------------

FreeTimer FPS
FreeFont Blitz18
End