.GLOBALE

Dim para$(128) ;um einzelne Zeilen einer Textdatei in Parameter umzuwandeln

Function TreeNew(x#,y#,z#,rn#)

 ;MR 28.04.2003

 ;Neuer Baum an x,y,z größe rn
 
  Tree.TreeType=New TreeType

  Tree\Entity=CopyEntity(tree_sprite)
  Tree\rn=rn
  y=MyTerrainY( land,x,y,z )+1
  MoveEntity Tree\Entity,x,y,z ;Nicht Position !?
  ScaleEntity Tree\Entity,rn,rn*2,rn
  EntityBox Tree\Entity,-rn/2,0,-rn/2,rn,rn*4,rn

End Function

Function TreesSave()

 ;MR 28.04.2003

 ;Bäume speichern in Textdatei :-)

  ;---------------------------------------------------------------------

  Print "Bäume speichern ..."

  Local f$="Data\Trees.txt"
  Local fh
  Local s$

   fh=WriteFile(f$)
   If fh Then
    For Tree.TreeType=Each TreeType
     s$="TREE:"+EntityX(Tree\Entity)+","+EntityY(Tree\Entity)+","+EntityZ(Tree\Entity)+","+Tree\rn
     WriteLine fh,s$
    Next
    CloseFile fh
   EndIf ;open ok

  Print "OK"

  ;---------------------------------------------------------------------

End Function

Function TreesLoad()

 ;MR 28.04.2003

 ;Bäume laden aus Textdatei :-)

  TreesFree

  ;---------------------------------------------------------------------

  Print "Bäume laden ..."

  Local f$="Data\Trees.txt"
  Local fh
  Local o$

  If FileExists(f$)=True

   fh=ReadFile(f$)
   If fh Then
    While Not Eof(fh)
     o$=StringToFunc(ReadLine(fh)+Chr(13)) ;Return wird entfernt ,brauche ich aber noch !
     DebugLog o$
    Wend
    CloseFile fh
   EndIf ;open ok

  EndIf ;Datei ist da

  Print "OK"

  ;---------------------------------------------------------------------

End Function

Function StringToFunc$(FileInput$)

 ;MR 28.04.2003

 ;----------------------------------------------------------------------------- String to Functions :-)

 Local c$,o$,x,x1,x2,p,i
 c$=""
 o$=""

 ;---------------------------------------------------------

 ;Command
 x=Instr(FileInput,":")
 If x>1 Then
  c$=Mid(FileInput,1,x-1)
  c$=Upper(c$)
 EndIf

 ;---------------------------------------------------------

 ;Clear Parameter
 p=0
 For i=1 To 128
  Para(i)=""
 Next

 ;Search for Parameters
 x2=0
 If Len(FileInput)>x Then
  x1=x+1
  Repeat
   x2=Instr(FileInput,",",x1)
   If x2=0 Then x2=Instr(FileInput,Chr(13),x1) ;or to End
   If x2>x1 Then
    p=p+1
    Para(p)=Mid(FileInput,x1,x2-x1)
    x1=x2+1
   EndIf
   If x2=Len(FileInput) Then x2=0 ;no endless loop ;-)
  Until x2=0
 EndIf

 ;------------------------------------------------------------> COMMAND <---

 ;Functions
 If Len(c$)>0 Then
 Select c$

 Case "TREE","BAUM"
  ;x,y,z,rn
  TreeNew Para(1),Para(2),Para(3),Para(4)
  o$=c$

 Case "TARGET","ZIEL"
  ;x,y,z,r,g,b
  TargetNew Para(1),Para(2),Para(3),Para(4),Para(5),Para(6)
  o$=c$

 Default
  o$="UNKNOWN COMMAND "+c$
 End Select
 EndIf ;Command >0

 ;---------------------------------------------------------

 ;Output what i have done :-)

 If Len(o$)>0 Then o$=o$+":"

 If p>0 Then
  For i=1 To p
   o$=o$+Para(i)
   If i<p Then o$=o$+","
  Next
 EndIf

 If Len(o$)>0 Then
  Return o$
 EndIf

End Function