// Test.cof
// Beispiel von M.Rauch
// In Cinema 4D (CE6) unter Menü/Fenster/Console öffnen
// Dann in Console Plug-ins erneut laden
// Plug-in ausführen
// Achtung , diese Coffee scheiße achtet auf Groß/kleinschreibung
// also nicht in dem BlitzBasic oder sonnstige Editoren öffnen die
// dan Anfangsbuchstaben groß schreiben ! *GRRR*
// Und an die bekloppten Semikolons denken !

// sollte eine unique ID sein , bekommt man bei www.plugincafe.com
var PLUGIN_ID = 910003;

// Meine Dialog Klasse

var mydoc;
var vec;

class MyDialog : GeModalDialog
{
   public:
      MyDialog();
      CreateLayout();
      Init();
      Command(id,msg);
                ObjektBewegen(doc);
      SpeichernAls(doc);
}

MyDialog::MyDialog() { super(); }

MyDialog::CreateLayout()
{
     
  //Hier werden die Knöppe und Textboxen erzeugt

   SetTitle("Mein erster Dialog in C4D");

   AddStaticText(3000,BFH_FIT,0,0,"Position",BORDER_THIN_IN);

   AddGroupBeginV(10000,0, 2, "Position", 0);
   AddGroupSpace(4, 4);
   AddGroupBorderSpace(4, 4, 4, 4);

   AddStaticText(3001,BFH_FIT,50,0,"X",BORDER_THIN_IN);
   AddEditNumber(4001,BFH_FIT,100,0);       

   AddStaticText(3002,BFH_FIT,50,0,"Y",BORDER_THIN_IN);
   AddEditNumber(4002,BFH_FIT,100,0);       

   AddStaticText(3003,BFH_FIT,50,0,"Z",BORDER_THIN_IN);
   AddEditNumber(4003,BFH_FIT,100,0);       

   AddGroupEnd();

   AddButton(5001, BFH_FIT,0,0,"Bewegen");

   AddButton(5002, BFH_FIT,0,0,"Speichern als ...");

   AddDlgGroup(DR_DLGGROUP_OK|DR_DLGGROUP_CANCEL);
       
   return TRUE;
}

MyDialog::Init()
{
 SetFloat(4001,vec.x,-10000,10000,1);
 SetFloat(4002,vec.y,-10000,10000,1);
 SetFloat(4003,vec.z,-10000,10000,1);
}

MyDialog::Command(id,msg)
{

 println("id=",id);

 // Das sind hier Ereignisse wie z.B. wenn der Benutzer den Text ändert

   switch (id)
   {
       case 4001: vec.x=GetFloat(id);break;
       case 4002: vec.y=GetFloat(id);break;
       case 4003: vec.z=GetFloat(id);break;

          case 5001: ObjektBewegen(mydoc);break;
          case 5002: SpeichernAls(mydoc);break;

   }
}


// register plugin in menu
class MyMenuPlugin : MenuPlugin
{
   public:
      MyMenuPlugin();

      GetID();
      GetName();
      GetHelp();               
      Execute(doc);                
}

MyMenuPlugin::MyMenuPlugin() { super(); }
MyMenuPlugin::GetID()        { return PLUGIN_ID; }
MyMenuPlugin::GetName()      { return "Test Menü"; }
MyMenuPlugin::GetHelp()      { return "Mal gucken was passiert";
}

MyMenuPlugin::Execute(doc)
{

 mydoc=doc;
 vec =vector(0,0,0);

   var d = new(MyDialog);
   d->Open(-1,-1);               
               
        var ok;
        ok=d->GetResult();
        println("Dialog ok=",ok);

        if (ok) {
         
         println("OK");   

        } else {
 
         println("Abbruch");

        } //Dialog OK?

}

MyDialog::ObjektBewegen(doc)
{

        var o ;
        var v ;
        o=GetActiveObject(doc);

        if (o) {
       
        println("Objekt Name = ",o->GetName());
        v=o->GetPosition();
        println("Pos X = ",v.x);
        println("Pos Y = ",v.y);
        println("Pos Z = ",v.z);
        o->SetPosition(vec);
        println("Neue Position");
        println("Pos X = ",vec.x);
        println("Pos Y = ",vec.y);
        println("Pos Z = ",vec.z);

        StopAllThreads(); // VERY IMPORTANT!!!
        DrawViews(DA_ONLY_ACTIVE|DA_NO_THREAD|DA_NO_ANIMATION|DA_ONLY_ACTIVE_VIEW);
        } else {
         println("erstmal nen Objekt auswählen !?");
        }

}

MyDialog::SpeichernAls(doc)
{
               
        var filename = GeGetStartupPath();
        filename->SetLastString("Hallo");
        filename->SetSuffix("a3d");

        var ok;
        ok=filename->FileSelect("Datei speichern unter ...", TRUE);
        println("ok=",ok);

        if (ok) {

         println("filename=",filename->GetFullString());

        } else {
 
         println("Abbruch");

        } //Speichern OK?

}

main()
{
   Register(MyMenuPlugin);
}