; Author: East-Power-Soft
; Date: 2005-11-13 19:03:00
; Title: tooltip.dll decls
; Description: Functions to create ToolTips

.lib "tooltip.dll"

TTAdd%(hWnd%, hGad%, Text$, MaxWidth%, Style%, col1%, col2%): "TTAdd"
TTRemove%(hTip%) : "TTRemove"
TTChange%(hTip%, Text$) : "TTChange"
TTShow%(hTip%,x%,y%) : "TTShow"
TTHide%(hTip%) : "TTHide"

;==================================================================================================
; ToolTip.DLL for Blitz+
;
; by East-Power-Soft (http://www.East-Power-Soft.de)
;
; This Lib is for using Tooltips with Blitz+. It doesn't work with Labels, sorry, i could find no
; reason for this. All other Elements should be work. (testet on: Button, Canvas, Slider, Panel,
; TreeView, ListBox, TextArea, TextField and Window)
;==================================================================================================

Global win = CreateWindow("test",300,200,300,250,Desktop())
Global but1 = CreateButton("Change ToolTipText",10,70,120,25,win)
Global but2 = CreateButton("ToolTip ON",140,70,100,25,win)
Global lab1 = CreateLabel("Go with the Mouse Over the Button and wait until you see the ToolTip.",10,10,180,30,win)
Global cnv1 = CreateCanvas(10,130,50,50,win)

;==================================================================================================
; Syntax: hTip = TTAdd (hWnd, hGad, Text$, MaxWidth, Style, TextColor, BackColor)
;
;      hWnd = Window Handle as QueryObject(WinVar,1)
;      hGad = Gadget Handle as QueryObject(GadVar,1)
;     Text$ = The ToolTip Text
;  MaxWidth = Maximum width of the Tooltip. Text will be wrapped automatic
;     Style = 0 = Square ToolTip; 1 = Balloon ToolTip
; TextColor = 0 = use Windows Color
; BackColor = 0 = use Windows Color
;==================================================================================================

Tip1 = TTAdd(QueryObject(win,1),QueryObject(but1,1),"Here is a normal ToolTip",100,0,$FFFFFF,$808080)
Tip2 = TTAdd(QueryObject(win,1),QueryObject(cnv1,1),"Works also over Canvas Objects",100,1,0,0)

Repeat
   event = WaitEvent()
   If event Then
      Select event
         Case $803: Exit
         Case $401
            Select EventSource()
               Case but1
                  TTChange(Tip1,"you changed the text")
               Case but2
                  If Not(ON) Then
                     Tip3 = TTAdd(QueryObject(win,1),QueryObject(but2,1),"Another ToolTip",100,0,0,0)
                     TTShow(Tip3,MouseX()+5,MouseY()+5)
                     SetGadgetText but2,"ToolTip ON"
                     ON = True
                  Else
                     TTRemove(Tip3)
                     SetGadgetText but2,"ToolTip OFF"
                     ON = False
                  End If
            End Select
      End Select
   End If
Forever

TTRemove(Tip1)
TTRemove(Tip2)
TTRemove(Tip3)


;==================================================================================================
; More Functions:
;
; TTRemove(hTip)        -> ToolTip will be deleted
; TTChange(hTip, Text$) -> Changes the Text in the ToolTip
; TTShow(hTip,x,y)      -> Shows the ToolTip immediately on the Pos x,y and this 'alwaysontop'
; TTHide(hTip)          -> Hides a Tooltip
;==================================================================================================