Include "collisions.bb"

Type T_Player
   Field pivot
   Field camera
   
   Field yspeed#
   Field movespeed
End Type

Global player.T_Player


Function Init_Player()
   ;Setup player
   player.T_Player = New T_Player
   
   ;Base
   player\pivot=CreatePivot()
   EntityRadius player\pivot,32
   EntityType player\pivot,col_player
   
   ;Camera
   player\camera=CreateCamera( player\pivot )
   MoveEntity player\camera,0,64,0
   
   ;Jump
   player\yspeed#=0.0
   player\movespeed=8
   
   ;Setup collisions
   Collisions col_player,col_environment,2,3
   
   ;Ins level etwas über den boden
   PositionEntity player\pivot,0,100,0
   
   
   MoveMouse 400,300
End Function


Function Update_Player()
   ;Look around
   mys = MouseYSpeed()/2
   If Abs(EntityPitch(player\camera)+mys)<89 Then
      TurnEntity player\camera,mys,0,0
   EndIf
   TurnEntity player\pivot,0,-MouseXSpeed()/2,0
   
   ;Movement
   If KeyDown(17) MoveEntity player\pivot,0,0,player\movespeed
   If KeyDown(31) MoveEntity player\pivot,0,0,-player\movespeed
   If KeyDown(30) MoveEntity player\pivot,-player\movespeed,0,0
   If KeyDown(32) MoveEntity player\pivot,player\movespeed,0,0
      
   ;Es lebe die schwerkraft
   player\yspeed=player\yspeed-2
   MoveEntity player\pivot,0,player\yspeed,0
   
   
   ;Collisions
   col=CountCollisions(player\pivot)
   For i=1 To col
      If CollisionNY(player\pivot,i) Then ;Baby,wenn ich down bin
         player\yspeed=0
         If KeyDown(57) player\yspeed=20 ;dann flieg ich nur so dahin(Jump),muha
      End If
   Next
   
   
   MoveMouse 400,300
End Function