Strict

Type TClient
   Global List  : TList
   
   Field Stream : TTCPClient
   Field IP     : String
End Type

Global Server  : TTCPServer
Global Stream  : TTCPClient
Global Client  : TClient

Global Message : String

TClient.List = CreateList()
TCPTimeouts 100, 100

Server = CreateTCPServer(1234)
If Server <> Null Then
   Print "Server erfolgreich gestartet!"
Else
   Print "Server konnte nicht erstellt werden"
   End
EndIf

While Not KeyDown(KEY_ESCAPE)
   Stream = AcceptTCPStream(Server)
   If Stream <> Null Then
      Client = New TClient
      Client.Stream = Stream
      Client.IP     = DottedIP(TCPStreamIP(Stream))
      
      TClient.List.AddLast(Client)
      Print "Neuer Klient: "+Client.IP
   EndIf
   
   For Client = EachIn TClient.List
      Select Eof(Client.Stream)
         Case -1
            Print Client.IP+" hat die Verbindung getrennt"
            TClient.List.Remove(Client)
            
         Case 0
            While Not Eof(Client.Stream)
               Message = ReadLine(Client.Stream)
               Print Client.IP+": "+Message
            Wend
            WriteLine Client.Stream, "OK"
      End Select
   Next
Wend

Strict

Global Client  : TTCPClient
Global Message : String

TCPTimeouts 100, 0

Client = OpenTCPStream("127.0.0.1", 1234)
If Client <> Null Then
   Print "Klient erfolgreich verbunden!"
Else
   Print "Konnte keine Verbindung herstellen!"
   WaitKey
   End
EndIf

While Not KeyDown(KEY_ESCAPE)
   Message = Input("Nachricht: ")
   WriteLine Client, Message
   
   If Message = "END" Then Exit
   
   Repeat
   Until ReadAvail(Client)

   While Not Eof(Client)
      Print "Server: "+ReadLine(Client)
   Wend
Wend