Graphics 200,200,32,2
SetBuffer BackBuffer()

Type Camera
   
   Field x#,y#,z#
   Field xwink#,ywink#

End Type

Type Entity
   
   Field x#,y#,z#
   Field v.Vector[65535]
   Field tri.Triangle[65535]
   Field tris
   Field vecs
   
End Type

Type Vector
   
   Field x#,y#,z#
   Field col
   
End Type

Type Triangle
   
   Field v.vector[3]
   
End Type

cam.Camera=New Camera

lastfps=MilliSecs()

z=R_CreateCube()

wink#=0

While Not KeyHit(1)

   Cls

   wink#=wink#+10.
   
   update3d(cam)
   
   fps#=(9.*fps#+(1000./(MilliSecs()-lastfps)))/10.:lastfps=MilliSecs()
   
   cam\x=Sin(wink#+180)*11.
   cam\z=11+Cos(wink#+180)*11.
   cam\ywink=wink#
   
   Text 1,1,fps#
   
   Flip
   
Wend

End

Function R_CreateCube()
   
   z=R_CreateEntity()
   
   R_AddVertex(z,-1,1,10)
   R_AddVertex(z,-1,-1,10)
   R_AddVertex(z,-1,1,12)
   R_AddVertex(z,-1,-1,12)
   R_AddVertex(z,1,1,10)
   R_AddVertex(z,1,-1,10)
   R_AddVertex(z,1,1,12)
   R_AddVertex(z,1,-1,12)
   
   R_AddTriangle(z,1,2,3)
   R_AddTriangle(z,2,3,4)
   R_AddTriangle(z,1,5,2)
   R_AddTriangle(z,2,5,6)
   R_AddTriangle(z,5,6,7)
   R_AddTriangle(z,6,7,8)
   R_AddTriangle(z,3,4,8)
   R_AddTriangle(z,3,7,8)
   R_AddTriangle(z,1,3,5)
   R_AddTriangle(z,3,5,7)
   R_AddTriangle(z,2,4,6)
   R_AddTriangle(z,4,6,8)
   
   Return z
   
End Function

Function R_CreateEntity()
   
   x.Entity=New Entity
   Return Handle(x)
   
End Function

Function R_AddTriangle(Entity,v1,v2,v3)
   
   Ent.Entity=Object.Entity(Entity)
   
   Ent\tris=Ent\tris+1
   s=Ent\tris
   
   Ent\tri[s]=New Triangle
   Ent\tri[s]\v[1]=Ent\v[v1]
   Ent\tri[s]\v[2]=Ent\v[v2]
   Ent\tri[s]\v[3]=Ent\v[v3]
   
   Return s
   
End Function

Function R_AddVertex(Entity,tx#,y#,z#,col=255 Shl 16 + 255 Shl 8 + 255)
   
   Ent.Entity=Object.Entity(Entity)
   
   Ent\vecs=Ent\vecs+1
   s=Ent\vecs
   Ent\v[s]=New Vector
   Ent\v[s]\x#=tx#
   Ent\v[s]\y#=y#
   Ent\v[s]\z#=z#
   Ent\v[s]\col=col
   
   Return s
   
End Function

Function update3d(camera.Camera,dist#=1000,fovx#=90,fovy#=0)
   
   If fovy#=0
      fovy#=GraphicsHeight()/GraphicsWidth()*90.
   EndIf
   
   LockBuffer
   
   wid=GraphicsWidth()
   hei=GraphicsHeight()
   
   camxwink#=camera\xwink#
   camywink#=camera\ywink#

   fakx#=wid/fovx#
   faky#=hei/fovy#
   
   For x=-wid/2 To wid/2-1
      For y=-wid/2 To wid/2-1
         
         sx#=camera\x#
         sy#=camera\y#
         sz#=camera\z#
         
         winky#=x/fakx#+camywink#
         winkx#=y/faky#+camxwink#
         
         dx#=sx#+Sin(winky#)*Cos(winkx#)*dist#
         dz#=sz#+Cos(winky#)*Cos(winkx#)*dist#
         dy#=sy#+Sin(winkx#)*dist#
         
         col=0
         short.Triangle=Null
         shortest=dist#
         
         For s.Triangle=Each Triangle
            
            r#=Ray_Intersect_Triangle#(sx#,sy#,sz#,dx#,dy#,dz#,s\v[1]\x#,s\v[1]\y#,s\v[1]\z#,s\v[2]\x#,s\v[2]\y#,s\v[2]\z#,s\v[3]\x#,s\v[3]\y#,s\v[3]\z#)

            If r#<>False; And r#<shortest
               
               shortest=r#
               short=s
               
            EndIf
            
         Next
         
         If short<>Null
            
            col=short\v[1]\col
            
         EndIf
         
         WritePixelFast(x+wid/2,y+hei/2,col,BackBuffer())
         
      Next
   Next
   
   UnlockBuffer
   
End Function

Function Ray_Intersect_Triangle#(Px#, Py#, Pz#, Dx#, Dy#, Dz#, V0x#, V0y#, V0z#, V1x#, V1y#, V1z#, V2x#, V2y#, V2z#, Extend_To_Infinity=False, Cull_Backfaces=False)
   
   ; crossproduct(b,c) =
   ; ax = (by * cz) - (cy * bz)
   ; ay = (bz * cx) - (cz * bx)    
   ; az = (bx * cy) - (cx * by)

   ; dotproduct(v,q) =
   ; (vx * qx) + (vy * qy) + (vz * qz)   
   ; DP =  1 = Vectors point in same direction.          (  0 degrees of seperation)
   ; DP =  0 = Vectors are perpendicular to one another. ( 90 degrees of seperation)
   ; DP = -1 = Vectors point in opposite directions.     (180 degrees of seperation)
   ;
   ; The dot product is also reffered to as "the determinant" or "the inner product"

   ; Calculate the vector that represents the first side of the triangle.
   E1x# = V2x# - V0x#
   E1y# = V2y# - V0y#
   E1z# = V2z# - V0z#

   ; Calculate the vector that represents the second side of the triangle.
   E2x# = V1x# - V0x#
   E2y# = V1y# - V0y#
   E2z# = V1z# - V0z#

   ; Calculate a vector which is perpendicular to the vector between point 0 and point 1,
   ; and the direction vector for the ray.
   ; Hxyz = Crossproduct(Dxyz, E2xyz)
   Hx# = (Dy# * E2z#) - (E2y# * Dz#)
   Hy# = (Dz# * E2x#) - (E2z# * Dx#)
   Hz# = (Dx# * E2y#) - (E2x# * Dy#)

   ; Calculate the dot product of the above vector and the vector between point 0 and point 2.
   A# = (E1x# * Hx#) + (E1y# * Hy#) + (E1z# * Hz#)

   ; If we should ignore triangles the ray passes through the back side of,
   ; and the ray points in the same direction as the normal of the plane,
   ; then the ray passed through the back side of the plane, 
   ; and the ray does not intersect the plane the triangle lies in.
   If (Cull_Backfaces = True) And (A# >= 0) Then Return False
      
   ; If the ray is almost parralel to the plane,
   ; then the ray does not intersect the plane the triangle lies in.
   If (A# > -0.00001) And (A# < 0.00001) Then Return False
   
   ; Inverse Determinant. (Dot Product)
   ; (Scaling factor for UV's?)
   F# = 1.0 / A#

   ; Calculate a vector between the starting point of our ray, and the first point of the triangle,
   ; which is at UV(0,0)
   Sx# = Px# - V0x#
   Sy# = Py# - V0y#
   Sz# = Pz# - V0z#
   
   ; Calculate the U coordinate of the intersection point.
   ;
   ;   Sxyz is the vector between the start of our ray and the first point of the triangle.
   ;   Hxyz is the normal of our triangle.
   ;   
   ; U# = F# * (DotProduct(Sxyz, Hxyz))
   U# = F# * ((Sx# * Hx#) + (Sy# * Hy#) + (Sz# * Hz#))
   
   ; Is the U coordinate outside the range of values inside the triangle?
   If (U# < 0.0) Or (U# > 1.0)

      ; The ray has intersected the plane outside the triangle.
      Return False
   
   EndIf

   ; Not sure what this is, but it's definitely NOT the intersection point.
   ;
   ;   Sxyz is the vector from the starting point of the ray to the first corner of the triangle.
   ;   E1xyz is the vector which represents the first side of the triangle.
   ;   The crossproduct of these two would be a vector which is perpendicular to both.
   ;
   ; Qxyz = CrossProduct(Sxyz, E1xyz)
   Qx# = (Sy# * E1z#) - (E1y# * Sz#)
   Qy# = (Sz# * E1x#) - (E1z# * Sx#)
   Qz# = (Sx# * E1y#) - (E1x# * Sy#)
   
   ; Calculate the V coordinate of the intersection point.
   ;   
   ;   Dxyz is the vector which represents the direction the ray is pointing in.
   ;   Qxyz is the intersection point I think?
   ;
   ; V# = F# * DotProduct(Dxyz, Qxyz)
   V# = F# * ((Dx# * Qx#) + (Dy# * Qy#) + (Dz# * Qz#))
   
   ; Is the V coordinate outside the range of values inside the triangle?   
   ; Does U+V exceed 1.0? 
   If (V# < 0.0) Or ((U# + V#) > 1.0)

      ; The ray has intersected the plane outside the triangle.      
      Return False

      ; The reason we check U+V is because if you imagine the triangle as half a square, U=1 V=1 would
      ; be in the lower left hand corner which would be in the lower left triangle making up the square.
      ; We are looking for the upper right triangle, and if you think about it, U+V will always be less
      ; than or equal to 1.0 if the point is in the upper right of the triangle.

   EndIf

   ; Calculate the distance of the intersection point from the starting point of the ray, Pxyz.
   ; This distance is scaled so that at Pxyz, the start of the ray, T=0, and at Dxyz, the end of the ray, T=1.
   ; If the intersection point is behind Pxyz, then T will be negative, and if the intersection point is
   ; beyond Dxyz then T will be greater than 1.
   T# = F# * ((E2x# * Qx#) + (E2y# * Qy#) + (E2z# * Qz#))

   ; If the triangle is behind Pxyz, ignore this intersection.
   ; We want a directional ray, which only intersects triangles in the direction it points.
   If (T# < 0) Then Return False

   ; If the plane is beyond Dxyz, amd we do not want the ray to extend to infinity, then ignore this intersection.
   If (Extend_To_Infinity = False) And (T# > 1) Return False

   ; The ray intersects the triangle!      
   Return T#

End Function