Private Sub CheckShouldRun()
   
 ' See if another instance of the program is
 ' running in screen saver mode.
       
    ' If no instance is running, we're safe.
    If Not App.PrevInstance Then Exit Sub

    ' See if there is a screen saver mode instance.
    If FindWindow(vbNullString, APP_NAME) Then End

    ' Set our caption so other instances can find
    ' us in the previous line.
    frmMain.Caption = APP_NAME

End Sub

Public Sub Main()
 
 'MR 25.12.2001

 ' Start the program.

 Dim args As String
 Dim preview_hwnd As Long
 Dim preview_rect As RECT
 Dim window_style As Long

    ' Get the command line arguments.
    args = UCase$(Trim$(Command$))

    ' Examine the first 2 characters.
    Select Case Mid$(args, 1, 2)
        Case "/C"   ' Display configuration dialog.
            RunMode = rmConfigure
        Case "", "/S"   ' Run as a screen saver.
            RunMode = rmScreenSaver
        Case "/P"       ' Run in preview mode.
            RunMode = rmPreview
        Case Else       ' This shouldn't happen.
            RunMode = rmScreenSaver
    End Select

    Select Case RunMode
        Case rmConfigure    ' Display configuration dialog.
           
            frmConfig.Show
       
        Case rmScreenSaver  ' Run as a screen saver.
            ' Make sure there isn't another one running.
            CheckShouldRun

            ' Display the cover form.
            Load frmMain
           
            frmMain.Left = 0
            frmMain.Top = 0
            frmMain.Width = Screen.Width
            frmMain.Height = Screen.Height
           
            frmMain.Resize

            Saver_Init

            frmMain.Show
                       
        Case rmPreview      ' Run in preview mode.
            ' Get the preview area hWnd.
            preview_hwnd = GetHwndFromCommand(args)

            ' Get the dimensions of the preview area.
            GetClientRect preview_hwnd, preview_rect

            Load frmMain
           
            ' Set the caption for Windows 95.
            frmMain.Caption = "Preview"

            ' Get the current window style.
            window_style = GetWindowLong(frmMain.hwnd, GWL_STYLE)

            ' Add WS_CHILD to make this a child window.
            window_style = (window_style Or WS_CHILD)

            ' Set the window's new style.
            SetWindowLong frmMain.hwnd, GWL_STYLE, window_style

            ' Set the window's parent so it appears
            ' inside the preview area.
            SetParent frmMain.hwnd, preview_hwnd

            ' Save the preview area's hWnd in
            ' the form's window structure.
            SetWindowLong frmMain.hwnd, GWL_HWNDPARENT, preview_hwnd

            ' Show the preview.
            SetWindowPos frmMain.hwnd, HWND_TOP, 0&, 0&, preview_rect.Right, preview_rect.Bottom, SWP_NOZORDER Or SWP_NOACTIVATE Or SWP_SHOWWINDOW
               
            frmMain.Width = frmMain.ScaleX(preview_rect.Right, vbPixels, vbTwips)
            frmMain.Height = frmMain.ScaleY(preview_rect.Bottom, vbPixels, vbTwips)

            frmMain.Resize
           
            Saver_Init
           
            frmMain.Show

    End Select

End Sub

Private Function GetHwndFromCommand(ByVal args As String) As Long
 
 'MR 25.12.2001
 
 ' Get the hWnd for the preview window from the
 ' command line arguments.

 Dim argslen As Integer
 Dim i As Integer
 Dim ch As String

 ' Take the rightmost numeric characters.
 args = Trim$(args)
 argslen = Len(args)
 For i = argslen To 1 Step -1
  ch = Mid$(args, i, 1)
  If ch < "0" Or ch > "9" Then Exit For
 Next i

 GetHwndFromCommand = CLng(Mid$(args, i + 1))

End Function

Const SRCCOPY = $CC0020
hdc          = API_GetDC(PrevHnd%)
BlitzHwnd = API_GetActiveWindow()
Blitzhdc    = API_GetDC(BlitzHwnd)
API_BitBlt(hdc, 0, 0, 150, 113, Blitzhdc, 0,0, SRCCOPY)
API_ReleaseDC(PrevHnd, hdc)
API_ReleaseDC(BlitzHwnd, Blitzhdc)