Graphics3D 800,600,32,2
SetBuffer BackBuffer()

cam=CreateCamera()

cube1 = CreatePivot() ; parent für all die multisurfacecubes
cube2 = CreateMesh() ; mesh für das einzelne cube-surface
surf = CreateSurface(cube2) ; surface für all die cubes

; ganz viele zufällig positionierte und gedrehte cubes erstellen
For i = 0 To 1200
   x = Rand(-20,20)
   y = Rand(-20,20)
   z = Rand(-20,20)
   
   c = CreateCube(cube1)
   PositionEntity c,x,y,z
   EntityColor c,255,200,200
   
   RotateEntity c,Rand(360),Rand(360),Rand(360)
   
   ;cube in das singlesurfacemesh reinkopieren
   AddToSurface(c,  surf,cube2)
   
Next


While Not KeyDown(1)
   
   If KeyDown(57) ; wenn leertaste gedrückt wird, wird das singlesurfacemesh gerendert, sonst werden viele surfaces gerendert
      HideEntity cube1
      ShowEntity cube2
   Else
      ShowEntity cube1
      HideEntity cube2
   EndIf
   
   TurnEntity cam,0,.1,0
   
   ms = MilliSecs()
   RenderWorld
   Text 0,0,"RenderTime: "+(MilliSecs()-ms)
   Flip
   
Wend

Function AddToSurface(mesh, surf,singlesurfaceentity)
   Local vert[2]
   For s = 1 To CountSurfaces(mesh)
      surface = GetSurface(mesh,s)      
      For i = 0 To  CountTriangles(surface)-1
         For i2 = 0 To 2
            oldvert = TriangleVertex(surface,i,i2)
            TFormPoint VertexX(surface,oldvert),VertexY(surface,oldvert),VertexZ(surface,oldvert), mesh,singlesurfaceentity
            vert[i2] = AddVertex(surf,TFormedX(),TFormedY(),TFormedZ(),VertexU(surface,oldvert),VertexV(surface,oldvert))
         Next
         AddTriangle(surf, vert[0], vert[1], vert[2])
      Next
   Next
End Function