WriteFile

ReadFile

 ; MR 06.01.2003

 ; Example usage:

 ;Print "INI Value = " + ReadINIValue("Archon", "Video", "Resolution", "800x600")
 ;bSuccess% = WriteINIValue("Archon", "Audio", "Music", "0")

 Function ReadINIValue$(sAppName$, sSection$, sKey$, sDefault$)

 ; Returns: INI Value (String) - The sDefault value is returned if no SECTION/KEY combination is found

     sSection = "[" + Upper$(Trim$(sSection)) + "]"
     sKey = Upper$(Trim$(sKey))

     sFilename$ = CurrentDir$() + "\"  + sAppName + ".ini"

 ; Retrieve the INI data

     sINI$= FileToString(sFilename)
     sUpperINI$ = Upper$(sINI) ; Speed up checks below

 ; Locate the SECTION, KEY and VALUE

     sValue$ = ""

     lSectionPos% = Instr(sUpperINI, sSection)
     If (lSectionPos <> 0) Then
         lKeyPos% = Instr(sUpperINI, sKey, (lSectionPos + Len(sSection) + 1))
         If (lKeyPos <> 0) Then
           Local nextSection=Instr(sUpperINI, "[", (lSectionPos + Len(sSection) + 1))
           If nextSection=0 Or (nextSection=>1 And lKeyPos<nextSection)
             lStartPos% = Instr(sUpperINI, "=", (lKeyPos + 1))
             If (lStartPos <> 0) Then
                 lEndPos% = Instr(sUpperINI, Chr$(0), (lStartPos + 1))
                 If (lEndPos <> 0) Then
                     ; We have located the required INI VALUE!
                     sValue = Trim$(Mid$(sINI, lStartPos + 1, (lEndPos - lStartPos - 1)))
                     ; Now remove any leader/trailer quotes (") - ** OPTIONAL **
                     ;If Left$(sValue, 1) = Chr$(34) Then sValue = Mid$(sValue, 2)
                     ;If Right$(sValue, 1) = Chr$(34) Then sValue = Mid$(sValue, 1, (Len(sValue) - 1))
                 End If
             End If
           EndIf ;KEY must inside section  !
         End If
     End If

 ; Return the value

     If (sValue <> "") Then Return sValue Else Return sDefault

 End Function

 Function WriteINIValue%(sAppName$, sSection$, sKey$, sValue$)

 ; Returns: True (Success) or False (Failed)

     sSection = "[" + Trim$(sSection) + "]"
     sUpperSection$ = Upper$(sSection)

     sKey = Trim$(sKey)
     sValue = Trim$(sValue)

     sFilename$ = CurrentDir$() + "\"  + sAppName + ".ini"

 ; Retrieve the INI data (if it exists)

     sINI$= FileToString(sFilename)

 ; (Re)Create the INI file updating/adding the SECTION, KEY and VALUE

     bWrittenKey% = False
     bSectionFound% = False
     sCurrentSection$ = ""

     f = WriteFile(sFilename)
     If f = 0 Then Return False ; Create file failed!

     lOldPos% = 1
     lPos% = Instr(sINI, Chr$(0))

     While (lPos <> 0)

         sTemp$ =Trim$(Mid$(sINI, lOldPos, (lPos - lOldPos)))
         
         If (sTemp <> "") Then

             If Left$(sTemp, 1) = "[" And Right$(sTemp, 1) = "]" Then

                 ; Process SECTION

                 If (sCurrentSection = sUpperSection) And (bWrittenKey = False) Then
                     bWrittenKey = CreateINIKey(f, sKey, sValue)
                 End If
                 sCurrentSection = Upper$(CreateINISection(f, sTemp))
                 If (sCurrentSection = sUpperSection) Then bSectionFound = True

             Else

                 ; KEY=VALUE

                 lEqualsPos% = Instr(sTemp, "=")
                 If (lEqualsPos <> 0) Then
                     If (sCurrentSection = sUpperSection) And (Upper$(Trim$(Left$(sTemp, (lEqualsPos - 1)))) = Upper$(sKey)) Then
                         If (sValue <> "") Then CreateINIKey f, sKey, sValue
                         bWrittenKey = True
                     Else
                         WriteLine f, sTemp
                     End If
                 End If

             End If

         End If

         ; Move through the INI file...

         lOldPos = lPos + 1
         lPos% = Instr(sINI, Chr$(0), lOldPos)

     Wend

     ; Section wasn't found in the INI file - Append a new SECTION and create our KEY=VALUE line

     If (bWrittenKey = False) Then
         If (bSectionFound = False) Then CreateINISection f, sSection
         CreateINIKey f, sKey, sValue
     End If

     CloseFile f

     Return True ; Success

 End Function

 Function FileToString$(sFilename$)

     sString$ = ""

     f% = ReadFile(sFilename)
     If f <> 0 Then
         While Not(Eof(f))
             sString = sString + ReadLine$(f) + Chr$(0)
         Wend
         CloseFile f
     End If

     Return sString

 End Function

 Function CreateINISection$(f%, sNewSection$)

     If FilePos(f) <> 0 Then WriteLine f, "" ; Blank line between sections
     WriteLine f, sNewSection
     Return sNewSection

 End Function

 Function CreateINIKey%(f%, sKey$, sValue$)

     WriteLine f, sKey + "=" + sValue
     Return True

 End Function

; --- Konfiguration laden ---
Function LoadConfig()

 File = OpenFile("Game.dat")

 If Not File = 0 Then
  Datei = ReadFile("Game.dat")
 
   For i = 0 To 3
    Highscore(i) = ReadShort(Datei)
   Next

   Level = ReadByte(Datei)
   Speed = ReadByte(Datei)
 
  CloseFile Datei
 EndIf


 If File = 0 Then
  For i = 0 To 3
   Highscore(i) = 0
  Next

  Level = 0
  Speed = 30
 EndIf

End Function
; --- Konfiguration laden ---



; --- Konfiguration speichern ---
Function SaveConfig()
 Datei = WriteFile("Game.dat")
  For i = 0 To 3
   WriteShort Datei, Highscore(i)
  Next

  WriteByte Datei, Level
  WriteByte Datei, Speed
 CloseFile Datei
End Function
; --- Konfiguration speichern ---

; Speichern
WriteLine Datei, "Geschwindigkeit =" + Speed

; Laden
Speed$ = ReadLine(Datei)
Speed = Mid(Speed$, 19, 2)

[Sektion 1]
name=wert
name2=wert2
; Kommentar

[überkategorie1]
wert1=a
wert2=b