;Simple SchattenDemo von Inarie
;www.projectblitz.de
;www.inarie.de


Graphics3D 800,600,32,1
SetBuffer BackBuffer()

;kamera
piv = CreatePivot()
cam = CreateCamera(piv)

MoveEntity cam,0,0,-10
PointEntity cam,piv


;heightmap... wird hier als texture und displacementzeugs genutzt
heightmap = LoadTexture("heightmap.bmp")

;ein hübsches bodenmesh aus sucox code geklaut ;)
mesh = CreateBoden(30,30)
ScaleMesh mesh,.2,.2,.2

; ein paar cylinder, die durch die luft fliegen
cubes = CreateMesh()
For i = 0 To 2
   cube = CreateCylinder(3)
   ScaleMesh cube,.8,.8,.8
   PositionMesh cube,Rnd(2,18)-10,.5,Rnd(2,18)-10
   RotateMesh cube,Rand(-20,20),Rand(360),Rand(-20,20)
   AddMesh(cube, cubes)
   FreeEntity cube
Next

ScaleMesh mesh,8,8,8
ScaleMesh cubes,2,2,2

PositionEntity mesh,0,-10,0

meshbrushwhite = CreateBrush(255,255,255)
BrushFX meshbrushwhite,1
meshbrush = CreateBrush(255,255,255)
BrushTexture meshbrush,heightmap,0,1

cubebrushwhite = CreateBrush(255,255,255)
BrushFX cubebrushwhite,1
cubebrush = CreateBrush(255,255,255)
BrushTexture cubebrush,heightmap,0,1


;licht und lichtkamera
Global light = CreateLight(2)
PositionEntity light,25,25,0
LightColor light,10,10,10
AmbientLight 10,10,10

lightcam = CreateCamera(light)
HideEntity lightcam
CameraFogMode lightcam,1
CameraFogRange lightcam,35,150
CameraClsColor lightcam,255,255,255
CameraViewport lightcam,0,0,512,512
PointEntity lightcam,cubes
CameraViewport lightcam,0,0,512,512

CreateCube(lightcam); man will ja auch sehen, wo das licht ist ;)

;die zwei schattentexturen
;die texturen nutzen das zweite uvset!
stex = CreateTexture(512,512,256)
TextureBlend stex,2
TextureCoords stex,1
stex2 = CreateTexture(512,512,256)
TextureBlend stex2,2
TextureCoords stex2,1

;projektion
ProjUV(lightcam,mesh,512,0)
ProjUV(lightcam,cubes,512)

;displacement für hübsches terrain
EntityDisplace(mesh,heightmap,10,-1)


;coole, schattenwerfende kugeln ;)
kpiv = CreatePivot()
Global kugel[5]
For i = 0 To 5
   t = Rand(0,3)
   Select t
   Case 0
      kugel[i] = CreateSphere(8,kpiv)
   Case 1
      kugel[i] = CreateCube(kpiv)
   Case 2
      kugel[i] = CreateCone(7,1,kpiv)
   Case 3
      kugel[i] = CreateCylinder(7,1,kpiv)
   End Select
         
   ScaleEntity kugel[i],Rnd(2,3),Rnd(2,3),Rnd(2,3)
   RotateEntity kugel[i],Rand(360),Rand(360),Rand(360)
   PositionEntity kugel[i],Rand(-30,30),Rand(-30,30),Rand(-30,30)
Next
ScaleEntity kpiv,.5,.5,.5
PositionEntity kpiv,0,5,0



;mainloop
While Not KeyHit(1)
   If KeyHit(57) Then wire = 1- wire:WireFrame wire
   
   ;umherwerfen der objekte
   TurnEntity kpiv,.15,.5,.05
   TurnEntity cubes,.1,0,0
   
   PointEntity light,cubes
   PointEntity lightcam,cubes
   MoveEntity light,-.2,0,0
   
   ;projektion der schattenuvkoordinaten
   ProjUV(lightcam,cubes,512)
   ProjUV(lightcam,mesh,512)
   
   ;anmalen der entities in der farbe, die ihr schatten haben soll
   PaintSpheres(100,100,100,1)
   PaintEntity mesh,meshbrushwhite
   PaintEntity cubes,cubebrushwhite
   
   ;schatten für die cubes rendern
   RenderShadow(lightcam,cam,stex)
   
   ;da die cubes schatten auf das terrain werfen sollen, müssen sie jetzt auch angemalt werden
   EntityColor cubes,100,100,100
   EntityFX cubes,1
   
   ;rendern der schatten auf dem terrain
   RenderShadow(lightcam,cam,stex2)
   
   ;alles in den farben anmalen, in denen es gerendert werden soll und schattentexturen draufpacken
   PaintEntity mesh,meshbrush
   PaintEntity cubes,cubebrush
   EntityTexture mesh,stex2,0,2
   EntityTexture cubes,stex,0,2
   PaintSpheres(255,255,255,0,heightmap)
   
   ;rendern
   RenderWorld
   
   If KeyHit(2) Then FlushKeys : WaitKey()
   
   ;kamerasteuerung
   TurnEntity piv,KeyDown(200)-KeyDown(208),KeyDown(205)-KeyDown(203),0
   MoveEntity cam,0,0,KeyDown(30)-KeyDown(44)
   RotateEntity piv,EntityPitch(piv),EntityYaw(piv),0
   
   Text 0,0,Util_Fps()
   ;Text 0,20,TrisRendered()
   
   Flip 0 ; flip0, damit man die tatsächlichen fps sieht
Wend
End


Function ProjUV(cam,mesh,width#,set=1)  ; diese funktion passt die vertexkoordinaten an die projektion der kamera an
   RotateEntity cam,EntityPitch(cam),EntityYaw(cam),0
   For s = 1 To CountSurfaces(mesh)
      sur = GetSurface(mesh,s)
      For ve = 1 To CountVertices(sur)-1
         x# = VertexX(sur,ve)
         y# = VertexY(sur,ve)
         z# = VertexZ(sur,ve)
         
         TFormPoint x#,y#,z#,mesh,0
         x# = TFormedX#()
         y# = TFormedY#()
         z# = TFormedZ#()
         
         CameraProject(cam,x#,y#,z#)
         u# = ProjectedX#()/width#
         v# = ProjectedY#()/width#
         
         VertexTexCoords sur,ve,u#,v#,0,set
      Next
   Next
End Function


Function PaintSpheres(r,g,b,fx,tex=0) ; färbt die ganzen kugeln ein (hätt' ich die doch bloß mit addmesh zusammengefügt! ;))
   For i = 0 To 15
      TurnEntity kugel[i],.2,.1,0
      EntityColor kugel[i],r,g,b
      EntityFX kugel[i],fx
      If tex Then EntityTexture kugel[i],tex
   Next
   EntityColor kugel[5],120,0,0
   EntityAlpha kugel[5],.5
End Function


Function RenderShadow(cam,hcam,tex) ; rendert die schattentextur
   ShowEntity cam
   HideEntity hcam
   size = TextureWidth(tex)
   
   CameraViewport cam,0,0,size,size
   
   UpdateWorld
   RenderWorld
   
   CopyRect 0,0,size,size,0,0,BackBuffer(),TextureBuffer(tex)
   
   HideEntity cam
   ShowEntity hcam
End Function


Function CreateBoden(xstep = 20, zStep = 20) ; erstellt einen wunderschönen suco-x boden ;)
   Local final_mesh = CreateMesh()
   Local final_surface = CreateSurface(final_mesh)
   Local vertex[5]
   
   
   For x = 0 To xstep-1
      For z = 0 To zStep-1     
         vertex[0] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2,0,0)
         vertex[1] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2-1,0,1)
         vertex[2] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2-1,1,1)
         
         vertex[3] = AddVertex(final_surface,x-xstep/2,0,z-zStep/2,0,0)
         vertex[4] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2,1,0)
         vertex[5] = AddVertex(final_surface,x-xstep/2+1,0,z-zStep/2-1,1,1)
         
         AddTriangle(final_surface, vertex[2], vertex[1], vertex[3])
         AddTriangle(final_surface, vertex[3], vertex[4], vertex[5])
         
         
      Next
   Next
   
   UpdateNormals(final_mesh)
   
   Return final_mesh
End Function


Function EntityDisplace(mesh,tex,scale#=1,diff#=0,updanormals=1) ; verschiebt vertices anhand ihrer uv in normalrichtung
   twidth   = TextureWidth(tex)-1                        ; wird weithin displacementmapping genannt ;)
   theight = TextureHeight(tex)-1
   
   LockBuffer TextureBuffer(tex)
   
   For s = 1 To CountSurfaces(mesh)
      sur = GetSurface(mesh,s)
      For ver = 0 To CountVertices(sur)-1
         c = ReadPixelFast(VertexU(sur,ver)*twidth,VertexV(sur,ver)*theight,TextureBuffer(tex))
         move# = Float#((c And $FF0000)/$10000)/255.00+diff#
         nx# = VertexX(sur,ver)+(VertexNX(sur,ver))*move*scale#
         ny# = VertexY(sur,ver)+(VertexNY(sur,ver))*move*scale#
         nz# = VertexZ(sur,ver)+(VertexNZ(sur,ver))*move*scale#
         VertexCoords sur,ver,nx,ny,nz
      Next
   Next
   
   UnlockBuffer TextureBuffer(tex)
   
   If updanormals Then UpdateNormals mesh
End Function


Global fps_frames,fps_ms=MilliSecs(),fps_anzeige#      ; zeigt nur die fps an
Function Util_Fps()
   fps_frames=fps_frames+1
   If MilliSecs()-fps_ms >= 1000 Then
      fps_anzeige=fps_frames
      fps_frames=0
      fps_ms=MilliSecs()
   EndIf
   Return fps_anzeige
End Function