;Eine Box Gegen die der Spieler gegen fahren kann
Type box
   Field x, y
   Field b, h
End Type

;Variablen für die Auflösung
Global grafx=1024
Global grafy=768

;Variablen für den Spieler
Global Px#, Py#, wi, sp

;zehn Boxen werden zufällig erstellt
For x=1 To 10
   CreateBox(Rand(0, grafx), Rand(0, grafy), Rand(10, 200), Rand(10, 200))
Next

;Grafikmodus wird gesetzt
Graphics(grafx, grafy, 16, 1)

;setzt den Buffer auf den gezeichnet werden soll fest
SetBuffer BackBuffer()
;beginn der Hauptschleife
While KeyHit(1)=0
   
   ;Winkel ändern
   If KeyDown(205) Then wi=wi+3
   If KeyDown(203) Then wi=wi-3
   If wi>360 Then wi=0
   If wi<0 Then wi=360
   
   ;vorwärts fahren?
   sp=KeyDown(200)*3
   ;rückwärts fahren?
   If sp=0 Then sp=0-KeyDown(208)*3
   
   ;Speichern der Spielerposition
   OPx=Px
   OPy=Py
   
   ;berechen der neuen Spielerposition
   Px=Px+Cos(wi)*sp
   Py=Py+Sin(wi)*sp
   
   ;wenn wo gegen gefahren dann die Spielerposition zurück setzen
   If Kollision()=1 Then
      Px=OPx
      Py=OPy
   EndIf 
   
   ;alles schwartz streichen^^
   Cls
   
   ;die boxen malen
   RenderBox()
   ;den Spieler malen
   Rect Px, Py, 32, 32, 0
   ;Den richtungspfeil malen
   Line Px+16, Py+16, Px+16+Cos(wi)*10, Py+16+Sin(wi)*10
   
   Flip
Wend
End

Function Kollision()
   ;eine Schleife die alle Boxen abfragt
   For box.box=Each box
      ;wenn Kollision dann gebe eins zurück
      If RectsOverlap(Px, Py, 32, 32, box\x, box\y, box\b, box\h) Then Return 1
   Next
End Function

;Function zum erstellen einer Box
Function CreateBox(x, y, b, h)
   box.box=New box
   box\x=x
   box\y=y
   box\b=b
   box\h=h
End Function

;zum zeichnen der Boxen
Function RenderBox()
   For box.box=Each box
      Rect(box\x, box\y, box\b, box\h, 0)
   Next
End Function