; Input-Routine © 2005, ChaosInteractive, written by Daniel 'D2006' Liebetrau.
; This Code is declared as PD

; Besonderheiten:
; Text kann markiert werden
; Alle Copy/Paste/Cut Tastenkürzel funktionieren

Graphics 640,480,32,2
SetBuffer BackBuffer()


;Globals für die Funktion
Global INP_C%,INP_L%,INP_M%=-1,INP_DONE

Repeat
Cls
Text 10,10,"Bitte geben Sie irgendetwas ein:"
inp$=Input(10,50,inp$,30)
Flip
Until INP_DONE
FlushKeys()

Cls
Text 320,240,Chr$(34)+inp$+Chr$(34),1,1
Flip
WaitKey()
End



Function Input$(x,y,dat$,max=65536)
   Local a,d,c$,SHIFT = GetKeyState(16), STRG = GetKeyState(17)
   Local EINFG = GetKeyState(45), ENTF = GetKeyState(46), ENTER = GetKeyState(13)
   Local r=ColorRed(),g=ColorGreen(),b=ColorBlue()
   Local m,l
   INP_DONE=0

   Text x,y,dat$

   ;blinkender Cursor
   If MilliSecs() Mod 800 < 400 Then Rect x+StringWidth(Left$(dat$,INP_C%)),y,1,FontHeight()
   
   ;Markierter Text:
   If INP_M%>-1 Then
      m=INP_M%
      l=INP_L%
      If l<0 Then m = m-Abs(l) : l=Abs(l)
      Color r,g,b
      Rect x+StringWidth(Left$(dat$,m-1)),y,StringWidth(Mid$(dat$,m,l)),FontHeight()
      Color 255-r,255-g,255-b
      Text x+StringWidth(Left$(dat$,m-1)),y,Mid$(dat$,m,l)
      Color r,g,b
   EndIf
   a = GetKey()
   
   ;Eingabe:
   If a>31 And a<256 Then
      If INP_M%>-1 Then
         dat$= Left$(dat$,m-1)+Mid$(dat$,m+l)
         INP_C%=m-1
         INP_M%=-1
         INP_L%=0
      EndIf
      If Len(dat$)=max Then d=1
      dat$ = Left$(dat$,INP_C%) + Chr$(a)+ Mid$(dat$,INP_C%+1+d)
      INP_C%=INP_C%+1
      If Len(dat$)>max Then dat$=Left$(dat$,max):INP_C%=max
   EndIf
   
   ;Löschen / Backspace:   
   If a=8 And Len(dat$)>0 Then
      If INP_M%>-1 Then
         dat$= Left$(dat$,m-1)+Mid$(dat$,m+l)
         INP_C%=m-1
         INP_M%=-1
         INP_L%=0
      ElseIf INP_C%>0             
         dat$ = Left$(dat$,INP_C%-1)+Mid$(dat$,INP_C%+1)
         If INP_C%>0 Then INP_C%=INP_C%-1
      EndIf   
   EndIf
   
   ;Entfernen:   
   If ENTF=-32767 And SHIFT=0 And Len(dat$)>0 Then
      If INP_M%>-1 Then
         dat$= Left$(dat$,m-1)+Mid$(dat$,m+l)
         INP_C%=m-1
         INP_M%=-1
         INP_L%=0
      ElseIf INP_C%<Len(dat$)            
         dat$ = Left$(dat$,INP_C%)+Mid$(dat$,INP_C%+2)
      EndIf   
   EndIf
   
   ;Einfügen:
   If (EINFG=-32767 And SHIFT<>0) Or (KeyHit(47) And STRG<>0) Then   ;Einfügen
      If INP_M%>-1 Then
         dat$= Left$(dat$,m-1)+Mid$(dat$,m+l)
         INP_C%=m-1
         INP_M%=-1
         INP_L%=0
      EndIf
      c$=INPUT_paste$()
      If Len(dat$)=max Then d=Len(c$)
      dat$ = Left$(dat$,INP_C%) + c$ + Mid$(dat$,INP_C%+1+d)
      INP_C% = INP_C%+Len(c$)
      If INP_C%>max Then INP_C%=max
      If Len(dat$)>max Then dat$=Left$(dat$,max)
   EndIf

   ;Kopieren:
   If (EINFG=-32767 And STRG<>0) Or (KeyHit(46) And STRG<>0) And INP_M%>-1 And INP_L%<>0 Then
         INPUT_copy(Mid$(dat$,m,l))
   EndIf
   
   ;Ausschneiden:
   If (ENTF=-32767 And SHIFT<>0) Or (KeyHit(45) And STRG<>0) And INP_M%>-1 And INP_L%<>0 Then
         INPUT_copy(Mid$(dat$,m,l))
         dat$= Left$(dat$,m-1)+Mid$(dat$,m+l)
         INP_C%=m-1
         INP_M%=-1
         INP_L%=0
   EndIf
   
   ;POS1:         
   If KeyHit(199) Then
         If SHIFT Then
            If INP_M%=-1 Then INP_M%=INP_C%+1
            INP_L%=-INP_M%+1
         Else
            INP_L%=0
            INP_M%=-1
         EndIf   
         INP_C%=0
   EndIf      
   
   ;ENDE:
   If KeyHit(207) Then
         If SHIFT Then
            If INP_M%=-1 Then INP_M%=INP_C%+1
            INP_L%=Len(dat$)-INP_M%+1
         Else
            INP_L%=0
            INP_M%=-1
         EndIf            
         INP_C%=Len(dat$)
   EndIf
   
   ;NACH LINKS:      
   If GetKeyState(37)=-32767 And INP_C%>0 Then
         INP_C% = INP_C% - 1
         If SHIFT Then
            If INP_M%=-1 Then INP_M%=INP_C%+2
            INP_L%=INP_L%-1
         Else
            INP_M%=-1
            INP_L%=0
         EndIf      
   EndIf
   
   ;NACH RECHTS:      
   If GetKeyState(39)=-32767 And INP_C%<Len(dat$) Then
         INP_C% = INP_C% + 1
         If SHIFT Then
            If INP_M%=-1 Then INP_M%=INP_C%
            INP_L%=INP_L%+1
         Else
            INP_M%=-1
            INP_L%=0
         EndIf   
   EndIf
   If ENTER Then INP_DONE=1:INP_M%=-1:INP_L%=0:INP_C%=0      
   Return dat$
End Function
   
Function INPUT_paste$() ;Funktion zum Auslesen des Clipboards. THX an OJay
   Local txt$="",t
   t = OpenClipboard(0)
   If t=0 Then Return ""
   If ExamineClipboard(1)
      txt$=GetClipboardData$(1)
   EndIf
   CloseClipboard
   Return txt$
End Function

Function INPUT_copy(txt$) ; Funktion zum Beschreiben des Clipboards. THX an OJay
   Local cb_TEXT=1
   If txt$="" Then Return
   OpenClipboard 0
   EmptyClipboard
   SetClipboardData cb_TEXT,txt$
   CloseClipboard
End Function

; This Code is declared as PD