Type team
   Field name$
End Type

Type match
   Field team1.team
   Field team2.team
End Type

Type lostrommel
   Field team.team
End Type

;anzahl der teams
anzahl = 16

;teams erstellen
For i=1 To anzahl
   t.team = New team
   t\name = "Team_"+i
Next

;alle teams in die virtuelle lostrommel
For t.team = Each team
   l.lostrommel = New lostrommel
   l\team = t
Next

;die anzahl der matche ist die anzahl der teams durch 2
For i=1 To Floor(anzahl/2)
   team1.team = choose_team()
   team2.team = choose_team()
   
   ;das match anlegen
   m.match = New match
   m\team1 = team1
   m\team2 = team2
Next

;die paarungen ausgeben
For m.match = Each match
   match_num = match_num + 1
   Print "Match "+match_num + ": " + m\team1\name+" - "+m\team2\name
Next
WaitKey

Function choose_team.team()
   ;erstmal zählen
   For l.lostrommel = Each lostrommel
      anzahl = anzahl + 1
   Next
   
   ;zufällig eine Nummer ziehen
   SeedRnd(MilliSecs())
   r = Rand(0,anzahl-1)
   
   ;solange durch den Type gehen bis nummer erreicht ist
   l.lostrommel = First lostrommel
   For i=1 To r
      l.lostrommel = After l
   Next
   
   ;team merken und das los löschen
   team.team = l\team
   Delete l
   
   ;den type zurückgeben
   Return team
End Function

; spielplan erstellen
;
; soli - andsa @ web.de
;


;vari
anzahlmannschaften=18


spielplan(anzahlmannschaften)

Function spielplan(anzahlmannschaften)

;für weniger mannschaften nicht notwendig
If anzahlmannschaften<4 Then Return;



   If anzahlmannschaften Mod 2=0
      modus$="gerade"
      spieltage=anzahlmannschaften-1
   Else
      modus$="ungerade"
      spieltage=anzahlmannschaften
   EndIf
   

   For x=1 To spieltage
   
      Cls
      Locate 0,0
      
      Print x + ".Spieltag"
      
      If modus$="gerade"
      
         paarungen=anzahlmannschaften/2
                  
         ;reihum - mannschaftA-rechtsherum - mannschaftB-linkssherum
         
         For y=1 To paarungen
                  
            mannschaftA= (x+1 + y-3) Mod (anzahlmannschaften-1) + 1
            mannschaftB= (anzahlmannschaften + x - y-1 )   Mod (anzahlmannschaften-1) + 1
            
            ;mannschaft des spieltages spielt immer gegen die letzte mannschaft
            If mannschaftA=x
               mannschaftB=anzahlmannschaften
            EndIf
            
      
            ;gerader spieltag - paarungen drehen wegen Heim/Auswärts
            If x Mod 2 = 0
               tmp=mannschaftA
               mannschaftA=mannschaftB
               mannschaftB=tmp
            EndIf
            
            
            Print mannschaftA + " : " + mannschaftB
                     
         Next
         
      EndIf
      
   ;Stop   
      If modus$="ungerade"
      
         paarungen=Int(anzahlmannschaften/2)
         
         ; mannschaft identisch mit spieltag ist spielfrei
         Print "Spielfrei:" + x
         
         For y=1 To paarungen

            mannschaftA= (x+1 + y-2) Mod (anzahlmannschaften) + 1
            mannschaftB= (anzahlmannschaften + x - y -1  )   Mod (anzahlmannschaften) + 1
   
            ;gerader spieltag - paarungen drehen wegen Heim/Auswärts
            If x Mod 2 = 0            
               tmp=mannschaftA
               mannschaftA=mannschaftB
               mannschaftB=tmp
            EndIf
            
            
            Print mannschaftA + " : " + mannschaftB
                                       
         Next
         
      EndIf
      
      WaitKey()
   
   Next
   
 End Function