Graphics 1024,768,16,1
Setbuffer backbuffer()
x1 = 0
x2 = 1024
y1 = 600
y2 = 600
c = 6
Repeat
   If KeyHit(203) c = c - 1
   If KeyHit(205) c = c + 1
   If c < 0 c = 0
   cls
   sline x1,y1,x2,y2,c
   Line MouseX()-5,mousey()-5,mousex()+5,mousey()+5
   Line MouseX()-5,mousey()+5,mousex()+5,mousey()-5
   If MouseDown(1) x1 = MouseX(): y1 = MouseY()
   If MouseDown(2) x2 = MouseX(): y2 = MouseY()
   Flip 0
Until KeyHit(1)
WaitKey()

Function sline(x1,y1,x2,y2,c)
;   Line x1,y1,x2,y2
   ab = Sqr((x2-x1)^2 + (y2-y1)^2)
   ri = ATan2(y2-y1,x2-x1)
   xt1 = x1+cos(ri)*ab/4
   yt1 = y1+sin(ri)*ab/4
   xt2 = x2-cos(ri)*ab/4
   yt2 = y2-sin(ri)*ab/4
   mx = (x1+x2)/2
   my = (y1+y2)/2
   tx = mx-cos(ri+90)*ab/2
   ty = my-sin(ri+90)*ab/2
   Line x1, y1, xt1, yt1
   If c
      sLine xt1,yt1,tx,ty, c-1
      sLine tx,ty,xt2,yt2, c-1
   Else
      Line xt1,yt1,tx,ty
      Line tx,ty,xt2,yt2
   End if
   Line xt2, yt2, x2, y2
End function

Graphics 1280,1024,16,1

Type entity
   Field x#,y#,dir#,scale#
   Field handled, art ;Art: 1 = Quadrat, 2 = Dreieck
End Type

Const variante = 1 ;1 = In eine Richtung, 2 = in 2 Richtungen

If variante = 1 Then
   t.entity = New entity
   t\x# = 580
   t\y# = 900
   t\dir# = 0
   t\scale# = 180
   t\handled = 0
   t\art = 1
Else
   t.entity = New entity
   t\x# = 580
   t\y# = 602
   t\dir# = 0
   t\scale# = 100
   t\handled = 0
   t\art = 1
   
   t.entity = New entity
   t\x# = 680
   t\y# = 602
   t\dir# = 180
   t\scale# = 100
   t\handled = 0
   t\art = 2
EndIf

Const tiefe = 50
Const logtype = 2 ;0=kein, 1=write, 2=text
Const waitk = 0 ;waitkey enabled/disabled

For i = 0 To tiefe
   If logtype = 1 Then
      Write i+";"
   EndIf
   If logtype = 2 Then
      Color 0,0,0
      Rect 9,9,100,20
      Color 255,255,255
      Text 10,10,i+"/"+tiefe
   EndIf
   
   For t.entity = Each entity ;DREIECK
      If KeyHit(1) Then End
      If t\handled = 0 Then
         If t\art = 2 Then
            t\handled = 1
            ;drawtriangle(t\x#,t\y#,t\dir#,t\scale#)
            
            e.entity = New entity
            e\x# = t\x#
            e\y# = t\y#
            e\dir# = t\dir#-37
            e\scale = t\scale*.8
            e\handled = 0
            e\art = 1
            
            e.entity = New entity
            e\x# = t\x#+Cos(t\dir#-37)*t\scale#*.8
            e\y# = t\y#+Sin(t\dir#-37)*t\scale#*.8
            e\dir# = t\dir#+53
            e\scale = t\scale*.6
            e\handled = 0
            e\art = 1
            Delete t.entity
         EndIf
      EndIf
   Next
   
   For t.entity = Each entity ;QUADRATE
      If KeyHit(1) Then End
      If t\handled = 0 Then
         If t\art = 1 Then
            t\handled = 1
            drawquad(t\x#,t\y#,t\dir#,t\scale#)
            
            e.entity = New entity
            e\x# = t\x#+Cos(t\dir#-90)*t\scale
            e\y# = t\y#+Sin(t\dir#-90)*t\scale
            e\dir# = t\dir#
            e\scale = t\scale
            e\handled = 0
            e\art = 2
            Delete t.entity
         EndIf
      EndIf
   Next
   If i = tiefe Then Text 640,10,"FERTIG",1,1
   If waitk Then WaitKey
Next
WaitKey




;#### FUNCTIONS ####

Function drawtriangle(x#,y#,dir#,scale#)
   up1# = Sin(dir#)*scale#
   rig1# = Cos(dir#)*scale#

   up2# = Sin(dir#-37)*scale#*.8
   rig2# = Cos(dir#-37)*scale#*.8

   Line(x#,y#,x#+rig1#,y#+up1#)
   Line(x#,y#,x#+rig2#,y#+up2#)
   Line(x#+rig2#,y#+up2#,x#+rig1#,y#+up1#)
End Function

Function drawquad(x#,y#,dir#,scale#)
   uppast# = y#
   rigpast# = x#
   For i = 0 To 270 Step 90
      uppast# = uppast#+up#
      rigpast# = rigpast#+rig#
      up# = Sin(dir#-i)*scale#
      rig# = Cos(dir#-i)*scale#
      Line(rigpast#,uppast#,rigpast#+rig#,uppast#+up#)
   Next
End Function