Graphics 640,480,32,2
SetBuffer BackBuffer()

Print "Searching... (Esc to interrupt)":Print

Search("C:",".bb","Hello")

file = WriteFile("found.log")
For result.TResult = Each TREsult
 Print result\name$
 WriteLine file,result\name$
 Delete result
Next
CloseFile file

Print:Print "Result saved in "+CurrentDir()+"found.log"
Print "Press any key..."

WaitKey()
End()

; ***************
;
;  Mainfunctions
;
; ***************

Function Search(s_dir$,s_file$,word$="")

   dir_n% = GetParameterNumber(s_dir$)
   file_n% = GetParameterNumber(s_file$)
   word_n% = GetParameterNumber(word$)
   
   For I = 1 To dir_n%
    dir.TDir = New TDir
    dir\name$ = GetParameter(s_dir$,I)
   Next
   For I = 1 To file_n%
    file.TFile = New TFile
    file\name$ = GetParameter(s_file$,I)
   Next
   For I = 1 To word_n%
    w.TWord = New TWord
    w\name$ = GetParameter(word$,I)
   Next
   
   Repeat
    If KeyHit(1) Then FlushKeys() : Exit
   
    n% = 0
    For dir.TDir = Each TDir
     n% = n% + 1
    Next
    If Not(n%) Then
     empty = 1
    Else
     dir = Last TDir
   
     SearchDir(dir\name$,word$)
   
     Delete dir
    EndIf
   Until empty=1

   For file.TFile = Each TFile
    Delete file
   Next
   For dir.TDir = Each TDir
    Delete dir
   Next
   For w.TWord = Each TWord
    Delete w
   Next

End Function

; ****************
;
; Helper Functions
;
; ****************

Function GetParameterNumber%(txt$)

   Local n%=1
   
   While Instr(txt$,",")
    n% = n% + 1
    txt$ = Mid(txt$,Instr(txt$,",")+1,Len(txt$))
   Wend
   
   Return n%

End Function

Function GetParameter$(txt$, index)

   Local n%=1
   Local new_txt$=""
   
   Repeat
    If n% = index Then
     If Instr(txt$,",") Then
      new_txt$ = Mid(txt$,1,Instr(txt$,",")-1)
     Else
      new_txt$ = txt$
     EndIf
     Exit
    Else
     txt$ = Mid(txt$,Instr(txt$,",")+1,Len(txt$))
    EndIf
    n% = n% + 1
   Forever
   
   new_txt$ = Trim(new_txt$)
   Return new_txt$

End Function

Function SearchDir(dir$,word$)

   DebugLog dir$
   s_dir = ReadDir(dir$)
   If s_dir Then
   
    Repeat
     file$ = NextFile(s_dir)
   
     If file$="" Then Exit
     If FileType(dir$+"\"+file$) = 2 Then
      If file$ <> "." And file$ <> ".." Then
       new_dir.TDir = New TDir
       new_dir\name$ = dir$+"\"+file$
       Insert new_dir After First TDir
      EndIf
     Else
   
      If word$ <> "" Then
       o_file = ReadFile(dir$+"\"+file$)
       If o_file Then
        Repeat
         l$ = ReadLine(o_file)
         For w.TWord = Each TWord
          If Instr(Lower(l$),Lower(w\name$)) Then
           n% = 0
           For result.TResult = Each TResult
            If Lower(result\name$) = Lower(dir$+"\"+file$) Then n% = 1 : Exit
           Next
           If n% = 0 Then
            result.TResult = New TResult
            result\name$ = dir$+"\"+file$
            DebugLog "Found: "+result\name$
           EndIf
          EndIf
         Next
        Until Eof(o_file)
        CloseFile o_file
       EndIf
      EndIf
   
      For all_files.TFile = Each TFile
       If Instr(Lower(file$),Lower(all_files\name$)) Then
        n% = 0
        For result.TResult = Each TResult
         If Lower(result\name$) = Lower(dir$+"\"+file$) Then n% = 1 : Exit
        Next
        If n% = 0 Then
         result.TResult = New TResult
         result\name$ = dir$+"\"+file$
         DebugLog "Found: "+result\name$
        EndIf
       EndIf
      Next
     EndIf
   
    Forever
   
    CloseDir s_dir
   EndIf

End Function

; ***************
;
;     Types
;
; ***************

Type TDir
 Field name$
End Type

Type TFile
 Field name$
End Type

Type TResult
 Field name$
End Type

Type TWord
 Field name$
End Type