' --- Funktionen ---
?win32

Extern "win32"

   Function SetWindowsHookExA:Int( id:Int, hookproc:Int( code:Int, wparam:Int, lparam:Int ), instance:Int, thread:Int )
   Function UnhookWindowsHookEx:Int( hook:Int )
   Function CallNextHookEx:Int( hook:Int, code:Int, wparam:Int, lparam:Int )

End Extern

' Globale variablen, bitte nicht verändern ;)
Global wkhook:Int
Global lwin:Int, rwin:Int

Const WH_KEYBOARD_LL:Int = 13

' Die Hook-Funktion, die bei jedem Tastendruck von Windows aufgerufen wird
Function KeyboardProc:Int( code:Int, wparam:Int, lparam:Int )
   If( code <= 0 ) CallNextHookEx( wkhook, code, wparam, lparam )
   
   ' Herausfinden, welche Taste gedrückt wurde
   Local key:Int = Byte Ptr( lparam )[0]

   If wparam = WM_KEYDOWN Or wparam = WM_KEYUP
      If( ( lwin And key = $5b ) Or ( rwin And key = $05c ) ) Return 1
   End If
   
   Return CallNextHookEx( wkhook, code, wparam, lparam )
End Function

?

' Funktion zum Ein-/Ausschalten des Hooks. Vor dem Beenden sollte EnableKeyLock( False ) aufgerufen werden.
Function EnableKeyLock( enable:Int )
   ?win32
   
   If enable wkhook = SetWindowsHookExA( 13, KeyboardProc, GetModuleHandleA( 0 ), 0 ) Else UnhookWindowsHookEx( wkhook )
   
   ?
End Function

' Sperrt die linke oder rechte Windowstaste
Function LockWinKeys( leftkey:Int, rightkey:Int )
   lwin = leftkey
   rwin = rightkey
End Function

' --- Beispiel ---

Framework brl.d3d7max2d
Import pub.win32

SuperStrict

Include "lockwinkeys.bmx"

Graphics 660, 220, 0

' Hook aktivieren
EnableKeyLock( True )

Local s1:Int, s2:Int

While Not( KeyDown( KEY_ESCAPE ) Or AppTerminate( ) )
   Cls
   
   If KeyHit( KEY_1 )
      s1 = 1 - s1
      
      ' Tasten sperren
      LockWinKeys( s1, s2 )
   End If
   
   If KeyHit( KEY_2 )
      s2 = 1 - s2
      
      ' Tasten sperren
      LockWinKeys( s1, s2 )
   End If
   
   DrawText( "--- Dieses Programm sperrt die Windowstasten ( made by Christian Klaussner ) ---", 10, 10 )
   DrawText( "Druecke die Tasten '1' und '2', um den Status zu wechseln.", 10, 70 )
   DrawText( "Null steht fuer normal, eins fuer gesperrt.", 10, 100 )
   
   DrawText( "Status der linken Taste: " + s1, 10, 150 )
   DrawText( "Status der rechten Taste: " + s2, 10, 180 )

   Flip
Wend

' Hook deaktivieren
EnableKeyLock( False )

' Programm beenden
End